[gentoo-commits] gentoo-x86 commit in kde-base/systemsettings: systemsettings-4.11.21.ebuild ChangeLog

[Manuel Rueger (mrueg)]

mrueg       15/07/02 13:23:00

  Modified:             ChangeLog
  Added:                systemsettings-4.11.21.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.285                kde-base/systemsettings/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?rev=1.285&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?rev=1.285&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/ChangeLog?r1=1.284&r2=1.285

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v
retrieving revision 1.284
retrieving revision 1.285
diff -u -r1.284 -r1.285
--- ChangeLog	13 Jun 2015 08:34:12 -0000	1.284
+++ ChangeLog	2 Jul 2015 13:23:00 -0000	1.285
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/systemsettings
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.284 2015/06/13 08:34:12 zlogene Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.285 2015/07/02 13:23:00 mrueg Exp $
+
+*systemsettings-4.11.21 (02 Jul 2015)
+
+  02 Jul 2015; Manuel Rüger <mrueg@g.o> +systemsettings-4.11.21.ebuild:
+  Version bump.
 
   13 Jun 2015; Mikle Kolyada <zlogene@g.o> systemsettings-4.11.19.ebuild:
   x86 stable wrt bug #550740



1.1                  kde-base/systemsettings/systemsettings-4.11.21.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.21.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.21.ebuild?rev=1.1&content-type=text/plain

Index: systemsettings-4.11.21.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/systemsettings-4.11.21.ebuild,v 1.1 2015/07/02 13:23:00 mrueg Exp $

EAPI=5

KDE_HANDBOOK="optional"
KMNAME="kde-workspace"
OPENGL_REQUIRED="optional"
VIRTUALX_REQUIRED="test"
VIRTUALDBUS_TEST="true"
inherit kde4-meta

DESCRIPTION="System settings utility"
HOMEPAGE+=" http://userbase.kde.org/System_Settings"
IUSE="debug gtk +kscreen nepomuk +usb"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"

COMMONDEPEND="
	app-misc/strigi
	dev-libs/glib:2
	$(add_kdebase_dep kwin)
	$(add_kdebase_dep libkworkspace)
	media-libs/fontconfig
	>=media-libs/freetype-2
	>=x11-libs/libxklavier-3.2
	x11-libs/libX11
	x11-libs/libXcursor
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXft
	x11-libs/libXi
	x11-libs/libxkbfile
	x11-libs/libXrandr
	x11-libs/libXtst
	opengl? ( virtual/opengl )
	usb? ( virtual/libusb:0 )
"
DEPEND="${COMMONDEPEND}
	x11-proto/kbproto
	x11-proto/xextproto
"
RDEPEND="${COMMONDEPEND}
	sys-libs/timezone-data
	x11-apps/setxkbmap
	x11-misc/xkeyboard-config
	gtk? ( kde-misc/kde-gtk-config )
	kscreen? ( kde-misc/kscreen:4 )
	nepomuk? ( $(add_kdeapps_dep nepomuk) )
"

KMEXTRA="
	kcontrol/
"
KMEXTRACTONLY="
	krunner/dbus/org.kde.krunner.App.xml
	krunner/dbus/org.kde.screensaver.xml
	ksmserver/screenlocker/dbus/org.kde.screensaver.xml
	kwin/
	libs/
	plasma/
"
# fails to connect to a kded instance
RESTRICT="test"

PATCHES=( "${FILESDIR}/${PN}-kcm-randr.patch" )

src_unpack() {
	if use handbook; then
		KMEXTRA+="
			doc/kcontrol
			doc/kfontview
		"
	fi

	kde4-meta_src_unpack
}

src_prepare() {
	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
		systemsettings/CMakeLists.txt \
		|| die "Failed to fix systemsettingsrc install location"

	kde4-meta_src_prepare
}

# FIXME: is have_openglxvisual found without screensaver
src_configure() {
	# Old keyboard-detection code is unmaintained,
	# so we force the new stuff, using libxklavier.
	local mycmakeargs=(
		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
		-DWITH_GLIB2=ON -DWITH_GObject=ON
		-DBUILD_KCM_RANDR=$(usex !kscreen)
		$(cmake-utils_use_with opengl OpenGL)
		$(cmake-utils_use_with usb)
	)

	kde4-meta_src_configure
}