[gentoo-commits] repo/gentoo:master commit in: sys-libs/libosinfo/

[Gilles Dartiguelongue]

commit:     6ab1bbf2fa56ac6c3f2d020bae27087ed8f4258e
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 10 10:50:08 2017 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Sep 10 10:50:31 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6ab1bbf2

sys-libs/libosinfo: restore 1.0.0 for ~sparc dependency tree

Package-Manager: Portage-2.3.8, Repoman-2.3.3

 sys-libs/libosinfo/libosinfo-1.0.0.ebuild | 49 +++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/sys-libs/libosinfo/libosinfo-1.0.0.ebuild b/sys-libs/libosinfo/libosinfo-1.0.0.ebuild
new file mode 100644
index 00000000000..97da310d330
--- /dev/null
+++ b/sys-libs/libosinfo/libosinfo-1.0.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 udev vala
+
+DESCRIPTION="GObject library for managing information about real and virtual OSes"
+HOMEPAGE="http://libosinfo.org/"
+SRC_URI="http://fedorahosted.org/releases/${PN:0:1}/${PN:1:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+
+IUSE="+introspection +vala test"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~sparc"
+
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2
+	>=dev-libs/libxslt-1.0.0:=
+	dev-libs/libxml2:=
+	>=net-libs/libsoup-2.42:2.4
+	sys-apps/hwids
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+DEPEND="${RDEPEND}
+	dev-libs/gobject-introspection-common
+	>=dev-util/gtk-doc-am-1.10
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable test tests) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		--disable-coverage
+}