[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/

[Gilles Dartiguelongue]

commit:     a07b20cf3d7d7e7f5f202a068ccec90b67a1e1a3
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Tue Sep  6 22:09:46 2016 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Tue Sep  6 22:09:46 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a07b20cf

gnome-extra/gnome-software: version bump to 3.20.2

Also fix handling of python unittests.

Package-Manager: portage-2.3.0

 gnome-extra/gnome-software/Manifest                |  1 +
 .../gnome-software/gnome-software-3.20.4.ebuild    | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 0f691a0..d16f6b3 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1 +1,2 @@
 DIST gnome-software-3.18.3.tar.xz 2195300 SHA256 cc76a51f56d114018f64478437aebef068799802884543c59e2473066c959b7b SHA512 61d4f9622d0f3c6b65d271a79908713f1ee5a2da67275aee6cd6510d6c124ad76300bcc696846d8bd95843f9326534218d3b140445f6e7d2f6ab8d336e476ec0 WHIRLPOOL acea5e54b06bcd2d1088d7790b813001a2718acd981c53f4dca170200efc96ca2d6e477ff674f384e08817821697ef2e2261d4d14cf5f3bd4c757352920231de
+DIST gnome-software-3.20.4.tar.xz 3513716 SHA256 d6a2794348e2c543218e3efb01105a7e6d51e93ad3055a2482e3104ca75345f2 SHA512 ea4536acc954f3d5d5d834323580041fe03099a6733a64f0c6a60f40028e0f054a4f9161b4fdd0956be8aa5ba25eed53748b28fff8d1c05b03ff314af6380fdf WHIRLPOOL e62085795f5eb84d0b94e140f83c7c759ea0bf7b2026890b19bd40cebbff3c53395ed820002657893846cccd505cfe0db0ca2f148ef3204c96d40059c0f2f357

diff --git a/gnome-extra/gnome-software/gnome-software-3.20.4.ebuild b/gnome-extra/gnome-software/gnome-software-3.20.4.ebuild
new file mode 100644
index 00000000..188062f
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-3.20.4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="http://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RDEPEND="
+	>=app-admin/packagekit-base-1.1.0
+	app-text/gtkspell:3
+	dev-db/sqlite:3
+	>=dev-libs/appstream-glib-0.5.12:0
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/json-glib-1.1.1
+	>=gnome-base/gnome-desktop-3.17.92:3=
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+	>=net-libs/libsoup-2.51.92:2.4
+	sys-auth/polkit
+	>=x11-libs/gdk-pixbuf-2.31.5
+	>=x11-libs/gtk+-3.18.2:3
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+# test? ( dev-util/valgrind )
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# valgrind fails with SIGTRAP
+	sed -e 's/TESTS = .*/TESTS =/' \
+		-i "${S}"/src/Makefile.{am,in} || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# FIXME: investigate limba and firmware update support
+	gnome2_src_configure \
+		--enable-man \
+		--enable-packagekit \
+		--enable-polkit \
+		--disable-xdg-app \
+		--disable-firmware \
+		--disable-limba \
+		$(use_enable test dogtail)
+}
+
+src_test() {
+	virtx emake check TESTS_ENVIRONMENT="dbus-run-session"
+}