[gentoo-commits] gentoo-x86 commit in dev-python/gevent: gevent-0.13.8.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    13/05/22 01:31:10

  Modified:             ChangeLog
  Added:                gevent-0.13.8.ebuild
  Log:
  Version bump and migrate to distutils-r1.
  
  (Portage version: 2.2.0_alpha176/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.11                 dev-python/gevent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	14 Feb 2013 06:17:26 -0000	1.10
+++ ChangeLog	22 May 2013 01:31:10 -0000	1.11
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/gevent
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v 1.10 2013/02/14 06:17:26 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v 1.11 2013/05/22 01:31:10 radhermit Exp $
+
+*gevent-0.13.8 (22 May 2013)
+
+  22 May 2013; Tim Harder <radhermit@g.o> +gevent-0.13.8.ebuild:
+  Version bump and migrate to distutils-r1.
 
 *gevent-1.0_rc2 (14 Feb 2013)
 



1.1                  dev-python/gevent/gevent-0.13.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/gevent-0.13.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/gevent/gevent-0.13.8.ebuild?rev=1.1&content-type=text/plain

Index: gevent-0.13.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/gevent-0.13.8.ebuild,v 1.1 2013/05/22 01:31:10 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

inherit distutils-r1 flag-o-matic

DESCRIPTION="Python networking library that uses greenlet to provide synchronous API"
HOMEPAGE="http://gevent.org/ http://pypi.python.org/pypi/gevent/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="doc examples"

RDEPEND="dev-libs/libevent
	dev-python/greenlet[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"

# Tests take long and fail terribly a few times.
# It also seems that they require network access.
RESTRICT="test"

python_configure_all() {
	append-flags -fno-strict-aliasing
}

python_compile_all() {
	use doc && emake -C doc html
}

python_test() {
	cd greentest || die
	"${PYTHON}" testrunner.py || die "Tests fail with ${EPYTHON}"
}

python_install_all() {
	local DOCS=( AUTHORS changelog.rst README.rst )
	use doc && local HTML_DOCS=( doc/_build/html/. )

	distutils-r1_python_install_all

	if use examples; then
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi
}