[gentoo-commits] repo/gentoo:master commit in: net-misc/miniupnpd/

[Michał Górny]

commit:     ed95db20162599e33f062aab3ca2019954bf8652
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May 14 06:22:34 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu May 14 06:22:34 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ed95db20

net-misc/miniupnpd: Bump to 2.1.20200510

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/miniupnpd/Manifest                      |  1 +
 net-misc/miniupnpd/miniupnpd-2.1.20200510.ebuild | 79 ++++++++++++++++++++++++
 2 files changed, 80 insertions(+)

diff --git a/net-misc/miniupnpd/Manifest b/net-misc/miniupnpd/Manifest
index a2d5175bf55..a9ff957550b 100644
--- a/net-misc/miniupnpd/Manifest
+++ b/net-misc/miniupnpd/Manifest
@@ -1 +1,2 @@
 DIST miniupnpd-2.1.20200329.tar.gz 243725 BLAKE2B a9ca048744bc8f397e10bcc5e27638285d0000700855952cce4c2ba7959b2c9099e18045bd5e9103c67da79c90d04a2e505e064bcb1bbca5574437d4625101a5 SHA512 3f6a1a6f08924505a6db5ca5b1dbf7c59f8b48647c59a600799b020146422497248367767e41df0715bd9774129f2d8f95c4a63493af2db849bbe006231e6edf
+DIST miniupnpd-2.1.20200510.tar.gz 245426 BLAKE2B 17b5335bb4cfb55a517c1f0aeb1eabd7515c729480ee737a8ba525988e59f067e18d2de78393df2ff62cc15201a742d17a17d5632601c1d98ea2a943dcc4a393 SHA512 36a5d1844075a93e76f13aba8820b3747bcc8f562c8cbcc562f991ac154e91c951b5caaa9b7c7066cf80534066c3ee6e20a066012b830143f0a7352cb9f5d71b

diff --git a/net-misc/miniupnpd/miniupnpd-2.1.20200510.ebuild b/net-misc/miniupnpd/miniupnpd-2.1.20200510.ebuild
new file mode 100644
index 00000000000..b208d8cce8f
--- /dev/null
+++ b/net-misc/miniupnpd/miniupnpd-2.1.20200510.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="MiniUPnP IGD Daemon"
+HOMEPAGE="http://miniupnp.free.fr/"
+SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+leasefile igd2 ipv6 nftables pcp-peer portinuse strict"
+
+RDEPEND="
+	dev-libs/gmp:0=
+	sys-apps/util-linux:=
+	dev-libs/openssl:0=
+	!nftables? (
+		>=net-firewall/iptables-1.4.6:0=[ipv6?]
+		net-libs/libnfnetlink:=
+		net-libs/libmnl:=
+	)
+	nftables? (
+		net-firewall/nftables
+		net-libs/libnftnl:=
+		net-libs/libmnl:=
+	)"
+DEPEND="${RDEPEND}
+	sys-apps/lsb-release"
+
+src_configure() {
+	local opts=(
+		--vendorcfg
+		$(usex igd2 '--igd2' '')
+		$(usex ipv6 '--ipv6' '')
+		$(usex leasefile '--leasefile' '')
+		$(usex portinuse '--portinuse' '')
+		$(usex pcp-peer '--pcp-peer' '')
+		$(usex strict '--strict' '')
+		--firewall=$(usex nftables nftables iptables)
+	)
+
+	# custom script
+	./configure "${opts[@]}" || die
+	# prevent gzipping manpage
+	sed -i -e '/gzip/d' Makefile || die
+}
+
+src_compile() {
+	# By default, it builds a bunch of unittests that are missing wrapper
+	# scripts in the tarball
+	emake CC="$(tc-getCC)" STRIP=true miniupnpd
+}
+
+src_install() {
+	emake PREFIX="${ED}" STRIP=true install
+
+	local confd_seds=()
+	if use nftables; then
+		confd_seds+=( -e 's/^iptables_scripts=/#&/' )
+	else
+		confd_seds+=( -e 's/^nftables_scripts=/#&/' )
+	fi
+	if ! use ipv6 || use nftables; then
+		confd_seds+=( -e 's/^ip6tables_scripts=/#&/' )
+	fi
+
+	newinitd "${FILESDIR}"/${PN}-init.d-r2 ${PN}
+	newconfd - ${PN} < <(sed "${confd_seds[@]}" \
+		"${FILESDIR}"/${PN}-conf.d-r2 || die)
+}
+
+pkg_postinst() {
+	elog "Please correct the external interface in the top of the two"
+	elog "scripts in /etc/miniupnpd and edit the config file in there too"
+}