[gentoo-commits] gentoo-x86 commit in app-cdr/k3b: k3b-2.0.3-r2.ebuild ChangeLog

[Johannes Huber (johu)]

johu        15/05/30 13:40:46

  Modified:             ChangeLog
  Added:                k3b-2.0.3-r2.ebuild
  Log:
  Revision bump adds patch to fix build with libav-11, bug #509332. Thanks to Oldrich Jedlicka <oldium.pro@××××××.cz>.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

Revision  Changes    Path
1.294                app-cdr/k3b/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/k3b/ChangeLog?rev=1.294&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/k3b/ChangeLog?rev=1.294&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/k3b/ChangeLog?r1=1.293&r2=1.294

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v
retrieving revision 1.293
retrieving revision 1.294
diff -u -r1.293 -r1.294
--- ChangeLog	13 May 2015 13:09:38 -0000	1.293
+++ ChangeLog	30 May 2015 13:40:46 -0000	1.294
@@ -1,6 +1,13 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.293 2015/05/13 13:09:38 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.294 2015/05/30 13:40:46 johu Exp $
+
+*k3b-2.0.3-r2 (30 May 2015)
+
+  30 May 2015; Johannes Huber <johu@g.o> +files/k3b-2.0.3-libav-11.patch,
+  +k3b-2.0.3-r2.ebuild:
+  Revision bump adds patch to fix build with libav-11, bug #509332. Thanks to
+  Oldrich Jedlicka <oldium.pro@××××××.cz>.
 
   13 May 2015; Michael Palimaka <kensington@g.o>
   -files/k3b-2.0.2-ffmpeg.patch, -files/k3b-2.0.2-ffmpeg2.patch,



1.1                  app-cdr/k3b/k3b-2.0.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/k3b/k3b-2.0.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/k3b/k3b-2.0.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: k3b-2.0.3-r2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-2.0.3-r2.ebuild,v 1.1 2015/05/30 13:40:46 johu Exp $

EAPI=5

MULTIMEDIA_REQUIRED="always"
WEBKIT_REQUIRED="always"
KDE_HANDBOOK="optional"
KDE_SCM="git"

# Translations are not available, since this is a snapshot
KDE_LINGUAS="ast be bg bs ca ca@valencia cs csb da de el en_GB eo es et eu fi fr
ga gl he hi hne hr hu is it ja kk km ko ku lt lv mai mr ms nb nds nl nn oc pa pl
pt pt_BR ro ru se sk sl sr sr@ijekavian sr@ijekavianlatin sr@latin sv th tr ug uk
zh_CN zh_TW"

SRC_URI="mirror://kde/stable/${PN}/${P}a.tar.xz"
DOCS=( FAQ PERMISSIONS README )

inherit kde4-base

DESCRIPTION="The CD/DVD Kreator for KDE"
HOMEPAGE="http://www.k3b.org/"

LICENSE="GPL-2 FDL-1.2"
SLOT="4"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis"

CDEPEND="
	|| ( kde-apps/libkcddb:4 $(add_kdebase_dep libkcddb) )
	media-libs/libsamplerate
	dvd? ( media-libs/libdvdread )
	ffmpeg? (
		libav? ( media-video/libav:= )
		!libav? ( media-video/ffmpeg:0= )
	)
	flac? ( >=media-libs/flac-1.2[cxx] )
	mp3? ( media-sound/lame )
	mad? ( media-libs/libmad )
	musepack? ( >=media-sound/musepack-tools-444 )
	sndfile? ( media-libs/libsndfile )
	taglib? ( >=media-libs/taglib-1.5 )
	vorbis? ( media-libs/libvorbis )
"
DEPEND="${CDEPEND}
	sys-devel/gettext
"
RDEPEND="${CDEPEND}
	$(add_kdebase_dep kdelibs 'udev,udisks(+)')
	app-cdr/cdrdao
	media-sound/cdparanoia
	virtual/cdrtools
	dvd? (
		>=app-cdr/dvd+rw-tools-7
		encode? ( media-video/transcode[dvd] )
	)
	emovix? ( media-video/emovix )
	sox? ( media-sound/sox )
	vcd? ( media-video/vcdimager )
"

DOCS+=( ChangeLog )

PATCHES=(
	"${FILESDIR}/${PN}-2.0.3-libav-11.patch"
)

REQUIRED_USE="
	mp3? ( encode )
	sox? ( encode )
"

src_configure() {
	mycmakeargs=(
		-DK3B_BUILD_API_DOCS=OFF
		-DK3B_BUILD_K3BSETUP=OFF
		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
		-DK3B_ENABLE_HAL_SUPPORT=OFF
		-DK3B_ENABLE_MUSICBRAINZ=OFF
		$(cmake-utils_use debug K3B_DEBUG)
		$(cmake-utils_use dvd K3B_ENABLE_DVD_RIPPING)
		$(cmake-utils_use encode K3B_BUILD_EXTERNAL_ENCODER_PLUGIN)
		$(cmake-utils_use ffmpeg K3B_BUILD_FFMPEG_DECODER_PLUGIN)
		$(cmake-utils_use flac K3B_BUILD_FLAC_DECODER_PLUGIN)
		$(cmake-utils_use mp3 K3B_BUILD_LAME_ENCODER_PLUGIN)
		$(cmake-utils_use mad K3B_BUILD_MAD_DECODER_PLUGIN)
		$(cmake-utils_use musepack K3B_BUILD_MUSE_DECODER_PLUGIN)
		$(cmake-utils_use sndfile K3B_BUILD_SNDFILE_DECODER_PLUGIN)
		$(cmake-utils_use sox K3B_BUILD_SOX_ENCODER_PLUGIN)
		$(cmake-utils_use taglib K3B_ENABLE_TAGLIB)
		$(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_DECODER_PLUGIN)
		$(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_ENCODER_PLUGIN)
	)
	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	echo
	elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
	elog "If you get warnings on start-up, uncheck the \"Check system"
	elog "configuration\" option in the \"Misc\" settings window."
	echo

	local group=cdrom
	use kernel_linux || group=operator
	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
	elog "Usually, it is sufficient to be in the ${group} group."
	echo
}