[gentoo-commits] gentoo-x86 commit in sys-devel/automake: ChangeLog automake-9999.ebuild

[Mike Frysinger (vapier)]

vapier      07/11/02 06:17:52

  Modified:             ChangeLog
  Added:                automake-9999.ebuild
  Log:
  Add support for git.
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.107                sys-devel/automake/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?rev=1.107&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?rev=1.107&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?r1=1.106&r2=1.107

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v
retrieving revision 1.106
retrieving revision 1.107
diff -u -r1.106 -r1.107
--- ChangeLog	8 Sep 2007 06:46:28 -0000	1.106
+++ ChangeLog	2 Nov 2007 06:17:52 -0000	1.107
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/automake
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v 1.106 2007/09/08 06:46:28 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v 1.107 2007/11/02 06:17:52 vapier Exp $
+
+*automake-9999 (02 Nov 2007)
+
+  02 Nov 2007; Mike Frysinger <vapier@g.o> +automake-9999.ebuild:
+  Add support for git.
 
   08 Sep 2007; Mike Frysinger <vapier@g.o>
   +files/automake-1.6.3-test-fixes.patch,



1.1                  sys-devel/automake/automake-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/automake-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/automake-9999.ebuild?rev=1.1&content-type=text/plain

Index: automake-9999.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/automake-9999.ebuild,v 1.1 2007/11/02 06:17:52 vapier Exp $

EGIT_REPO_URI="git://git.savannah.gnu.org/automake.git"

inherit eutils git

DESCRIPTION="Used to generate Makefile.in from Makefile.am"
HOMEPAGE="http://sources.redhat.com/automake/"
SRC_URI=""

LICENSE="GPL-3"
SLOT="${PV:0:4}"
KEYWORDS=""
IUSE=""

RDEPEND="dev-lang/perl
	>=sys-devel/automake-wrapper-2
	>=sys-devel/autoconf-2.60
	>=sys-apps/texinfo-4.7
	sys-devel/gnuconfig"
DEPEND="${RDEPEND}
	sys-apps/help2man"

src_unpack() {
	git_src_unpack
	cd "${S}"
	sed -i \
		-e "s|: (automake)| v${SLOT}: (automake${SLOT})|" \
		doc/automake.texi || die "sed failed"
	export WANT_AUTOCONF=2.5
}

src_compile() {
	econf --docdir=/usr/share/doc/${PF} || die
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc NEWS README THANKS TODO AUTHORS ChangeLog

	# SLOT the docs and junk
	local x
	for x in aclocal automake ; do
		help2man ./${x} > ${x}-${SLOT}.1
		doman ${x}-${SLOT}.1
		rm -f "${D}"/usr/bin/${x}
	done
	cd "${D}"/usr/share/info || die
	for x in *.info* ; do
		mv "${x}" "${x/${PN}/${PN}${SLOT}}" || die
	done

	# remove all config.guess and config.sub files replacing them
	# w/a symlink to a specific gnuconfig version
	for x in guess sub ; do
		dosym ../gnuconfig/config.${x} /usr/share/${PN}-${SLOT}/config.${x}
	done
}



-- 
gentoo-commits@g.o mailing list