[gentoo-commits] repo/gentoo:master commit in: dev-qt/qtcore/

[Andreas Sturmlechner]

commit:     0dcf5b3010ab33e7f058ea910b3798f47d7a040d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 13 14:14:09 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Oct 13 15:01:37 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0dcf5b30

dev-qt/qtcore: Drop 5.15.1 (r0)

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-qt/qtcore/qtcore-5.15.1.ebuild | 100 -------------------------------------
 1 file changed, 100 deletions(-)

diff --git a/dev-qt/qtcore/qtcore-5.15.1.ebuild b/dev-qt/qtcore/qtcore-5.15.1.ebuild
deleted file mode 100644
index 449fddfc065..00000000000
--- a/dev-qt/qtcore/qtcore-5.15.1.ebuild
+++ /dev/null
@@ -1,100 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-QT5_MODULE="qtbase"
-inherit linux-info qt5-build
-
-DESCRIPTION="Cross-platform application development framework"
-SLOT=5/$(ver_cut 1-3)
-
-if [[ ${QT5_BUILD_TYPE} == release ]]; then
-	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
-fi
-
-IUSE="icu old-kernel systemd"
-
-DEPEND="
-	dev-libs/double-conversion:=
-	dev-libs/glib:2
-	dev-libs/libpcre2[pcre16,unicode]
-	sys-libs/zlib:=
-	icu? ( dev-libs/icu:= )
-	!icu? ( virtual/libiconv )
-	systemd? ( sys-apps/systemd:= )
-"
-RDEPEND="${DEPEND}
-	!<dev-qt/qtcore-4.8.7-r4:4
-"
-
-QT5_TARGET_SUBDIRS=(
-	src/tools/bootstrap
-	src/tools/moc
-	src/tools/rcc
-	src/corelib
-	src/tools/qlalr
-	doc
-)
-
-QT5_GENTOO_PRIVATE_CONFIG=(
-	!:network
-	!:sql
-	!:testlib
-	!:xml
-)
-
-PATCHES=( "${FILESDIR}/${PN}-5.14.1-cmake-macro-backward-compat.patch" ) # bug 703306
-
-pkg_pretend() {
-	use kernel_linux || return
-	get_running_version
-	if kernel_is -lt 4 11 && ! use old-kernel; then
-		ewarn "The running kernel is older than 4.11. USE=old-kernel is needed for"
-		ewarn "dev-qt/qtcore to function on this kernel properly. Bugs #669994, #672856"
-	fi
-}
-
-src_prepare() {
-	# don't add -O3 to CXXFLAGS, bug 549140
-	sed -i -e '/CONFIG\s*+=/s/optimize_full//' src/corelib/corelib.pro || die
-
-	# fix missing qt_version_tag symbol w/ LTO, bug 674382
-	sed -i -e 's/^gcc:ltcg/gcc/' src/corelib/global/global.pri || die
-
-	qt5-build_src_prepare
-}
-
-src_configure() {
-	local myconf=(
-		$(qt_use icu)
-		$(qt_use !icu iconv)
-		$(qt_use systemd journald)
-	)
-	use old-kernel && myconf+=(
-		-no-feature-renameat2 # needs Linux 3.16, bug 669994
-		-no-feature-getentropy # needs Linux 3.17, bug 669994
-		-no-feature-statx # needs Linux 4.11, bug 672856
-	)
-	qt5-build_src_configure
-}
-
-src_install() {
-	qt5-build_src_install
-
-	local flags=(
-		DBUS FREETYPE IMAGEFORMAT_JPEG IMAGEFORMAT_PNG
-		OPENGL OPENSSL SSL WIDGETS
-	)
-
-	for flag in ${flags[@]}; do
-		cat >> "${D}"/${QT5_HEADERDIR}/QtCore/qconfig.h <<- _EOF_ || die
-
-			#if defined(QT_NO_${flag}) && defined(QT_${flag})
-			# undef QT_NO_${flag}
-			#elif !defined(QT_NO_${flag}) && !defined(QT_${flag})
-			# define QT_NO_${flag}
-			#endif
-		_EOF_
-	done
-}