[gentoo-commits] gentoo-x86 commit in dev-python/enthoughtbase: ChangeLog enthoughtbase-3.0.5.ebuild

[Justin Lecher (jlec)]

jlec        10/05/31 06:55:29

  Modified:             ChangeLog
  Added:                enthoughtbase-3.0.5.ebuild
  Log:
  Version Bump on permission of Patrick
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 dev-python/enthoughtbase/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/enthoughtbase/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/enthoughtbase/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/enthoughtbase/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/enthoughtbase/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	23 Mar 2010 05:12:05 -0000	1.11
+++ ChangeLog	31 May 2010 06:55:29 -0000	1.12
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/enthoughtbase
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/enthoughtbase/ChangeLog,v 1.11 2010/03/23 05:12:05 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/enthoughtbase/ChangeLog,v 1.12 2010/05/31 06:55:29 jlec Exp $
+
+*enthoughtbase-3.0.5 (31 May 2010)
+
+  31 May 2010; Justin Lecher <jlec@g.o> +enthoughtbase-3.0.5.ebuild:
+  Version Bump on permission of Patrick
 
 *enthoughtbase-3.0.4 (20 Mar 2010)
 



1.1                  dev-python/enthoughtbase/enthoughtbase-3.0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/enthoughtbase/enthoughtbase-3.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/enthoughtbase/enthoughtbase-3.0.5.ebuild?rev=1.1&content-type=text/plain

Index: enthoughtbase-3.0.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/enthoughtbase/enthoughtbase-3.0.5.ebuild,v 1.1 2010/05/31 06:55:29 jlec Exp $

EAPI="2"
SUPPORT_PYTHON_ABIS="1"

inherit distutils

MY_PN="EnthoughtBase"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="Core packages for the Enthought Tool Suite"
HOMEPAGE="http://code.enthought.com/projects/enthought_base.php"
SRC_URI="http://www.enthought.com/repo/ETS/${MY_P}.tar.gz"

IUSE="doc examples"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
LICENSE="BSD LGPL-2"
RDEPEND=""

DEPEND="dev-python/setuptools
	doc? ( dev-python/setupdocs )"
# tests would require circular deps
#	test? ( >=dev-python/nose-0.10.3
#			dev-python/traits
#			dev-python/etsdevtools )"

RESTRICT_PYTHON_ABIS="3.*"
RESTRICT="test"

S="${WORKDIR}/${MY_P}"

PYTHON_MODNAME="enthought"

src_prepare() {
	sed -i \
		-e "s/self.run_command('build_docs')/pass/" \
		-e '/setupdocs/d' \
		setup.py || die
}

src_compile() {
	distutils_src_compile
	if use doc; then
		export VARTEXFONTS="${T}/fonts"
		"$(PYTHON -f)" setup.py build_docs --formats=html,pdf \
			|| die "doc building failed"
	fi
}

src_test() {
	testing() {
		PYTHONPATH="build-${PYTHON_ABI}/lib" "$(PYTHON)" setup.py build -b "build-${PYTHON_ABI}" test
	}
	python_execute_function testing
}

src_install() {
	find "${S}" -name \*LICENSE.txt -delete
	distutils_src_install
	dodoc docs/*.txt
	insinto /usr/share/doc/${PF}
	if use doc; then
		doins -r build/docs/html || die
		doins build/docs/latex/*.pdf || die
	fi
	if use examples; then
		doins -r examples || die
	fi
}