[gentoo-commits] gentoo-x86 commit in net-misc/chrony: ChangeLog chrony-1.30.ebuild chrony-1.30_pre1.ebuild

[Jeroen Roovers (jer)]

jer         14/07/04 13:41:32

  Modified:             ChangeLog
  Added:                chrony-1.30.ebuild
  Removed:              chrony-1.30_pre1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.133                net-misc/chrony/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.133&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.133&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?r1=1.132&r2=1.133

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v
retrieving revision 1.132
retrieving revision 1.133
diff -u -r1.132 -r1.133
--- ChangeLog	7 Jun 2014 12:42:55 -0000	1.132
+++ ChangeLog	4 Jul 2014 13:41:31 -0000	1.133
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/chrony
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.132 2014/06/07 12:42:55 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.133 2014/07/04 13:41:31 jer Exp $
+
+*chrony-1.30 (04 Jul 2014)
+
+  04 Jul 2014; Jeroen Roovers <jer@g.o> -chrony-1.30_pre1.ebuild,
+  +chrony-1.30.ebuild:
+  Version bump.
 
   07 Jun 2014; Jeroen Roovers <jer@g.o> chrony-1.30_pre1.ebuild:
   RESTRICT=test for compile failure/downloading.



1.1                  net-misc/chrony/chrony-1.30.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.30.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.30.ebuild?rev=1.1&content-type=text/plain

Index: chrony-1.30.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/chrony-1.30.ebuild,v 1.1 2014/07/04 13:41:32 jer Exp $

EAPI=5
inherit eutils systemd toolchain-funcs

DESCRIPTION="NTP client and server programs"
HOMEPAGE="http://chrony.tuxfamily.org/"
SRC_URI="http://download.tuxfamily.org/${PN}/${P/_/-}.tar.gz"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~sparc ~x86"
IUSE="caps ipv6 +readline +rtc selinux"

RDEPEND="
	caps? ( sys-libs/libcap )
	readline? ( >=sys-libs/readline-4.1-r4 )
	selinux? ( sec-policy/selinux-chronyd )
"
DEPEND="
	${RDEPEND}
	sys-apps/texinfo
"

RESTRICT=test

S="${WORKDIR}/${P/_/-}"

src_prepare() {
	sed -i \
		-e 's:/etc/chrony\.:/etc/chrony/chrony.:g' \
		-e 's:/var/run:/run:g' \
		conf.c chrony.texi.in chrony.txt examples/* FAQ || die
}

src_configure() {
	tc-export CC

	# not an autotools generated script
	./configure \
		$(usex caps '' --disable-linuxcaps) \
		$(usex ipv6 '' --disable-ipv6) \
		$(usex readline '' --disable-readline) \
		$(usex rtc '' --disable-rtc) \
		--docdir=/usr/share/doc/${PF} \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man \
		--prefix=/usr \
		--sysconfdir=/etc/chrony \
		--without-nss \
		--without-tomcrypt \
		${EXTRA_ECONF} \
		|| die
}

src_compile() {
	emake all docs
}

src_install() {
	default
	rm "${D}"/usr/share/doc/${PF}/COPYING || die
	doinfo chrony.info*

	newinitd "${FILESDIR}"/chronyd.init chronyd
	newconfd "${FILESDIR}"/chronyd.conf chronyd

	insinto /etc/${PN}
	newins examples/chrony.conf.example chrony.conf
	newins examples/chrony.keys.example chrony.keys

	keepdir /var/{lib,log}/chrony

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/chrony.logrotate chrony

	systemd_newunit "${FILESDIR}"/chronyd.service-r1 chronyd.service
	systemd_enable_ntpunit 50-chrony chronyd.service
}