[gentoo-commits] gentoo-x86 commit in app-admin/eselect-postgresql: ChangeLog eselect-postgresql-0.4.ebuild

[Patrick Lauer (patrick)]

patrick     10/06/02 18:26:49

  Modified:             ChangeLog
  Added:                eselect-postgresql-0.4.ebuild
  Log:
  Bump, thanks to Aaron Swenson for the improvements
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.11                 app-admin/eselect-postgresql/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect-postgresql/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect-postgresql/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect-postgresql/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/eselect-postgresql/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	25 Apr 2010 19:55:00 -0000	1.10
+++ ChangeLog	2 Jun 2010 18:26:49 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/eselect-postgresql
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-postgresql/ChangeLog,v 1.10 2010/04/25 19:55:00 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-postgresql/ChangeLog,v 1.11 2010/06/02 18:26:49 patrick Exp $
+
+*eselect-postgresql-0.4 (02 Jun 2010)
+
+  02 Jun 2010; Patrick Lauer <patrick@g.o>
+  +eselect-postgresql-0.4.ebuild:
+  Bump, thanks to Aaron Swenson for the improvements
 
   25 Apr 2010; Raúl Porcel <armin76@g.o>
   eselect-postgresql-0.3.ebuild:



1.1                  app-admin/eselect-postgresql/eselect-postgresql-0.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect-postgresql/eselect-postgresql-0.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect-postgresql/eselect-postgresql-0.4.ebuild?rev=1.1&content-type=text/plain

Index: eselect-postgresql-0.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-postgresql/eselect-postgresql-0.4.ebuild,v 1.1 2010/06/02 18:26:49 patrick Exp $

EAPI=2

inherit multilib

DESCRIPTION="Utility to change the default postgresql installation"
HOMEPAGE="http://www.gentoo.org/"
SRC_URI="http://gentooexperimental.org/~patrick/${P}.tbz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE=""

RDEPEND="app-admin/eselect
		!!dev-db/libpq"

src_install() {
	keepdir /etc/eselect/postgresql
	doenvd "${FILESDIR}/50postgresql-eselect"

	insinto /usr/share/eselect/modules
	doins postgresql.eselect
	sed -i \
		-e "s|/usr/lib/|/usr/$(get_libdir)/|g" \
		"${D}/usr/share/eselect/modules/postgresql.eselect"

	exeinto /usr/$(get_libdir)/${PN}
	doexe "binwrapper"

	dodir /usr/bin
	dosym /usr/bin/eselect /usr/bin/postgresql-config
}

pkg_preinst() {
	local ff=""
	for f in "${ROOT}"/usr/include/{postgresql,libpq-fe.h,libpq,postgres_ext.h,pg_config_manual.h} ; do
		[[ -e "${f}" ]] || continue
		[[ -L "${f}" ]] && continue
		if [[ -d "${f}" ]] ; then
			if [[ -z "$(find \"${f}\" -not \( -type l -or -type d \))" ]] ; then
				rm -rf "${f}"
			else
				ff="$ff $f"
			fi
		else
			ff="$ff $f"
		fi
	done
	if [[ ! -z "$ff" ]] ; then
		eerror "You have leftovers from previous postgresql installations that"
		eerror "can't be dealt with automatically. The proper way to treat"
		eerror "files is:"
		eerror ""
		eerror "rm -rf ${ff}"
		eerror ""
		die "Please, remove the files manually"
	fi
}

pkg_postinst() {
	elog "This eselect module can be used to define which PostgreSQL version is being used"
	elog "to link against and which (major) version of PostgreSQL is being started by the"
	elog "init-system when an init.d file lists 'need postgresql' or 'use postgresql' in"
	elog "its dependencies."
	elog
	elog "For users of the 'postgresql' overlay: In case you have"
	elog "dev-db/postgresql-{base,server} installed but 'eselect postgresql list' doesn't"
	elog "anything, please re-install dev-db/postgresql-{base,server} since we had to move"
	elog "around some stuff. Sorry for the inconvenience."
	elog
	elog "Please make sure that you use the new postgresql ebuilds"
	elog "(dev-db/postgresql-{base,server}). This eselect module won't list the old"
	elog "dev-db/{postgresql,libpq} installations as available libraries or services."
}