[gentoo-commits] repo/gentoo:master commit in: dev-util/ostree/

[Zac Medico]

commit:     c21111531ad46fa9fc0c9e46bdc6de497c561b0b
Author:     Jonathan Davies <jpds <AT> protonmail <DOT> com>
AuthorDate: Wed Sep 30 13:24:38 2020 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Sun Oct  4 19:16:30 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c2111153

dev-util/ostree: Version updated to 2020.6.

Closes: https://bugs.gentoo.org/730360
Closes: https://github.com/gentoo/gentoo/pull/17718
Signed-off-by: Jonathan Davies <jpds <AT> protonmail.com>
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 dev-util/ostree/Manifest             |  1 +
 dev-util/ostree/ostree-2020.6.ebuild | 90 ++++++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)

diff --git a/dev-util/ostree/Manifest b/dev-util/ostree/Manifest
index 5211bf003e4..a0d1025bb60 100644
--- a/dev-util/ostree/Manifest
+++ b/dev-util/ostree/Manifest
@@ -1 +1,2 @@
 DIST ostree-2019.5.tar.xz 1972452 BLAKE2B a8b015118855b8b0097f535ac074aeffc599c3f6f654967043e8e4de339d2a51e85ad1b4b3f3b22e18d39235e6ad9c1973334a2c4fc9b5c694f2ff40d68ae703 SHA512 27150802ed9af16e698ed163f6ad235f0f99a1410df52b4b1e266585fe665880c0b9490bf245b5593cb277007b7229d808be7403dd964c58aded6e567349c912
+DIST ostree-2020.6.tar.xz 2014456 BLAKE2B 97d84c6838993edfbabb598bce800332ab1c8b22c0431839f7129f2f57afdd71c1b8ea8b8d6c1dc2cbf8d7f6828d624394b5e8c533f7a98eb1b1c3aeedff92cf SHA512 1d8f8ccaa3e543a6f494d3be2a3651ad340846f0c314e003955260b7bd1d8c0421acf102ec2ca6580379c354bf4cfac0940e4e95b724b7aaf9dc8116085aa538

diff --git a/dev-util/ostree/ostree-2020.6.ebuild b/dev-util/ostree/ostree-2020.6.ebuild
new file mode 100644
index 00000000000..68c74d15f95
--- /dev/null
+++ b/dev-util/ostree/ostree-2020.6.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="Operating system and container binary deployment and upgrades"
+HOMEPAGE="https://ostree.readthedocs.io/en/latest/"
+SRC_URI="https://github.com/ostreedev/ostree/releases/download/v${PV}/lib${P}.tar.xz -> ${P}.tar.xz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="LGPL-2+"
+SLOT="0"
+
+IUSE="archive curl doc dracut gnutls grub http2 httpd introspection libmount selinux ssl soup systemd zeroconf"
+RESTRICT="test"
+REQUIRED_USE="httpd? ( || ( curl soup ) )"
+
+COMMON_DEPEND="
+	archive? ( app-arch/libarchive )
+	app-crypt/gpgme
+	app-arch/xz-utils
+	curl? ( net-misc/curl )
+	soup? ( net-libs/libsoup )
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	dev-libs/glib:2
+	dracut? ( sys-kernel/dracut )
+	grub? ( sys-boot/grub:2= )
+	introspection? ( dev-libs/gobject-introspection )
+	ssl? (
+		gnutls? ( net-libs/gnutls )
+		!gnutls? ( dev-libs/openssl:0= ) )
+	>=sys-fs/fuse-2.9.2:0
+	sys-libs/zlib
+	libmount? ( sys-apps/util-linux )
+	selinux? ( sys-libs/libselinux )
+	systemd? ( sys-apps/systemd:0= )
+	zeroconf? ( net-dns/avahi[dbus] )"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )"
+
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	sys-devel/flex
+	sys-devel/bison
+	virtual/pkgconfig"
+
+S="${WORKDIR}/lib${P}"
+
+src_prepare() {
+	sed -Ee 's:(XSLT_STYLESHEET = ).*:\1/usr/share/sgml/docbook/xsl-stylesheets/manpages/docbook.xsl:' \
+		-i Makefile.in Makefile-man.am || die
+
+	eautoreconf
+	default
+}
+
+src_configure() {
+	local econfargs=(
+		--enable-man
+		--enable-shared
+		$(use_with archive libarchive)
+		$(use_with curl)
+		$(use_with dracut)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable http2)
+		$(use_enable httpd trivial-httpd-cmdline)
+		$(use_with selinux )
+		$(use_with soup)
+		$(use_with libmount)
+		$(use ssl && { use gnutls && echo --with-crypto=gnutls || echo --with-crypto=openssl; })
+		$(use_with systemd libsystemd)
+		$(use_with zeroconf avahi)
+	)
+
+	unset ${!XDG_*} #657346 g-ir-scanner sandbox violation
+	econf ${econfargs[*]}
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}