[gentoo-commits] gentoo-x86 commit in net-irc/quassel: ChangeLog quassel-0.7_rc1.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    10/08/27 10:26:29

  Modified:             ChangeLog
  Added:                quassel-0.7_rc1.ebuild
  Log:
  Version bump to latest rc.
  
  (Portage version: 2.2_rc68/cvs/Linux x86_64)

Revision  Changes    Path
1.103                net-irc/quassel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/quassel/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/quassel/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/quassel/ChangeLog?r1=1.102&r2=1.103

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog	27 Aug 2010 10:20:48 -0000	1.102
+++ ChangeLog	27 Aug 2010 10:26:29 -0000	1.103
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/quassel
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v 1.102 2010/08/27 10:20:48 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/ChangeLog,v 1.103 2010/08/27 10:26:29 scarabeus Exp $
+
+*quassel-0.7_rc1 (27 Aug 2010)
+
+  27 Aug 2010; Tomáš Chvátal <scarabeus@g.o>
+  +quassel-0.7_rc1.ebuild:
+  Version bump to latest rc.
 
   27 Aug 2010; Tomáš Chvátal <scarabeus@g.o> quassel-9999.ebuild:
   Forgot to specify the src_uri too.



1.1                  net-irc/quassel/quassel-0.7_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/quassel/quassel-0.7_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/quassel/quassel-0.7_rc1.ebuild?rev=1.1&content-type=text/plain

Index: quassel-0.7_rc1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/quassel/quassel-0.7_rc1.ebuild,v 1.1 2010/08/27 10:26:29 scarabeus Exp $

EAPI=3

EGIT_REPO_URI="git://git.quassel-irc.org/quassel.git"
EGIT_BRANCH="master"
[[ "${PV}" == "9999" ]] && GIT_ECLASS="git"

QT_MINIMAL="4.6.0"
KDE_MINIMAL="4.4"

inherit cmake-utils eutils ${GIT_ECLASS}

DESCRIPTION="Qt4/KDE4 IRC client suppporting a remote daemon for 24/7 connectivity."
HOMEPAGE="http://quassel-irc.org/"
[[ "${PV}" == "9999" ]] || SRC_URI="http://quassel-irc.org/pub/${P/_/-}.tar.bz2"

LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86 ~amd64-linux"
SLOT="0"
IUSE="ayatana crypt dbus debug kde monolithic phonon postgres +server +ssl webkit X"

SERVER_RDEPEND="
	crypt? ( app-crypt/qca:2 )
	!postgres? ( >=x11-libs/qt-sql-${QT_MINIMAL}:4[sqlite] dev-db/sqlite[threadsafe] )
	postgres? ( >=x11-libs/qt-sql-${QT_MINIMAL}:4[postgres] )
	x11-libs/qt-script:4
"

GUI_RDEPEND="
	>=x11-libs/qt-gui-${QT_MINIMAL}:4
	ayatana? ( dev-libs/libindicate-qt )
	dbus? (
		>=x11-libs/qt-dbus-${QT_MINIMAL}:4
		dev-libs/libdbusmenu-qt
	)
	kde? (
		>=kde-base/kdelibs-${KDE_MINIMAL}
		>=kde-base/oxygen-icons-${KDE_MINIMAL}
		ayatana? ( kde-misc/plasma-widget-message-indicator )
	)
	phonon? ( || ( media-sound/phonon >=x11-libs/qt-phonon-${QT_MINIMAL} ) )
	webkit? ( >=x11-libs/qt-webkit-${QT_MINIMAL}:4 )
"

RDEPEND="
	monolithic? (
		${SERVER_RDEPEND}
		${GUI_RDEPEND}
	)
	!monolithic? (
		server? ( ${SERVER_RDEPEND} )
		X? ( ${GUI_RDEPEND} )
	)
	ssl? ( x11-libs/qt-core:4[ssl] )
	!monolithic? (
		!server? (
			!X? (
				${SERVER_RDEPEND}
				${GUI_RDEPEND}
			)
		)
	)
	"
DEPEND="${RDEPEND}"

DOCS="AUTHORS ChangeLog README"

pkg_setup() {
	if ! use monolithic && ! use server && ! use X ; then
		ewarn "You have to build at least one of the monolithic client (USE=monolithic),"
		ewarn "the quasselclient (USE=X) or the quasselcore (USE=server)."
		echo
		ewarn "Enabling monolithic by default."
		FORCED_MONO="yes"
	fi

	if use server; then
		QUASSEL_DIR=/var/lib/${PN}
		QUASSEL_USER=${PN}
		# create quassel:quassel user
		enewgroup "${QUASSEL_USER}"
		enewuser "${QUASSEL_USER}" -1 -1 "${QUASSEL_DIR}" "${QUASSEL_USER}"
	fi
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with ayatana LIBINDICATE)
		$(cmake-utils_use_want X QTCLIENT)
		$(cmake-utils_use_want server CORE)
		$(cmake-utils_use_want monolithic MONO)
		$(cmake-utils_use_with webkit)
		$(cmake-utils_use_with phonon)
		$(cmake-utils_use_with kde)
		$(cmake-utils_use_with dbus)
		$(cmake-utils_use_with ssl OPENSSL)
		$(cmake-utils_use_with !kde OXYGEN)
		$(cmake-utils_use_with crypt)
		"-DEMBED_DATA=OFF"
	)

	[[ ${FORCED_MONO} == "yes" ]] && mycmakeargs+=( '-DWANT_MONO=ON' )

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use server ; then
		# prepare folders in /var/
		keepdir "${QUASSEL_DIR}"
		fowners "${QUASSEL_USER}":"${QUASSEL_USER}" "${QUASSEL_DIR}"

		# init scripts
		newinitd "${FILESDIR}"/quasselcore.init quasselcore || die "newinitd failed"
		newconfd "${FILESDIR}"/quasselcore.conf quasselcore || die "newconfd failed"

		# logrotate
		insinto /etc/logrotate.d
		newins "${FILESDIR}/quassel.logrotate" quassel || die "newins failed"
	fi
}

pkg_postinst() {
	if ( use monolithic || [[ "${FORCED_MONO}" == "yes" ]] ) && use ssl ; then
		elog "Information on how to enable SSL support for client/core connections"
		elog "is available at http://bugs.quassel-irc.org/wiki/quassel-irc."
	fi

	if use server; then
		einfo "If you want to generate SSL certificate remember to run:"
		einfo "	emerge --config =${CATEGORY}/${PF}"
	fi

	# temporary info mesage
	if use server; then
		echo
		ewarn "Please note that all configuration moved from"
		ewarn "/home/\${QUASSEL_USER}/.config/quassel-irc.org/"
		ewarn "to: ${QUASSEL_DIR}."
		echo
		ewarn "For migration, stop the core, move quasselcore files (pretty	much"
		ewarn "everything apart from quasselclient.conf and settings.qss) into"
		ewarn "new location and then start server again."
	fi
}

pkg_config() {
	if use server && use ssl; then
		# generate the pem file only when it does not already exist
		if [ ! -f "${QUASSEL_DIR}/quasselCert.pem" ]; then
			einfo "Generating QUASSEL SSL certificate to: \"${QUASSEL_DIR}/quasselCert.pem\""
			openssl req -x509 -nodes -days 365 -newkey rsa:2048 \
				-keyout "${QUASSEL_DIR}/quasselCert.pem" \
				-out "${QUASSEL_DIR}/quasselCert.pem"
			# permissions for the key
			chown ${QUASSEL_USER}:${QUASSEL_USER} "${QUASSEL_DIR}/quasselCert.pem"
			chmod 400 "${QUASSEL_DIR}/quasselCert.pem"
		else
			einfo "Certificate \"${QUASSEL_DIR}/quasselCert.pem\" already exists."
			einfo "Remove it if you want to create new one."
		fi
	fi
}