[gentoo-commits] repo/gentoo:master commit in: net-irc/weechat/

[Georgy Yakovlev]

commit:     1f0bb3aa21757135549fcaf80b49b9da72e7c87e
Author:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  3 01:16:28 2021 +0000
Commit:     Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Wed Feb  3 01:16:28 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f0bb3aa

net-irc/weechat: bump to 3.0.1

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>

 net-irc/weechat/Manifest             |   1 +
 net-irc/weechat/weechat-3.0.1.ebuild | 170 +++++++++++++++++++++++++++++++++++
 2 files changed, 171 insertions(+)

diff --git a/net-irc/weechat/Manifest b/net-irc/weechat/Manifest
index c385b00ca39..0b617bc913e 100644
--- a/net-irc/weechat/Manifest
+++ b/net-irc/weechat/Manifest
@@ -1,2 +1,3 @@
 DIST weechat-2.9.tar.xz 2206584 BLAKE2B 8089cd846ca192ec666a50e8071ed57e1c2518b2d5ea98733b8e3fa6c8c684e8ed14253d787b3f9995a8f481a7413444c3ba262dcb6c100283192bcafb502627 SHA512 c4a5723accb417c0496b5427ee58fbf5d3e842e6d79a7988f8680cd605534cfc9d30f6f4844afe45f5223458f28b8deff1284fff2fb5b7d04cb99a81cde4e13e
+DIST weechat-3.0.1.tar.xz 2215312 BLAKE2B 204c110259528c485a832a750a34c6b408e24c9b9c9797d41e2e2bfd5e33dcd4aa7c80c4478e8825155363048306a48bcbc61469813b9a82247c6cbffcc385a7 SHA512 d5b2949b668f622c08d60764aa230f8a4901d358facf83ab13428709854b173830aafe65fec86abacbea08ffe89e6e34131a5e4de37bbb5409454fa223f7885e
 DIST weechat-3.0.tar.xz 2215408 BLAKE2B ed43c16af2a9fea101b54714e21d5f28f2b18fed5734c5f6adde857500befd94089f6bd7be5e2ad2738fce4e1bd5b10ebef32d0d46039242efaa2dc7f664eb42 SHA512 d6a68f35dc7363b838af811ff0a0a8d9fff519a4231c66f963e896bdda8653a56608e46333dc866e7dee25c1eafd2f1bf99c443089dde5a268bba637a0dee8ca

diff --git a/net-irc/weechat/weechat-3.0.1.ebuild b/net-irc/weechat/weechat-3.0.1.ebuild
new file mode 100644
index 00000000000..f8abf272aff
--- /dev/null
+++ b/net-irc/weechat/weechat-3.0.1.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} )
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit cmake lua-single python-single-r1 xdg-utils
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/weechat/weechat.git"
+else
+	SRC_URI="https://weechat.org/files/src/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Portable and multi-interface IRC client"
+HOMEPAGE="https://weechat.org/"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+NETWORKS="+irc"
+PLUGINS="+alias +buflist +charset +exec +fifo +fset +logger +relay +scripts +spell +trigger +xfer"
+# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
+SCRIPT_LANGS="guile lua +perl php +python ruby tcl"
+LANGS=" cs de es fr it ja pl ru"
+IUSE="doc man nls test ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
+
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( nls )
+"
+
+RDEPEND="
+	dev-libs/libgcrypt:0=
+	net-libs/gnutls:=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:=
+	net-misc/curl[ssl]
+	charset? ( virtual/libiconv )
+	guile? ( >=dev-scheme/guile-2.0 )
+	lua? ( ${LUA_DEPS} )
+	nls? ( virtual/libintl )
+	perl? ( dev-lang/perl:= )
+	php? ( >=dev-lang/php-7.0:*[embed] )
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( || ( dev-lang/ruby:2.7 dev-lang/ruby:2.6 dev-lang/ruby:2.5 ) )
+	spell? ( app-text/aspell )
+	tcl? ( >=dev-lang/tcl-8.4.15:0= )
+"
+
+DEPEND="${RDEPEND}
+	test? ( dev-util/cpputest )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( >=dev-ruby/asciidoctor-1.5.4 )
+	man? ( >=dev-ruby/asciidoctor-1.5.4 )
+	nls? ( >=sys-devel/gettext-0.15 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0-cmake_lua_version.patch
+)
+
+DOCS="AUTHORS.adoc ChangeLog.adoc Contributing.adoc ReleaseNotes.adoc README.adoc"
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# install only required translations
+	local i
+	for i in ${LANGS} ; do
+		if ! has ${i} ${LINGUAS-${i}} ; then
+			sed -i \
+				-e "/${i}.po/d" \
+				po/CMakeLists.txt || die
+		fi
+	done
+
+	# install only required documentation ; en always
+	for i in $(grep add_subdirectory doc/CMakeLists.txt \
+			| sed -e 's/.*add_subdirectory(\(..\)).*/\1/' -e '/en/d'); do
+		if ! has ${i} ${LINGUAS-${i}} ; then
+			sed -i \
+				-e '/add_subdirectory('${i}')/d' \
+				doc/CMakeLists.txt || die
+		fi
+	done
+
+	# install docs in correct directory
+	sed -i "s#\${SHAREDIR}/doc/\${PROJECT_NAME}#\0-${PV}/html#" doc/*/CMakeLists.txt || die
+
+	if [[ ${CHOST} == *-darwin* ]]; then
+		# fix linking error on Darwin
+		sed -i "s/+ get_config_var('LINKFORSHARED')//" \
+			cmake/FindPython.cmake || die
+		# allow to find the plugins by default
+		sed -i 's/".so,.dll"/".bundle,.so,.dll"/' \
+			src/core/wee-config.c || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLIBDIR=/usr/$(get_libdir)
+		-DENABLE_JAVASCRIPT=OFF
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_NCURSES=ON
+		-DENABLE_ALIAS=$(usex alias)
+		-DENABLE_BUFLIST=$(usex buflist)
+		-DENABLE_CHARSET=$(usex charset)
+		-DENABLE_DOC=$(usex doc)
+		-DENABLE_EXEC=$(usex exec)
+		-DENABLE_FIFO=$(usex fifo)
+		-DENABLE_FSET=$(usex fset)
+		-DENABLE_GUILE=$(usex guile)
+		-DENABLE_IRC=$(usex irc)
+		-DENABLE_LOGGER=$(usex logger)
+		-DENABLE_LUA=$(usex lua)
+		-DENABLE_MAN=$(usex man)
+		-DENABLE_NLS=$(usex nls)
+		-DENABLE_PERL=$(usex perl)
+		-DENABLE_PHP=$(usex php)
+		-DENABLE_PYTHON=$(usex python)
+		-DENABLE_RELAY=$(usex relay)
+		-DENABLE_RUBY=$(usex ruby)
+		-DENABLE_SCRIPT=$(usex scripts)
+		-DENABLE_SCRIPTS=$(usex scripts)
+		-DENABLE_SPELL=$(usex spell)
+		-DENABLE_TCL=$(usex tcl)
+		-DENABLE_TESTS=$(usex test)
+		-DENABLE_TRIGGER=$(usex trigger)
+		-DENABLE_XFER=$(usex xfer)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	if $(locale -a | grep -iq "en_US\.utf.*8"); then
+		cmake_src_test -V
+	else
+		eerror "en_US.UTF-8 locale is required to run ${PN}'s ${FUNCNAME}"
+		die "required locale missing"
+	fi
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}