1 |
commit: 45f27e6d51513385dcba2e5d13d4a4ef49a34dd7 |
2 |
Author: Michał Górny <mgorny <AT> gentoo <DOT> org> |
3 |
AuthorDate: Wed Aug 3 16:17:19 2022 +0000 |
4 |
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org> |
5 |
CommitDate: Wed Aug 3 16:23:08 2022 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45f27e6d |
7 |
|
8 |
dev-python/django: Bump to 3.2.15 |
9 |
|
10 |
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org> |
11 |
|
12 |
dev-python/django/Manifest | 2 + |
13 |
dev-python/django/django-3.2.15.ebuild | 109 +++++++++++++++++++++++++++++++++ |
14 |
2 files changed, 111 insertions(+) |
15 |
|
16 |
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest |
17 |
index 6f783159de2d..47ef69b43c53 100644 |
18 |
--- a/dev-python/django/Manifest |
19 |
+++ b/dev-python/django/Manifest |
20 |
@@ -1,5 +1,7 @@ |
21 |
DIST Django-3.2.14.checksum.txt 2552 BLAKE2B 8949b6bbc05160539ba26e4a9a2b774e450890b1668ee9794b087e97c772a78e010f0f33d7f15b9b43fb749bc7804a6c9ea7f24125b6f93c8af6d408d29e530d SHA512 84de32c72c72f2dd8d7c5e159fb77d82b04fe3cb66f30e808249eb1778305f29c75569c3ebf7e89ffdeca12a68a6f8334830db202f230901ddff1f47a3b03b8f |
22 |
DIST Django-3.2.14.tar.gz 9814965 BLAKE2B d2081621598ca9743b056b752775d8fe87748e7e0ad4e252f9bb0d50bbdd942cf5908aafc7757668a5dd041aafecd94f63b38441e4dbb8e1810babde1aaec436 SHA512 daa18a0a64870789af4627b1cd345fef66d4b227d71cbd9b4766332728c37e3fb17472924c290851f8bc2111efe90c5e22eebf9b6f7a26e77bdc8edaa8e42e16 |
23 |
+DIST Django-3.2.15.checksum.txt 2560 BLAKE2B 35a4f28005a07cee0b667ec55838d846cb7f1970be41ce08f2191992b1247263f7632bb9dcaa3d20f9df4e050b370416a2a9af6f0e5cc3523484016161a7a47e SHA512 b3d00d18e14be7dec77901ddd8818b41e2b592dbafb2c66b314478f0b2ac0f8486ce41a73a71da9bed4d9ad92a6d6bf21765ede79055c1fb2a9972e3f16cfac7 |
24 |
+DIST Django-3.2.15.tar.gz 9833828 BLAKE2B 4b914b1e3c192340d9a1bbd68b7d3bf3d1c1b3f41da6e4a67149e811a2312f646e2ced83af23ae035cf590e526dad00537aa5b4aee14a657f6952675eca94b30 SHA512 fccdad52d39c8757972d5e987b94b13d8ce5ce08ad480ef79407b0d9b88cff69336770409cbe18ce9529bf10966ad63105a0b0f1ffe39b681a41be3718ec886b |
25 |
DIST Django-4.0.6.checksum.txt 2543 BLAKE2B 4d38a86dc468f1cf9553557073fa6d5aad6875739c5cd3e50dd79954254dc25a0345b32fc771f4db3d566858c58b48d4f0fba434903eae0e0709666627b5e38c SHA512 b701e13371bdc00b61e7ff7f5a2b2d39a9d703616ce79640700e53a252f8aefd8bbf5560b082420bd4ff921110a44ac6a353c61db664b0ee899905d5cf65de59 |
26 |
DIST Django-4.0.6.tar.gz 10389543 BLAKE2B c458b2b2a782d95771df00ed529d4b0ef0f42720f19258d32ea955e90806b61aabf03a5eb39a7a36c5d220af32dd35e78244db4d17a3f074601952905fd5e0fa SHA512 1050511bd9345519d8382a58e4e6ccc39cd41a6777c9575540dcc655f11dd36316cfc2431f94da9ac4a0fa6e41640a9131c8d49df4188a2ffc26f7ff56d40a6a |
27 |
DIST Django-4.0.7.checksum.txt 2551 BLAKE2B 6fa44707d33af485d3c55096dcc650b4e2384421c57c30cedee9f9577488783836a3ad8261dceaf5c718c1a5fcbe5852b081596525b22639c310c9aa6e86c639 SHA512 4b2453be8090c2a9d48bbe34f6e5dd55859b9debc3a116519c69da39d04ecca202e6da62ae9114790a9da8c55cfcfe176a972bb25576305a8e23736e2e063e3e |
28 |
|
29 |
diff --git a/dev-python/django/django-3.2.15.ebuild b/dev-python/django/django-3.2.15.ebuild |
30 |
new file mode 100644 |
31 |
index 000000000000..3065555963a8 |
32 |
--- /dev/null |
33 |
+++ b/dev-python/django/django-3.2.15.ebuild |
34 |
@@ -0,0 +1,109 @@ |
35 |
+# Copyright 1999-2022 Gentoo Authors |
36 |
+# Distributed under the terms of the GNU General Public License v2 |
37 |
+ |
38 |
+EAPI=8 |
39 |
+ |
40 |
+DISTUTILS_USE_PEP517=setuptools |
41 |
+PYTHON_COMPAT=( python3_{8..10} ) |
42 |
+PYTHON_REQ_USE='sqlite?,threads(+)' |
43 |
+ |
44 |
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig |
45 |
+ |
46 |
+MY_P=${P^} |
47 |
+DESCRIPTION="High-level Python web framework" |
48 |
+HOMEPAGE=" |
49 |
+ https://www.djangoproject.com/ |
50 |
+ https://pypi.org/project/Django/ |
51 |
+" |
52 |
+SRC_URI=" |
53 |
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz |
54 |
+ verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt ) |
55 |
+" |
56 |
+S="${WORKDIR}/${MY_P}" |
57 |
+ |
58 |
+LICENSE="BSD" |
59 |
+# admin fonts: Roboto (media-fonts/roboto) |
60 |
+LICENSE+=" Apache-2.0" |
61 |
+# admin icons, jquery, xregexp.js |
62 |
+LICENSE+=" MIT" |
63 |
+SLOT="0" |
64 |
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos" |
65 |
+IUSE="doc sqlite test" |
66 |
+RESTRICT="!test? ( test )" |
67 |
+ |
68 |
+RDEPEND=" |
69 |
+ >=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}] |
70 |
+ dev-python/pytz[${PYTHON_USEDEP}] |
71 |
+ >=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}] |
72 |
+" |
73 |
+BDEPEND=" |
74 |
+ test? ( |
75 |
+ $(python_gen_impl_dep sqlite) |
76 |
+ ${RDEPEND} |
77 |
+ dev-python/docutils[${PYTHON_USEDEP}] |
78 |
+ dev-python/jinja[${PYTHON_USEDEP}] |
79 |
+ dev-python/numpy[${PYTHON_USEDEP}] |
80 |
+ dev-python/pillow[webp,${PYTHON_USEDEP}] |
81 |
+ dev-python/pyyaml[${PYTHON_USEDEP}] |
82 |
+ dev-python/selenium[${PYTHON_USEDEP}] |
83 |
+ dev-python/tblib[${PYTHON_USEDEP}] |
84 |
+ sys-devel/gettext |
85 |
+ !!<dev-python/ipython-7.21.0-r1 |
86 |
+ !!=dev-python/ipython-7.22.0-r0 |
87 |
+ ) |
88 |
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 ) |
89 |
+" |
90 |
+ |
91 |
+PATCHES=( |
92 |
+ "${FILESDIR}"/${PN}-3.1-bashcomp.patch |
93 |
+) |
94 |
+ |
95 |
+distutils_enable_sphinx docs --no-autodoc |
96 |
+ |
97 |
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc |
98 |
+ |
99 |
+src_unpack() { |
100 |
+ if use verify-sig; then |
101 |
+ cd "${DISTDIR}" || die |
102 |
+ verify-sig_verify_signed_checksums \ |
103 |
+ "${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz" |
104 |
+ cd "${WORKDIR}" || die |
105 |
+ fi |
106 |
+ |
107 |
+ default |
108 |
+} |
109 |
+ |
110 |
+python_prepare_all() { |
111 |
+ # Fails because of warnings |
112 |
+ sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py || die |
113 |
+ # TODO: this suddenly started failing |
114 |
+ sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die |
115 |
+ |
116 |
+ distutils-r1_python_prepare_all |
117 |
+} |
118 |
+ |
119 |
+python_test() { |
120 |
+ # Tests have non-standard assumptions about PYTHONPATH, |
121 |
+ # and don't work with ${BUILD_DIR}/lib. |
122 |
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 || |
123 |
+ die "Tests fail with ${EPYTHON}" |
124 |
+} |
125 |
+ |
126 |
+python_install_all() { |
127 |
+ newbashcomp extras/django_bash_completion ${PN}-admin |
128 |
+ bashcomp_alias ${PN}-admin django-admin.py |
129 |
+ |
130 |
+ distutils-r1_python_install_all |
131 |
+} |
132 |
+ |
133 |
+pkg_postinst() { |
134 |
+ optfeature_header "Additional Backend support can be enabled via:" |
135 |
+ optfeature "MySQL backend support" dev-python/mysqlclient |
136 |
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2 |
137 |
+ optfeature_header |
138 |
+ optfeature "GEO Django" "sci-libs/gdal[geos]" |
139 |
+ optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached |
140 |
+ optfeature "ImageField Support" dev-python/pillow |
141 |
+ optfeature "Password encryption" dev-python/bcrypt |
142 |
+ optfeature "High-level abstractions for Django forms" dev-python/django-formtools |
143 |
+} |