[gentoo-commits] repo/gentoo:master commit in: media-tv/kodi/

[Craig Andrews]

commit:     88caa4510f10188e906aecd6a4602dcd91fb49c2
Author:     Craig Andrews <candrews <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  1 00:44:55 2020 +0000
Commit:     Craig Andrews <candrews <AT> gentoo <DOT> org>
CommitDate: Sun Nov  1 00:47:02 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=88caa451

media-tv/kodi: 19.0_alpha3 version bump

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Craig Andrews <candrews <AT> gentoo.org>

 media-tv/kodi/Manifest                |   1 +
 media-tv/kodi/kodi-19.0_alpha3.ebuild | 302 ++++++++++++++++++++++++++++++++++
 2 files changed, 303 insertions(+)

diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index a23ea44a1df..19fd7b59402 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -5,6 +5,7 @@ DIST kodi-18.7.tar.gz 51051040 BLAKE2B 7ff04cd0ddcf74e46eef4318cf870662b9e076b36
 DIST kodi-18.8.tar.gz 51052219 BLAKE2B 6e49b08b5e2bfe778dafb687658e82b90226a9f1c1a7827a4290d601fe4c98e5cbaabaa39563c19a2956b83ce3a76640f081a56a41dfea4d65fb8b503c6f37b0 SHA512 242eaa9144ba0d9b15f02ab41282295de76d375cf66d595e7f6687d47c996133fcf5647448dcd06759df9f30bd86cdba239720b9bdd8b57827b6f261c08c4aaa
 DIST kodi-18.9.tar.gz 51052509 BLAKE2B e7cd888a38ed81e90566ae5e8a6f28c93688c8293af4b210674f224b02e7452ac81c25128cfbeaa3c67980fc00e18631060640ddff61263c782c807f8c5ea00e SHA512 72e4e2afa46d5d2061ed348af5c9a4218474589cb38d630e6d0643b35aff3b0aefb3db81333d52da6c799c530a1b709b1d7ccb6ec77dcb0cba06fce6791cb353
 DIST kodi-19.0_alpha2_p20201030.tar.gz 52309285 BLAKE2B 13d20b526675f7338f4ef033004710917da2fee4851fa96290d461941465f46de82b76124ba67fb301c4f460443fdf14b1271895f35a45409d3d6c4938d6abb7 SHA512 84c3d7aaf35585c278929749c539f2a3f33709d716d52019ad13a5780b05ccaca3a15a727a295b41c5479f50313d4bce1751af998c326c77aa729910a1915132
+DIST kodi-19.0a3.tar.gz 52312636 BLAKE2B 2672e8ec243e59ae31ce1a0a4d1bfadc4dddfe3ae5eb0e7560ad2c9452d3ad238be9d7e12ed2b72a63ba6b172515842f0b4bb0c79e987df25a21480bf7850851 SHA512 9d08cee972d611c2e9a3ba7b46ad098f76be15321606e3a1645492bfaa8018a902603dabaa59cbd93d99b1e431d0f8b155096b235a6b0a1070cfb164b228e7b0
 DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e
 DIST libdvdnav-6.0.0-Leia-Alpha-3.tar.gz 137942 BLAKE2B 7573434a0ae8e8ccabf48173f81fcde29074eb138e119a2ae9156cde3c3d8bfd716f5d0e605b97f2dcac21f570781137c8533c5ae306b51e3905822fda318355 SHA512 11c93eaacd156f8fd7dec7c43d366438b201f31ad55b2870463a9e286912b6ada08882319a021fb7992190f87b909a49f2b83e0321cc17aedc29f7fe5898fa72
 DIST libdvdread-6.0.0-Leia-Alpha-3.tar.gz 130649 BLAKE2B 0c206acdaf0776841ab792c74e023af07d9539eb72e03ae164382a31ed950f60e5e15f1d055979d28f1398924471b294d11f064b11b8373353b3962a3777ff3c SHA512 b3419ba0a1a2dd70f1bb6236afdfe1c6e88c9ad4264198b289e3bba9375e077cecf7f89848c7b09debaa445327f3507101f3d157e692f7a7163b2bb52643e1e7

diff --git a/media-tv/kodi/kodi-19.0_alpha3.ebuild b/media-tv/kodi/kodi-19.0_alpha3.ebuild
new file mode 100644
index 00000000000..ad742a28610
--- /dev/null
+++ b/media-tv/kodi/kodi-19.0_alpha3.ebuild
@@ -0,0 +1,302 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_REQ_USE="libressl?,sqlite,ssl"
+LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
+LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
+LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
+FFMPEG_VERSION="4.3.1"
+CODENAME="Matrix"
+FFMPEG_KODI_VERSION="Alpha1-2"
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
+	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+	inherit git-r3
+else
+	MY_PV=${PV/_p/_r}
+	MY_PV=${MY_PV/_alpha/a}
+	MY_PV=${MY_PV/_beta/b}
+	MY_PV=${MY_PV/_rc/rc}
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
+fi
+
+inherit autotools cmake desktop linux-info pax-utils python-single-r1 xdg
+
+DESCRIPTION="A free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# use flag is called libusb so that it doesn't fool people in thinking that
+# it is _required_ for USB support. Otherwise they'll disable udev and
+# that's going to be worse.
+IUSE="airplay alsa bluetooth bluray caps cec +css dbus dvd gbm gles lcms libressl libusb lirc mariadb mysql nfs +opengl pulseaudio raspberry-pi samba systemd +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( gles opengl )
+	|| ( gbm wayland X )
+	?? ( mariadb mysql )
+	bluray? ( udf )
+	udev? ( !libusb )
+	udisks? ( dbus )
+	upower? ( dbus )
+"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	airplay? (
+		>=app-pda/libplist-2.0.0
+		net-libs/shairplay
+	)
+	alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
+	bluetooth? ( net-wireless/bluez )
+	bluray? ( >=media-libs/libbluray-1.1.2 )
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	dev-db/sqlite
+	dev-libs/expat
+	>=dev-libs/flatbuffers-1.11.0
+	>=dev-libs/fribidi-1.0.5
+	cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
+	dev-libs/libpcre[cxx]
+	>=dev-libs/libinput-1.10.5
+	>=dev-libs/libxml2-2.9.4
+	>=dev-libs/lzo-2.04
+	>=dev-libs/spdlog-1.5.0:=
+	dev-libs/tinyxml[stl]
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_MULTI_USEDEP}]
+	')
+	>=dev-libs/libcdio-2.1.0
+	>=dev-libs/libfmt-6.1.2
+	dev-libs/libfstrcmp
+	gbm? (	media-libs/mesa[gbm] )
+	gles? (
+		!raspberry-pi? ( media-libs/mesa[gles2] )
+	)
+	lcms? ( media-libs/lcms:2 )
+	libusb? ( virtual/libusb:1 )
+	virtual/ttf-fonts
+	media-fonts/roboto
+	media-libs/dav1d
+	>=media-libs/fontconfig-2.13.1
+	>=media-libs/freetype-2.10.1
+	>=media-libs/libass-0.13.4
+	!raspberry-pi? ( media-libs/mesa[egl] )
+	>=media-libs/taglib-1.11.1
+	system-ffmpeg? (
+		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[dav1d,encode,postproc]
+		libressl? ( media-video/ffmpeg[libressl,-openssl] )
+		!libressl? ( media-video/ffmpeg[-libressl,openssl] )
+	)
+	mysql? ( dev-db/mysql-connector-c:= )
+	mariadb? ( dev-db/mariadb-connector-c:= )
+	>=net-misc/curl-7.68.0[http2]
+	nfs? ( >=net-fs/libnfs-2.0.0:= )
+	opengl? ( media-libs/glu )
+	!libressl? ( >=dev-libs/openssl-1.0.2l:0= )
+	libressl? ( dev-libs/libressl:0= )
+	raspberry-pi? (
+		|| ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl,gles2,video_cards_vc4] )
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
+	>=sys-libs/zlib-1.2.11
+	udf? ( >=dev-libs/libudfread-1.0.0 )
+	udev? ( virtual/udev )
+	vaapi? (
+		x11-libs/libva:=
+		opengl? ( x11-libs/libva[opengl] )
+		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
+		vdpau? ( x11-libs/libva[vdpau] )
+		wayland? ( x11-libs/libva[wayland] )
+		X? ( x11-libs/libva[X] )
+	)
+	virtual/libiconv
+	vdpau? (
+		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
+		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
+	)
+	wayland? (
+		>=dev-cpp/waylandpp-0.2.3:=
+		media-libs/mesa[wayland]
+		>=dev-libs/wayland-protocols-1.7
+	)
+	webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages(+)] )
+	X? (
+		media-libs/mesa[X]
+		x11-libs/libX11
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		system-ffmpeg? ( media-video/ffmpeg[X] )
+	)
+	x11-libs/libdrm
+	>=x11-libs/libxkbcommon-0.4.1
+	xslt? ( dev-libs/libxslt )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+RDEPEND="${COMMON_DEPEND}
+	lirc? ( app-misc/lirc )
+	udisks? ( sys-fs/udisks:2 )
+	upower? ( sys-power/upower )
+"
+DEPEND="${COMMON_DEPEND}
+	app-arch/bzip2
+	app-arch/xz-utils
+	dev-lang/swig
+	dev-libs/crossguid
+	dev-libs/rapidjson
+	dev-util/cmake
+	dev-util/gperf
+	media-libs/giflib
+	>=media-libs/libjpeg-turbo-2.0.4:=
+	>=media-libs/libpng-1.6.26:0=
+	test? ( >=dev-cpp/gtest-1.10.0 )
+	virtual/pkgconfig
+	virtual/jre
+	x86? ( dev-lang/nasm )
+"
+
+CONFIG_CHECK="~IP_MULTICAST"
+ERROR_IP_MULTICAST="
+In some cases Kodi needs to access multicast addresses.
+Please consider enabling IP_MULTICAST under Networking options.
+"
+
+pkg_setup() {
+	check_extra_config
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999 ]] ; then
+		git-r3_src_unpack
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# avoid long delays when powerkit isn't running #348580
+	sed -i \
+		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
+		xbmc/platform/linux/*.cpp || die
+
+	# Prepare tools and libs witch are configured with autotools during compile time
+	AUTOTOOLS_DIRS=(
+		"${S}"/tools/depends/native/TexturePacker/src
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src
+	)
+
+	local d
+	for d in "${AUTOTOOLS_DIRS[@]}" ; do
+		pushd ${d} >/dev/null || die
+		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
+		popd >/dev/null || die
+	done
+	elibtoolize
+
+	# Prevent autoreconf rerun
+	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
+		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
+		|| die
+}
+
+src_configure() {
+	local platform=()
+	use gbm && platform+=( gbm )
+	use wayland && platform+=( wayland )
+	use X && platform+=( x11 )
+	local mycmakeargs=(
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
+		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AIRTUNES=$(usex airplay)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_BLUETOOTH=$(usex bluetooth)
+		-DENABLE_BLURAY=$(usex bluray)
+		-DENABLE_CCACHE=OFF
+		-DENABLE_CEC=$(usex cec)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DVDCSS=$(usex css)
+		-DENABLE_INTERNAL_CROSSGUID=OFF
+		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+		-DENABLE_INTERNAL_FSTRCMP=OFF
+		-DENABLE_INTERNAL_GTEST=OFF
+		-DENABLE_INTERNAL_UDFREAD=OFF
+		-DENABLE_CAP=$(usex caps)
+		-DENABLE_LCMS2=$(usex lcms)
+		-DENABLE_LIRCCLIENT=$(usex lirc)
+		-DENABLE_MARIADBCLIENT=$(usex mariadb)
+		-DENABLE_MICROHTTPD=$(usex webserver)
+		-DENABLE_MYSQLCLIENT=$(usex mysql)
+		-DENABLE_NFS=$(usex nfs)
+		-DENABLE_OPENGLES=$(usex gles)
+		-DENABLE_OPENGL=$(usex opengl)
+		-DENABLE_OPTICAL=$(usex dvd)
+		-DENABLE_PLIST=$(usex airplay)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
+		-DENABLE_SMBCLIENT=$(usex samba)
+		-DENABLE_TESTING=$(usex test)
+		-DENABLE_UDEV=$(usex udev)
+		-DENABLE_UDFREAD=$(usex udf)
+		-DENABLE_UPNP=$(usex upnp)
+		-DENABLE_VAAPI=$(usex vaapi)
+		-DENABLE_VDPAU=$(usex vdpau)
+		-DENABLE_XSLT=$(usex xslt)
+		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
+		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
+		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
+		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
+		-DPYTHON_LIBRARY="$(python_get_library_path)"
+		-DAPP_RENDER_SYSTEM="$(usex opengl gl gles)"
+		-DCORE_PLATFORM_NAME="${platform[@]}"
+	)
+
+	use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
+
+	if use system-ffmpeg; then
+		mycmakeargs+=( -DWITH_FFMPEG="yes" )
+	else
+		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile all
+}
+
+src_test() {
+	# see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
+	KODI_HOME="${BUILD_DIR}" cmake_build check
+}
+
+src_install() {
+	cmake_src_install
+
+	pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
+
+	newicon media/icon48x48.png kodi.png
+
+	rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
+	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
+		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
+
+	python_domodule tools/EventClients/lib/python/xbmcclient.py
+	python_newscript "tools/EventClients/Clients/KodiSend/kodi-send.py" kodi-send
+}