[gentoo-commits] gentoo-x86 commit in dev-util/mercurial: ChangeLog mercurial-0.9.5.ebuild

[Andrew Ross (aross)]

aross       07/11/07 10:57:52

  Modified:             ChangeLog
  Added:                mercurial-0.9.5.ebuild
  Log:
  Version bump (bug #196713).
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.58                 dev-util/mercurial/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/mercurial/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/mercurial/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/mercurial/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/mercurial/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	7 Nov 2007 09:53:49 -0000	1.57
+++ ChangeLog	7 Nov 2007 10:57:51 -0000	1.58
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/mercurial
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/mercurial/ChangeLog,v 1.57 2007/11/07 09:53:49 aross Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/mercurial/ChangeLog,v 1.58 2007/11/07 10:57:51 aross Exp $
+
+*mercurial-0.9.5 (07 Nov 2007)
+
+  07 Nov 2007; Andrew Ross <aross@g.o> +mercurial-0.9.5.ebuild:
+  Version bump (bug #196713).
 
   07 Nov 2007; Andrew Ross <aross@g.o> mercurial-0.9.1-r2.ebuild:
   Fix quoting issues caught by repoman.



1.1                  dev-util/mercurial/mercurial-0.9.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/mercurial/mercurial-0.9.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/mercurial/mercurial-0.9.5.ebuild?rev=1.1&content-type=text/plain

Index: mercurial-0.9.5.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/mercurial/mercurial-0.9.5.ebuild,v 1.1 2007/11/07 10:57:51 aross Exp $

inherit bash-completion distutils elisp-common flag-o-matic

DESCRIPTION="Scalable distributed SCM"
HOMEPAGE="http://www.selenic.com/mercurial/"
SRC_URI="http://www.selenic.com/mercurial/release/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bugzilla cvs darcs emacs git gpg subversion test zsh-completion"

CDEPEND=">=dev-lang/python-2.3"
RDEPEND="${CDEPEND}
	bugzilla? ( dev-python/mysql-python )
	cvs? ( dev-util/cvs )
	darcs? ( || ( dev-python/celementtree dev-python/elementtree ) )
	git? ( dev-util/git )
	gpg? ( app-crypt/gnupg )
	subversion? ( dev-util/subversion )
	zsh-completion? ( app-shells/zsh )"
DEPEND="${CDEPEND}
	emacs? ( virtual/emacs )
	test? ( app-arch/unzip )"

PYTHON_MODNAME="${PN} hgext"
SITEFILE="70${PN}-gentoo.el"

src_compile() {
	filter-flags -ftracer -ftree-vectorize

	distutils_src_compile

	if use emacs; then
		cd "${S}"/contrib
		elisp-compile mercurial.el || die "elisp-compile failed!"
	fi

	rm -rf contrib/{win32,macosx}
}

src_install() {
	distutils_src_install

	dobashcompletion contrib/bash_completion ${PN}

	if use zsh-completion ; then
		insinto /usr/share/zsh/site-functions
		newins contrib/zsh_completion _hg
	fi

	dodoc CONTRIBUTORS PKG-INFO README *.txt
	cp hgweb*.cgi "${D}"/usr/share/doc/${PF}/
	rm -f contrib/bash_completion
	cp -r contrib "${D}"/usr/share/doc/${PF}/
	doman doc/*.?

	if use emacs; then
		elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
		elisp-site-file-install "${FILESDIR}"/${SITEFILE}
	fi
}

pkg_postinst() {
	distutils_pkg_postinst
	use emacs && elisp-site-regen
	bash-completion_pkg_postinst
}

pkg_postrm() {
	distutils_pkg_postrm
	use emacs && elisp-site-regen
}



-- 
gentoo-commits@g.o mailing list