[gentoo-commits] gentoo-x86 commit in gnustep-base/gnustep-base: ChangeLog gnustep-base-1.22.1.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    11/09/29 22:05:29

  Modified:             ChangeLog
  Added:                gnustep-base-1.22.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha60/cvs/Linux x86_64)

Revision  Changes    Path
1.106                gnustep-base/gnustep-base/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-base/ChangeLog?rev=1.106&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-base/ChangeLog?rev=1.106&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-base/ChangeLog?r1=1.105&r2=1.106

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-base/ChangeLog,v
retrieving revision 1.105
retrieving revision 1.106
diff -u -r1.105 -r1.106
--- ChangeLog	28 Sep 2011 10:57:01 -0000	1.105
+++ ChangeLog	29 Sep 2011 22:05:28 -0000	1.106
@@ -1,6 +1,12 @@
 # ChangeLog for gnustep-base/gnustep-base
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-base/ChangeLog,v 1.105 2011/09/28 10:57:01 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-base/ChangeLog,v 1.106 2011/09/29 22:05:28 voyageur Exp $
+
+*gnustep-base-1.22.1 (29 Sep 2011)
+
+  29 Sep 2011; Bernard Cafarelli <voyageur@g.o>
+  +gnustep-base-1.22.1.ebuild:
+  Version bump
 
   28 Sep 2011; Samuli Suominen <ssuominen@g.o> metadata.xml:
   USE="libffi" is now global USE flag.



1.1                  gnustep-base/gnustep-base/gnustep-base-1.22.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-base/gnustep-base-1.22.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-base/gnustep-base-1.22.1.ebuild?rev=1.1&content-type=text/plain

Index: gnustep-base-1.22.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-base/gnustep-base-1.22.1.ebuild,v 1.1 2011/09/29 22:05:28 voyageur Exp $

EAPI="3"

inherit gnustep-base

DESCRIPTION="A library of general-purpose, non-graphical Objective C objects."

HOMEPAGE="http://www.gnustep.org"
SRC_URI="ftp://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
SLOT="0"
LICENSE="GPL-2 LGPL-2.1"

IUSE="gnutls +icu +libffi zeroconf"

RDEPEND="${GNUSTEP_CORE_DEPEND}
	>=gnustep-base/gnustep-make-2.6.0
	gnutls? ( net-libs/gnutls )
	icu? ( >=dev-libs/icu-4.0 )
	!libffi? ( dev-libs/ffcall
		gnustep-base/gnustep-make[-native-exceptions] )
	libffi? ( virtual/libffi )
	>=dev-libs/libxml2-2.6
	>=dev-libs/libxslt-1.1
	>=dev-libs/gmp-4.1
	>=dev-libs/openssl-0.9.7
	>=sys-libs/zlib-1.2
	zeroconf? ( || (
		net-dns/avahi[mdnsresponder-compat]
		net-misc/mDNSResponder ) )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_configure() {
	egnustep_env

	local myconf
	if use libffi;
	then
		myconf="--enable-libffi --disable-ffcall --with-ffi-include=$(pkg-config --variable=includedir libffi)"
	else
		myconf="--disable-libffi --enable-ffcall"
	fi

	myconf="$myconf $(use_enable icu)"
	myconf="$myconf $(use_enable gnutls tls)"
	myconf="$myconf $(use_enable zeroconf)"
	myconf="$myconf --with-xml-prefix=${EPREFIX}/usr"
	myconf="$myconf --with-gmp-include=${EPREFIX}/usr/include --with-gmp-library=${EPREFIX}/usr/lib"
	myconf="$myconf --with-default-config=${EPREFIX}/etc/GNUstep/GNUstep.conf"

	econf $myconf || die "configure failed"
}

src_install() {
	# We need to set LD_LIBRARY_PATH because the doc generation program
	# uses the gnustep-base libraries.  Since egnustep_env "cleans the
	# environment" including our LD_LIBRARY_PATH, we're left no choice
	# but doing it like this.

	egnustep_env
	egnustep_install

	if use doc ; then
		export LD_LIBRARY_PATH="${S}/Source/obj:${LD_LIBRARY_PATH}"
		egnustep_doc
	fi
	egnustep_install_config
}

pkg_postinst() {
	ewarn "The shared library version has changed in this release."
	ewarn "You will need to recompile all Applications/Tools/etc in order"
	ewarn "to use this library. Please run revdep-rebuild to do so"
}