[gentoo-commits] repo/gentoo:master commit in: net-analyzer/ipv6toolkit/

[Jeroen Roovers]

commit:     78a9c81c87e92d48d247da5210c9cc1dc29ede96
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  8 09:05:13 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Wed Jan  8 09:16:24 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=78a9c81c

net-analyzer/ipv6toolkit: Add live ebuild

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 .../ipv6toolkit/ipv6toolkit-99999999.ebuild        | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/net-analyzer/ipv6toolkit/ipv6toolkit-99999999.ebuild b/net-analyzer/ipv6toolkit/ipv6toolkit-99999999.ebuild
new file mode 100644
index 00000000000..8a862e67718
--- /dev/null
+++ b/net-analyzer/ipv6toolkit/ipv6toolkit-99999999.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit git-r3 toolchain-funcs
+
+DESCRIPTION="Set of IPv6 security/trouble-shooting tools to send arbitrary IPv6-based packets"
+HOMEPAGE="https://www.si6networks.com/tools/ipv6toolkit/"
+EGIT_REPO_URI="https://github.com/fgont/ipv6toolkit"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+
+DEPEND="
+	net-libs/libpcap[ipv6(+)]
+"
+RDEPEND="
+	${DEPEND}
+	sys-apps/hwids
+"
+
+HWIDS_OUI_PATH=/usr/share/misc/oui.txt
+
+src_prepare() {
+	default
+	sed -i "s#/usr/share/ipv6toolkit/oui.txt#${HWIDS_OUI_PATH}#" \
+		manuals/ipv6toolkit.conf.5
+}
+src_compile() {
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" PREFIX=/usr
+}
+
+src_install() {
+	dodir /etc
+	emake install DESTDIR="${ED}" PREFIX=/usr
+	#remove the included oui file
+	rm -f "${D}"/usr/share/ipv6toolkit/oui.txt
+	#fix the conf file to use the one from sys-apps/hwids
+	sed -i "s#/usr/share/ipv6toolkit/oui.txt#${HWIDS_OUI_PATH}#" \
+		"${ED}"/etc/ipv6toolkit.conf
+	dodoc CHANGES.TXT README.TXT
+}