[gentoo-commits] gentoo-x86 commit in media-libs/libbluray: ChangeLog libbluray-0.2.3.ebuild

[Tim Harder (radhermit)]

radhermit    12/08/27 06:15:19

  Modified:             ChangeLog
  Added:                libbluray-0.2.3.ebuild
  Log:
  Version bump (bug #431900).
  
  (Portage version: 2.2.0_alpha123/cvs/Linux x86_64)

Revision  Changes    Path
1.35                 media-libs/libbluray/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	28 Jun 2012 12:44:32 -0000	1.34
+++ ChangeLog	27 Aug 2012 06:15:19 -0000	1.35
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libbluray
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.34 2012/06/28 12:44:32 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.35 2012/08/27 06:15:19 radhermit Exp $
+
+*libbluray-0.2.3 (27 Aug 2012)
+
+  27 Aug 2012; Tim Harder <radhermit@g.o> +libbluray-0.2.3.ebuild:
+  Version bump (bug #431900).
 
   28 Jun 2012; Brent Baude <ranger@g.o> libbluray-0.2.2.ebuild:
   Marking libbluray-0.2.2 ppc for bug 422107



1.1                  media-libs/libbluray/libbluray-0.2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/libbluray-0.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libbluray/libbluray-0.2.3.ebuild?rev=1.1&content-type=text/plain

Index: libbluray-0.2.3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/libbluray-0.2.3.ebuild,v 1.1 2012/08/27 06:15:19 radhermit Exp $

EAPI=4

inherit autotools java-pkg-opt-2 flag-o-matic eutils

DESCRIPTION="Blu-ray playback libraries"
HOMEPAGE="http://www.videolan.org/developers/libbluray.html"
SRC_URI="ftp://ftp.videolan.org/pub/videolan/libbluray/${PV}/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="aacs java static-libs utils +xml"

COMMON_DEPEND="
	xml? ( dev-libs/libxml2 )
"
RDEPEND="
	${COMMON_DEPEND}
	aacs? ( media-libs/libaacs )
	java? ( >=virtual/jre-1.6 )
"
DEPEND="
	${COMMON_DEPEND}
	java? (
		>=virtual/jdk-1.6
		dev-java/ant-core
	)
	virtual/pkgconfig
"
REQUIRED_USE="utils? ( static-libs )"

DOCS=( ChangeLog README.txt )

src_prepare() {
	use java && export JDK_HOME="$(java-config -g JAVA_HOME)"
	eautoreconf

	java-pkg-opt-2_src_prepare
}

src_configure() {
	local myconf=""
	if use java; then
		export JAVACFLAGS="$(java-pkg_javac-args)"
		append-cflags "$(java-pkg_get-jni-cflags)"
		myconf="--with-jdk=${JDK_HOME}"
	fi

	use xml && myconf+=" --enable-libxml2"

	econf \
		--disable-debug \
		--disable-optimizations \
		$(use_enable java bdjava) \
		$(use_enable static-libs static) \
		$(use_enable utils examples) \
		${myconf}
}

src_install() {
	default

	if use utils; then
		cd src/examples/
		dobin clpi_dump index_dump mobj_dump mpls_dump sound_dump
		cd .libs/
		dobin bd_info bdsplice hdmv_test libbluray_test list_titles
		if use java; then
			dobin bdj_test
		fi
	fi

	if use java; then
		java-pkg_dojar "${S}/src/.libs/${PN}.jar"
		doenvd "${FILESDIR}"/90${PN}
	fi

	prune_libtool_files
}