[gentoo-commits] proj/kde:master commit in: kde-plasma/libksysguard/, kde-plasma/bluedevil/, kde-plasma/kde-gtk-config/, ...

[Andreas Sturmlechner]

commit:     6a91c336b7f3bda97bc06be1518a7103df9b60e7
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed May  6 17:41:14 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed May  6 17:41:14 2020 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=6a91c336

kde-plasma: Add KDE Plasma 5.18.5

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/bluedevil/bluedevil-5.18.5.ebuild       |  40 ++++
 kde-plasma/breeze-grub/breeze-grub-5.18.5.ebuild   |  23 +++
 kde-plasma/breeze-gtk/breeze-gtk-5.18.5.ebuild     |  48 +++++
 .../breeze-plymouth/breeze-plymouth-5.18.5.ebuild  |  28 +++
 kde-plasma/breeze/breeze-5.18.5.ebuild             |  56 ++++++
 kde-plasma/discover/discover-5.18.5.ebuild         |  78 ++++++++
 kde-plasma/drkonqi/drkonqi-5.18.5.ebuild           |  67 +++++++
 .../kactivitymanagerd-5.18.5.ebuild                |  36 ++++
 .../kde-cli-tools/kde-cli-tools-5.18.5.ebuild      |  70 +++++++
 .../kde-gtk-config/kde-gtk-config-5.18.5.ebuild    |  49 +++++
 kde-plasma/kdecoration/kdecoration-5.18.5.ebuild   |  24 +++
 .../kdeplasma-addons-5.18.5.ebuild                 |  62 ++++++
 kde-plasma/kgamma/kgamma-5.18.5.ebuild             |  32 +++
 kde-plasma/khotkeys/khotkeys-5.18.5.ebuild         |  50 +++++
 kde-plasma/kinfocenter/kinfocenter-5.18.5.ebuild   | 105 ++++++++++
 kde-plasma/kmenuedit/kmenuedit-5.18.5.ebuild       |  41 ++++
 kde-plasma/kscreen/kscreen-5.18.5.ebuild           |  46 +++++
 .../kscreenlocker/kscreenlocker-5.18.5.ebuild      | 100 ++++++++++
 kde-plasma/ksshaskpass/ksshaskpass-5.18.5.ebuild   |  78 ++++++++
 kde-plasma/ksysguard/ksysguard-5.18.5.ebuild       |  55 ++++++
 kde-plasma/kwallet-pam/kwallet-pam-5.18.5.ebuild   |  37 ++++
 .../kwayland-integration-5.18.5.ebuild             |  30 +++
 kde-plasma/kwin/kwin-5.18.5.ebuild                 | 111 +++++++++++
 kde-plasma/kwrited/kwrited-5.18.5.ebuild           |  27 +++
 kde-plasma/libkscreen/libkscreen-5.18.5.ebuild     |  31 +++
 kde-plasma/libksysguard/libksysguard-5.18.5.ebuild |  64 ++++++
 .../libkworkspace/libkworkspace-5.18.5.ebuild      |  60 ++++++
 kde-plasma/milou/milou-5.18.5.ebuild               |  33 ++++
 kde-plasma/oxygen/oxygen-5.18.5.ebuild             |  54 +++++
 .../plasma-browser-integration-5.18.5.ebuild       |  41 ++++
 .../plasma-desktop/plasma-desktop-5.18.5.ebuild    | 170 ++++++++++++++++
 .../plasma-integration-5.18.5.ebuild               |  48 +++++
 kde-plasma/plasma-meta/plasma-meta-5.18.5.ebuild   |  94 +++++++++
 kde-plasma/plasma-nm/plasma-nm-5.18.5.ebuild       |  81 ++++++++
 kde-plasma/plasma-pa/plasma-pa-5.18.5.ebuild       |  38 ++++
 kde-plasma/plasma-sdk/plasma-sdk-5.18.5.ebuild     |  46 +++++
 .../plasma-thunderbolt-5.18.5.ebuild               |  33 ++++
 kde-plasma/plasma-vault/plasma-vault-5.18.5.ebuild |  47 +++++
 .../plasma-workspace-wallpapers-5.18.5.ebuild      |  19 ++
 .../plasma-workspace-5.18.5.ebuild                 | 219 +++++++++++++++++++++
 kde-plasma/plymouth-kcm/plymouth-kcm-5.18.5.ebuild |  40 ++++
 .../polkit-kde-agent-5.18.5.ebuild                 |  33 ++++
 kde-plasma/powerdevil/powerdevil-5.18.5.ebuild     |  67 +++++++
 kde-plasma/sddm-kcm/sddm-kcm-5.18.5.ebuild         |  38 ++++
 .../systemsettings/systemsettings-5.18.5.ebuild    |  67 +++++++
 kde-plasma/user-manager/user-manager-5.18.5.ebuild |  34 ++++
 .../xdg-desktop-portal-kde-5.18.5.ebuild           |  53 +++++
 .../xembed-sni-proxy-5.18.5.ebuild                 |  44 +++++
 48 files changed, 2747 insertions(+)

diff --git a/kde-plasma/bluedevil/bluedevil-5.18.5.ebuild b/kde-plasma/bluedevil/bluedevil-5.18.5.ebuild
new file mode 100644
index 0000000000..dd47c0e872
--- /dev/null
+++ b/kde-plasma/bluedevil/bluedevil-5.18.5.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Bluetooth stack for KDE Plasma"
+HOMEPAGE="https://cgit.kde.org/bluedevil.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/bluez-qt-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"

diff --git a/kde-plasma/breeze-grub/breeze-grub-5.18.5.ebuild b/kde-plasma/breeze-grub/breeze-grub-5.18.5.ebuild
new file mode 100644
index 0000000000..6ba651f290
--- /dev/null
+++ b/kde-plasma/breeze-grub/breeze-grub-5.18.5.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-3)
+inherit kde.org
+
+DESCRIPTION="Breeze theme for GRUB"
+
+LICENSE="GPL-3+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+src_prepare() { default; }
+src_configure() { :; }
+src_compile() { :; }
+
+src_install() {
+	insinto /usr/share/grub/themes
+	doins -r breeze
+}

diff --git a/kde-plasma/breeze-gtk/breeze-gtk-5.18.5.ebuild b/kde-plasma/breeze-gtk/breeze-gtk-5.18.5.ebuild
new file mode 100644
index 0000000000..da547ee9b7
--- /dev/null
+++ b/kde-plasma/breeze-gtk/breeze-gtk-5.18.5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PVCUT=$(ver_cut 1-3)
+inherit ecm kde.org python-any-r1
+
+DESCRIPTION="Official GTK+ port of Plasma's Breeze widget style"
+HOMEPAGE="https://cgit.kde.org/breeze-gtk.git"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	dev-lang/sassc
+	$(python_gen_any_dep 'dev-python/pycairo[${PYTHON_USEDEP}]')
+	>=kde-plasma/breeze-${PVCUT}:5
+"
+
+python_check_deps() {
+	has_version "dev-python/pycairo[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	if has_version "<dev-util/cmake-3.16_rc1"; then
+		eapply "${FILESDIR}"/${PN}-5.16.5-cmake-pre-3.16.patch
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	if has_version "<dev-util/cmake-3.16_rc1"; then
+		mycmakeargs=( -DPYTHON_EXECUTABLE="${PYTHON}" )
+	fi
+	ecm_src_configure
+}

diff --git a/kde-plasma/breeze-plymouth/breeze-plymouth-5.18.5.ebuild b/kde-plasma/breeze-plymouth/breeze-plymouth-5.18.5.ebuild
new file mode 100644
index 0000000000..9ac3d9978b
--- /dev/null
+++ b/kde-plasma/breeze-plymouth/breeze-plymouth-5.18.5.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+inherit cmake kde.org
+
+DESCRIPTION="Breeze theme for Plymouth"
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+BDEPEND=">=kde-frameworks/extra-cmake-modules-${KFMIN}:5"
+DEPEND="sys-boot/plymouth"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISTRO_NAME="Gentoo Linux"
+		-DDISTRO_VERSION=
+	)
+
+	cmake_src_configure
+}

diff --git a/kde-plasma/breeze/breeze-5.18.5.ebuild b/kde-plasma/breeze/breeze-5.18.5.ebuild
new file mode 100644
index 0000000000..84ee6ad4ff
--- /dev/null
+++ b/kde-plasma/breeze/breeze-5.18.5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://cgit.kde.org/breeze.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="wayland X"
+
+# drop qtwidgets subslot operator when QT_MINIMAL >= 5.13.0
+RDEPEND="
+	>=kde-frameworks/frameworkintegration-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5=
+	sci-libs/fftw:3.0=
+	wayland? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kpackage-${KFMIN}:5
+"
+PDEPEND="
+	>=kde-frameworks/breeze-icons-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package wayland KF5Wayland)
+		$(cmake_use_find_package X XCB)
+	)
+	ecm_src_configure
+}

diff --git a/kde-plasma/discover/discover-5.18.5.ebuild b/kde-plasma/discover/discover-5.18.5.ebuild
new file mode 100644
index 0000000000..d576b1e645
--- /dev/null
+++ b/kde-plasma/discover/discover-5.18.5.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma resources management GUI"
+HOMEPAGE="https://userbase.kde.org/Discover"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+firmware telemetry"
+
+# libmarkdown (app-text/discount) only used in PackageKitBackend
+DEPEND="
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	firmware? ( sys-apps/fwupd )
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# we don't need it with PackageKitBackend off
+	ecm_punt_bogus_dep KF5 Archive
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_AppStreamQt=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Snapd=ON
+		-DBUILD_FlatpakBackend=OFF
+		-DBUILD_FwupdBackend=$(usex firmware)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 686392: needs network connection
+	local myctestargs=(
+		-E "(knsbackendtest)"
+	)
+
+	ecm_src_test
+}

diff --git a/kde-plasma/drkonqi/drkonqi-5.18.5.ebuild b/kde-plasma/drkonqi/drkonqi-5.18.5.ebuild
new file mode 100644
index 0000000000..c808e156a9
--- /dev/null
+++ b/kde-plasma/drkonqi/drkonqi-5.18.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlrpcclient-${KFMIN}:5
+	X? ( >=dev-qt/qtx11extras-${QTMIN}:5 )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# needs network access, bug #698510
+	local myctestargs=(
+		-E "(connectiontest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	if ! has_version "sys-devel/gdb"; then
+		elog "For more usability consider installing the following package:"
+		elog "    sys-devel/gdb - Easier debugging support"
+	fi
+}

diff --git a/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.18.5.ebuild b/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.18.5.ebuild
new file mode 100644
index 0000000000..5c762c5cbc
--- /dev/null
+++ b/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.18.5.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="System service to manage user's activities, track the usage patterns etc."
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"

diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-5.18.5.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-5.18.5.ebuild
new file mode 100644
index 0000000000..3010997fe7
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/kde-cli-tools-5.18.5.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://cgit.kde.org/kde-cli-tools.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="kdesu X"
+
+REQUIRED_USE="kdesu? ( X )"
+
+DEPEND="
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	kdesu? ( >=kde-frameworks/kdesu-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	kdesu? ( sys-apps/dbus[X] )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.12.80-tests-optional.patch" )
+
+# requires running kde environment
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kdesu KF5Su)
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	use kdesu && dosym ../$(get_libdir)/libexec/kf5/kdesu /usr/bin/kdesu
+}

diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.18.5.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.18.5.ebuild
new file mode 100644
index 0000000000..1cdc9e44ed
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.18.5.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="GTK2 and GTK3 configurator for KDE Plasma"
+HOMEPAGE="https://cgit.kde.org/kde-gtk-config.git"
+
+LICENSE="GPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	dev-libs/glib:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	gnome-base/gsettings-desktop-schemas
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	x11-libs/gtk+:2
+	x11-libs/gtk+:3
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+}

diff --git a/kde-plasma/kdecoration/kdecoration-5.18.5.ebuild b/kde-plasma/kdecoration/kdecoration-5.18.5.ebuild
new file mode 100644
index 0000000000..0bf22cdaf7
--- /dev/null
+++ b/kde-plasma/kdecoration/kdecoration-5.18.5.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Plugin based library to create window decorations"
+
+LICENSE="|| ( LGPL-2.1 LGPL-3 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+"
+RDEPEND="${DEPEND}"

diff --git a/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.18.5.ebuild b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.18.5.ebuild
new file mode 100644
index 0000000000..18a7b74928
--- /dev/null
+++ b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.18.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Extra Plasma applets and engines"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="share webengine"
+
+DEPEND="
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kross-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/plasma-workspace-${PVCUT}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package share KF5Purpose)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-plasma/kgamma/kgamma-5.18.5.ebuild b/kde-plasma/kgamma/kgamma-5.18.5.ebuild
new file mode 100644
index 0000000000..afd05d6c3b
--- /dev/null
+++ b/kde-plasma/kgamma/kgamma-5.18.5.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KDE_ORG_NAME="${PN}5"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Screen gamma values kcontrol module"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	x11-libs/libX11
+	x11-libs/libXxf86vm
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"

diff --git a/kde-plasma/khotkeys/khotkeys-5.18.5.ebuild b/kde-plasma/khotkeys/khotkeys-5.18.5.ebuild
new file mode 100644
index 0000000000..9259113b2f
--- /dev/null
+++ b/kde-plasma/khotkeys/khotkeys-5.18.5.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional" # not optional until !kdelibs4support
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma workspace hotkey module"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5[X]
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	x11-libs/libX11
+	x11-libs/libXtst
+"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+	x11-libs/libxcb
+	x11-libs/libXtst
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"

diff --git a/kde-plasma/kinfocenter/kinfocenter-5.18.5.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.18.5.ebuild
new file mode 100644
index 0000000000..7ad414c340
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.18.5.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Utility providing information about the computer hardware"
+HOMEPAGE="https://userbase.kde.org/KInfoCenter"
+SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="gles2-only ieee1394 +opengl +pci wayland"
+
+REQUIRED_USE="wayland? ( || ( opengl gles2-only ) )"
+
+BDEPEND=">=dev-util/cmake-3.14.3"
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	x11-libs/libX11
+	gles2-only? ( media-libs/mesa[gles2] )
+	ieee1394? ( sys-libs/libraw1394 )
+	opengl? (
+		media-libs/mesa[X(+)]
+		!gles2-only? ( media-libs/glu )
+	)
+	pci? ( sys-apps/pciutils )
+	wayland? (
+		>=kde-frameworks/kwayland-${KFMIN}:5
+		media-libs/mesa[egl]
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package ieee1394 RAW1394)
+		$(cmake_use_find_package pci PCIUTILS)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+	)
+
+	if has_version "dev-qt/qtgui[gles2-only]"; then
+		mycmakeargs+=( $(cmake_use_find_package gles2 OpenGLES) )
+	else
+		mycmakeargs+=( $(cmake_use_find_package opengl OpenGL) )
+	fi
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# TODO: Make this fully obsolete by /etc/os-release
+	insinto /etc/xdg
+	doins "${FILESDIR}"/kcm-about-distrorc
+
+	insinto /usr/share/${PN}
+	doins "${DISTDIR}"/glogo-small.png
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		has_version "net-fs/nfs-utils" || \
+			elog "Installing net-fs/nfs-utils will enable the NFS information module."
+
+		has_version "net-fs/samba" || \
+			elog "Installing net-fs/samba will enable the Samba status information module."
+	fi
+}

diff --git a/kde-plasma/kmenuedit/kmenuedit-5.18.5.ebuild b/kde-plasma/kmenuedit/kmenuedit-5.18.5.ebuild
new file mode 100644
index 0000000000..7ad3a0f55a
--- /dev/null
+++ b/kde-plasma/kmenuedit/kmenuedit-5.18.5.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.66.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma menu editor"
+HOMEPAGE="https://cgit.kde.org/kmenuedit.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kinit-${KFMIN}:5
+"

diff --git a/kde-plasma/kscreen/kscreen-5.18.5.ebuild b/kde-plasma/kscreen/kscreen-5.18.5.ebuild
new file mode 100644
index 0000000000..9ac37b817e
--- /dev/null
+++ b/kde-plasma/kscreen/kscreen-5.18.5.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma screen management"
+HOMEPAGE="https://cgit.kde.org/kscreen.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsensors-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+"
+
+# bug #580440, last checked 5.6.3
+RESTRICT+=" test"

diff --git a/kde-plasma/kscreenlocker/kscreenlocker-5.18.5.ebuild b/kde-plasma/kscreenlocker/kscreenlocker-5.18.5.ebuild
new file mode 100644
index 0000000000..5e66c8cd5e
--- /dev/null
+++ b/kde-plasma/kscreenlocker/kscreenlocker-5.18.5.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org pam
+
+DESCRIPTION="Library and components for secure lock screen architecture"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="consolekit +pam seccomp"
+
+REQUIRED_USE="seccomp? ( pam )"
+
+RDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	dev-libs/wayland
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+	consolekit? ( sys-auth/consolekit )
+	pam? ( sys-libs/pam )
+	seccomp? ( sys-libs/libseccomp )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+PDEPEND="
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+RESTRICT+=" test"
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use test; then
+		sed -e "/add_subdirectory(autotests)/ s/^/#/" \
+			-i greeter/CMakeLists.txt || die
+	fi
+}
+
+src_test() {
+	# requires running environment
+	local myctestargs=(
+		-E x11LockerTest
+	)
+	ecm_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package consolekit loginctl)
+		-DPAM_REQUIRED=$(usex pam)
+		$(cmake_use_find_package pam PAM)
+		$(cmake_use_find_package seccomp Seccomp)
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	use pam && newpamd "${FILESDIR}/kde.pam" kde
+	use pam && newpamd "${FILESDIR}/kde-np.pam" kde-np
+
+	if ! use pam; then
+		chown root "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+		chmod +s "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+	fi
+}

diff --git a/kde-plasma/ksshaskpass/ksshaskpass-5.18.5.ebuild b/kde-plasma/ksshaskpass/ksshaskpass-5.18.5.ebuild
new file mode 100644
index 0000000000..cf1f23b87d
--- /dev/null
+++ b/kde-plasma/ksshaskpass/ksshaskpass-5.18.5.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE implementation of ssh-askpass with Kwallet integration"
+HOMEPAGE="https://cgit.kde.org/ksshaskpass.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	ecm_pkg_setup
+
+	local srcfile=/etc/plasma/startup/05-ksshaskpass.sh
+	local newfile=/etc/xdg/plasma-workspace/env/05-ksshaskpass.sh
+	if [[ -f "${EROOT}"${srcfile} ]]; then
+		local md5=$(md5sum "${EROOT}"${srcfile})
+		if [[ ${md5%% *} != 615ae8f5b0090ff7f51d0edee7885d55 ]]; then
+			elog "Existing modified "${EPREFIX}"${srcfile} detected."
+			elog "Copying to "${EPREFIX}"${newfile}..."
+			cp -v "${EROOT}"${srcfile} "${T}"/ || die
+		fi
+	fi
+}
+
+src_prepare() {
+	ecm_src_prepare
+	if [[ ! -f "${T}"/05-ksshaskpass.sh ]]; then
+		cp "${FILESDIR}"/05-ksshaskpass.sh "${T}"/ || die
+	fi
+}
+
+src_install() {
+	ecm_src_install
+
+	insinto /etc/xdg/plasma-workspace/env/
+	doins "${FILESDIR}/05-ksshaskpass.sh"
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	elog "In order to have ssh-agent start with Plasma 5,"
+	elog "edit /etc/xdg/plasma-workspace/env/10-agent-startup.sh"
+	elog "and uncomment the lines enabling ssh-agent."
+	elog
+	elog "If you do so, do not forget to uncomment the respective"
+	elog "lines in /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
+	elog "to properly kill the agent when the session ends."
+	elog
+	elog "${PN} has been installed as your default askpass application"
+	elog "for Plasma 5 sessions."
+	elog "If that's not desired, select the one you want to use in"
+	elog "/etc/xdg/plasma-workspace/env/05-ksshaskpass.sh"
+
+	# Clean up pre-5.17.4 script
+	if [[ -e "${EROOT}"/etc/plasma/startup/05-ksshaskpass.sh ]]; then
+		rm "${EROOT}"/etc/plasma/startup/05-ksshaskpass.sh || die
+		elog "Removed obsolete ${EPREFIX}/etc/plasma/startup/05-ksshaskpass.sh"
+	fi
+}

diff --git a/kde-plasma/ksysguard/ksysguard-5.18.5.ebuild b/kde-plasma/ksysguard/ksysguard-5.18.5.ebuild
new file mode 100644
index 0000000000..a15e75cfb1
--- /dev/null
+++ b/kde-plasma/ksysguard/ksysguard-5.18.5.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Network-enabled task manager and system monitor"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="lm-sensors pcap"
+
+DEPEND="
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5[-minimal(-)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	pcap? (
+		net-libs/libpcap
+		sys-libs/libcap
+	)
+	lm-sensors? ( sys-apps/lm-sensors:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package pcap libpcap)
+		$(cmake_use_find_package lm-sensors Sensors)
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-plasma/kwallet-pam/kwallet-pam-5.18.5.ebuild b/kde-plasma/kwallet-pam/kwallet-pam-5.18.5.ebuild
new file mode 100644
index 0000000000..849263d4d7
--- /dev/null
+++ b/kde-plasma/kwallet-pam/kwallet-pam-5.18.5.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+inherit ecm kde.org
+
+DESCRIPTION="PAM module to not enter KWallet password again after login"
+
+LICENSE="LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	dev-libs/libgcrypt:0=
+	sys-libs/pam
+"
+RDEPEND="${DEPEND}
+	net-misc/socat
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_LIBDIR="/$(get_libdir)"
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "This package enables auto-unlocking of kde-frameworks/kwallet:5."
+	elog "See also: https://wiki.gentoo.org/wiki/KDE#KWallet_auto-unlocking"
+}

diff --git a/kde-plasma/kwayland-integration/kwayland-integration-5.18.5.ebuild b/kde-plasma/kwayland-integration/kwayland-integration-5.18.5.ebuild
new file mode 100644
index 0000000000..c23dadc1b5
--- /dev/null
+++ b/kde-plasma/kwayland-integration/kwayland-integration-5.18.5.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Provides integration plugins for various KDE frameworks for Wayland"
+HOMEPAGE="https://cgit.kde.org/kwayland-integration.git"
+
+LICENSE="LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT+=" test" # bug 668872

diff --git a/kde-plasma/kwin/kwin-5.18.5.ebuild b/kde-plasma/kwin/kwin-5.18.5.ebuild
new file mode 100644
index 0000000000..a66ce81e1b
--- /dev/null
+++ b/kde-plasma/kwin/kwin-5.18.5.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="optional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Flexible, composited Window Manager for windowing systems on Linux"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="caps gles2-only multimedia"
+
+COMMON_DEPEND="
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5=
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5=
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-plasma/breeze-${PVCUT}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5=[gles2-only=]
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtsensors-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-libs/libinput-1.9
+	>=dev-libs/wayland-1.2
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/libepoxy
+	media-libs/mesa[egl,gbm,wayland,X(+)]
+	virtual/libudev:=
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libdrm
+	>=x11-libs/libxcb-1.10
+	>=x11-libs/libxkbcommon-0.7.0
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-keysyms
+	x11-libs/xcb-util-wm
+	caps? ( sys-libs/libcap )
+	gles2-only? ( media-libs/mesa[gles2] )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtvirtualkeyboard-${QTMIN}:5
+	multimedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer,qml] )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/designer-${QTMIN}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	x11-base/xorg-proto
+"
+PDEPEND="
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+RESTRICT+=" test"
+
+src_prepare() {
+	ecm_src_prepare
+	use multimedia || eapply "${FILESDIR}/${PN}-5.16.80-gstreamer-optional.patch"
+
+	# Access violations, bug #640432
+	sed -e "s/^ecm_find_qmlmodule.*QtMultimedia/#&/" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package caps Libcap)
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-plasma/kwrited/kwrited-5.18.5.ebuild b/kde-plasma/kwrited/kwrited-5.18.5.ebuild
new file mode 100644
index 0000000000..2582c33d16
--- /dev/null
+++ b/kde-plasma/kwrited/kwrited-5.18.5.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma daemon listening for wall and write messages"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}"

diff --git a/kde-plasma/libkscreen/libkscreen-5.18.5.ebuild b/kde-plasma/libkscreen/libkscreen-5.18.5.ebuild
new file mode 100644
index 0000000000..1d4fad5fb6
--- /dev/null
+++ b/kde-plasma/libkscreen/libkscreen-5.18.5.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="true"
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Plasma screen management library"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5/7"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	x11-libs/libxcb
+"
+RDEPEND="${DEPEND}"
+
+# requires running session
+RESTRICT+=" test"

diff --git a/kde-plasma/libksysguard/libksysguard-5.18.5.ebuild b/kde-plasma/libksysguard/libksysguard-5.18.5.ebuild
new file mode 100644
index 0000000000..01dc3bb862
--- /dev/null
+++ b/kde-plasma/libksysguard/libksysguard-5.18.5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Task management and system monitoring library"
+LICENSE="LGPL-2+"
+SLOT="5/8"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="minimal webengine X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	sys-libs/zlib
+	webengine? (
+		>=dev-qt/qtwebchannel-${QTMIN}:5
+		>=dev-qt/qtwebengine-${QTMIN}:5
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libXres
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	!minimal? ( >=kde-frameworks/plasma-${KFMIN}:5 )
+	X? ( x11-base/xorg-proto )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.16.0-no-detailed-mem-message.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package !minimal KF5Plasma)
+		$(cmake_use_find_package webengine Qt5WebChannel)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		$(cmake_use_find_package X X11)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	LC_NUMERIC="C" ecm_src_test # bug 695514
+}

diff --git a/kde-plasma/libkworkspace/libkworkspace-5.18.5.ebuild b/kde-plasma/libkworkspace/libkworkspace-5.18.5.ebuild
new file mode 100644
index 0000000000..51ebb58c4a
--- /dev/null
+++ b/kde-plasma/libkworkspace/libkworkspace-5.18.5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KDE_ORG_NAME="plasma-workspace"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Workspace library to interact with the Plasma session manager"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-plasma/kwin-${PVCUT}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/plasma-workspace-5.14.2:5
+"
+
+S="${S}/${PN}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.16.80-standalone.patch" )
+
+src_prepare() {
+	# delete colliding libkworkspace translations, let ecm_src_prepare do its magic
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
+		rm -rf po/*/docs || die
+		cp -a ../po ./ || die
+	fi
+	ecm_src_prepare
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		cat >> CMakeLists.txt <<- _EOF_ || die
+			ki18n_install(po)
+		_EOF_
+	fi
+
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" \
+		-i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
+}

diff --git a/kde-plasma/milou/milou-5.18.5.ebuild b/kde-plasma/milou/milou-5.18.5.ebuild
new file mode 100644
index 0000000000..3f9556f47b
--- /dev/null
+++ b/kde-plasma/milou/milou-5.18.5.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional-recursive"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Dedicated search application built on top of Baloo"
+HOMEPAGE="https://cgit.kde.org/milou.git"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}"

diff --git a/kde-plasma/oxygen/oxygen-5.18.5.ebuild b/kde-plasma/oxygen/oxygen-5.18.5.ebuild
new file mode 100644
index 0000000000..4c77767f6b
--- /dev/null
+++ b/kde-plasma/oxygen/oxygen-5.18.5.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Oxygen visual style for the Plasma desktop"
+HOMEPAGE="https://cgit.kde.org/oxygen.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="wayland"
+
+COMMON_DEPEND="
+	>=kde-frameworks/frameworkintegration-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	x11-libs/libxcb
+	wayland? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kservice-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/plasma-desktop-5.16.80
+"
+PDEPEND="
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package wayland KF5Wayland)
+	)
+	ecm_src_configure
+}

diff --git a/kde-plasma/plasma-browser-integration/plasma-browser-integration-5.18.5.ebuild b/kde-plasma/plasma-browser-integration/plasma-browser-integration-5.18.5.ebuild
new file mode 100644
index 0000000000..4d2d15d9ea
--- /dev/null
+++ b/kde-plasma/plasma-browser-integration/plasma-browser-integration-5.18.5.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Integrate Chrome/Firefox better into Plasma through browser extensions"
+
+LICENSE="GPL-3+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/purpose-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DMOZILLA_DIR="${EPREFIX}/usr/$(get_libdir)/mozilla"
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.18.5.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.18.5.ebuild
new file mode 100644
index 0000000000..bd37d0f65a
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.18.5.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma desktop"
+
+# Avoid pulling in xf86-input-{evdev,libinput,synaptics} DEPENDs
+# just for 1 header each. touchpad also uses a header from xorg-server.
+SHA_EVDEV="425ed601"
+SHA_LIBINPUT="e52daf20"
+SHA_SYNAPTICS="383355fa"
+SHA_XSERVER="d511a301"
+XORG_URI="https://gitlab.freedesktop.org/xorg/driver/PKG/-/raw"
+SRC_URI+="
+	${XORG_URI/PKG/xf86-input-evdev}/${SHA_EVDEV}/include/evdev-properties.h -> evdev-properties.h-${SHA_EVDEV}
+	${XORG_URI/PKG/xf86-input-libinput}/${SHA_LIBINPUT}/include/libinput-properties.h -> libinput-properties.h-${SHA_LIBINPUT}
+	${XORG_URI/PKG/xf86-input-synaptics}/${SHA_SYNAPTICS}/include/synaptics-properties.h -> synaptics-properties.h-${SHA_SYNAPTICS}
+	${XORG_URI/driver\/PKG/xserver}/${SHA_XSERVER}/include/xserver-properties.h -> xserver-properties.h-${SHA_XSERVER}
+"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+fontconfig ibus scim +semantic-desktop"
+
+COMMON_DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/attica-${KFMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kemoticons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/plasma-workspace-${PVCUT}:5
+	media-libs/phonon[qt5(+)]
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb[xkb]
+	x11-libs/libxkbfile
+	fontconfig? (
+		media-libs/fontconfig
+		media-libs/freetype
+		x11-libs/libXft
+		x11-libs/xcb-util-image
+	)
+	ibus? (
+		app-i18n/ibus
+		dev-libs/glib:2
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	x11-base/xorg-proto
+	fontconfig? ( x11-libs/libXrender )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-plasma/breeze-${PVCUT}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/oxygen-${PVCUT}:5
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	!<kde-plasma/kdeplasma-addons-5.15.80
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.18.4.1-override-include-dirs.patch" # downstream patch
+	"${FILESDIR}/${PN}-5.18.4.1-synaptics-header.patch" # in Plasma/5.19
+)
+
+src_unpack() {
+	kde.org_src_unpack
+	mkdir "${WORKDIR}/include" || die "Failed to prepare evdev/libinput dir"
+	cp "${DISTDIR}"/evdev-properties.h-${SHA_EVDEV} \
+		"${WORKDIR}"/include/evdev-properties.h || die "Failed to copy evdev"
+	cp "${DISTDIR}"/libinput-properties.h-${SHA_LIBINPUT} \
+		"${WORKDIR}"/include/libinput-properties.h || die "Failed to copy libinput"
+	cp "${DISTDIR}"/synaptics-properties.h-${SHA_SYNAPTICS} \
+		"${WORKDIR}"/include/synaptics-properties.h || die "Failed to copy synaptics"
+	cp "${DISTDIR}"/xserver-properties.h-${SHA_XSERVER} \
+		"${WORKDIR}"/include/xserver-properties.h || die "Failed to copy xserver"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package fontconfig Fontconfig)
+		-DEvdev_INCLUDE_DIRS="${WORKDIR}"/include
+		-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}"/include
+		-DSynaptics_INCLUDE_DIRS="${WORKDIR}"/include
+		$(cmake_use_find_package ibus IBus)
+		$(cmake_use_find_package scim SCIM)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# needs D-Bus, bug #634166
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts)"
+	)
+
+	ecm_src_test
+}

diff --git a/kde-plasma/plasma-integration/plasma-integration-5.18.5.ebuild b/kde-plasma/plasma-integration/plasma-integration-5.18.5.ebuild
new file mode 100644
index 0000000000..b691003265
--- /dev/null
+++ b/kde-plasma/plasma-integration/plasma-integration-5.18.5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Qt Platform Theme integration plugins for the Plasma workspaces"
+
+LICENSE="LGPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-plasma/breeze-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5=[dbus]
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	x11-libs/libXcursor
+	x11-libs/libxcb
+"
+RDEPEND="${DEPEND}
+	media-fonts/hack
+	media-fonts/noto
+"
+
+# requires running kde environment
+RESTRICT+=" test"

diff --git a/kde-plasma/plasma-meta/plasma-meta-5.18.5.ebuild b/kde-plasma/plasma-meta/plasma-meta-5.18.5.ebuild
new file mode 100644
index 0000000000..004ee85880
--- /dev/null
+++ b/kde-plasma/plasma-meta/plasma-meta-5.18.5.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Merge this to pull in all Plasma 5 packages"
+HOMEPAGE="https://kde.org/plasma-desktop"
+
+LICENSE="metapackage"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="bluetooth +browser-integration crypt +desktop-portal discover
++display-manager elogind grub gtk +handbook kwallet +legacy-systray
+networkmanager plymouth pulseaudio qrcode +sddm sdk systemd thunderbolt +wallpapers"
+
+REQUIRED_USE="?? ( elogind systemd )"
+
+RDEPEND="
+	>=kde-plasma/breeze-${PV}:${SLOT}
+	>=kde-plasma/drkonqi-${PV}:${SLOT}
+	>=kde-plasma/kactivitymanagerd-${PV}:${SLOT}
+	>=kde-plasma/kde-cli-tools-${PV}:${SLOT}
+	>=kde-plasma/kdecoration-${PV}:${SLOT}
+	>=kde-plasma/kdeplasma-addons-${PV}:${SLOT}
+	>=kde-plasma/kgamma-${PV}:${SLOT}
+	>=kde-plasma/khotkeys-${PV}:${SLOT}
+	>=kde-plasma/kinfocenter-${PV}:${SLOT}
+	>=kde-plasma/kmenuedit-${PV}:${SLOT}
+	>=kde-plasma/kscreen-${PV}:${SLOT}
+	>=kde-plasma/kscreenlocker-${PV}:${SLOT}
+	>=kde-plasma/ksshaskpass-${PV}:${SLOT}
+	>=kde-plasma/ksysguard-${PV}:${SLOT}
+	>=kde-plasma/kwayland-integration-${PV}:${SLOT}
+	>=kde-plasma/kwin-${PV}:${SLOT}
+	>=kde-plasma/kwrited-${PV}:${SLOT}
+	>=kde-plasma/libkscreen-${PV}:${SLOT}
+	>=kde-plasma/libksysguard-${PV}:${SLOT}
+	>=kde-plasma/milou-${PV}:${SLOT}
+	>=kde-plasma/oxygen-${PV}:${SLOT}
+	>=kde-plasma/plasma-desktop-${PV}:${SLOT}
+	>=kde-plasma/plasma-integration-${PV}:${SLOT}
+	>=kde-plasma/plasma-workspace-${PV}:${SLOT}
+	>=kde-plasma/polkit-kde-agent-${PV}:${SLOT}
+	>=kde-plasma/powerdevil-${PV}:${SLOT}
+	>=kde-plasma/systemsettings-${PV}:${SLOT}
+	>=kde-plasma/user-manager-${PV}:${SLOT}
+	sys-apps/dbus[elogind?,systemd?]
+	sys-auth/polkit[elogind?,systemd?]
+	sys-fs/udisks:2[elogind?,systemd?]
+	bluetooth? ( >=kde-plasma/bluedevil-${PV}:${SLOT} )
+	browser-integration? ( >=kde-plasma/plasma-browser-integration-${PV}:${SLOT} )
+	crypt? ( >=kde-plasma/plasma-vault-${PV}:${SLOT} )
+	desktop-portal? ( >=kde-plasma/xdg-desktop-portal-kde-${PV}:${SLOT} )
+	discover? ( >=kde-plasma/discover-${PV}:${SLOT} )
+	display-manager? (
+		sddm? (
+			>=kde-plasma/sddm-kcm-${PV}:${SLOT}
+			x11-misc/sddm[elogind?,systemd?]
+		)
+		!sddm? ( x11-misc/lightdm )
+	)
+	grub? ( >=kde-plasma/breeze-grub-${PV}:${SLOT} )
+	gtk? (
+		>=kde-plasma/breeze-gtk-${PV}:${SLOT}
+		>=kde-plasma/kde-gtk-config-${PV}:${SLOT}
+	)
+	handbook? ( kde-apps/khelpcenter:5 )
+	kwallet? ( >=kde-plasma/kwallet-pam-${PV}:${SLOT} )
+	legacy-systray? ( >=kde-plasma/xembed-sni-proxy-${PV}:${SLOT} )
+	networkmanager? (
+		>=kde-plasma/plasma-nm-${PV}:${SLOT}
+		net-misc/networkmanager[elogind?,systemd?]
+		qrcode? ( kde-frameworks/prison[qml] )
+	)
+	plymouth? (
+		>=kde-plasma/breeze-plymouth-${PV}:${SLOT}
+		>=kde-plasma/plymouth-kcm-${PV}:${SLOT}
+	)
+	pulseaudio? ( >=kde-plasma/plasma-pa-${PV}:${SLOT} )
+	sdk? ( >=kde-plasma/plasma-sdk-${PV}:${SLOT} )
+	thunderbolt? ( >=kde-plasma/plasma-thunderbolt-${PV}:${SLOT} )
+	wallpapers? ( >=kde-plasma/plasma-workspace-wallpapers-${PV}:${SLOT} )
+"
+
+pkg_postinst() {
+	has_version sys-auth/consolekit || return
+	use elogind || use systemd && return
+	ewarn "An existing installation of sys-auth/consolekit was detected even though"
+	ewarn "${PN} was configured with USE $(usex elogind elogind systemd)."
+	ewarn "There can only be one session manager at runtime, otherwise random issues"
+	ewarn "may occur. Please make sure USE consolekit is nowhere enabled in make.conf"
+	ewarn "or package.use and remove sys-auth/consolekit before raising bugs."
+	ewarn "For more information, visit https://wiki.gentoo.org/wiki/KDE"
+}

diff --git a/kde-plasma/plasma-nm/plasma-nm-5.18.5.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.18.5.ebuild
new file mode 100644
index 0000000000..b54f622285
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.18.5.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.1.1:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	net-misc/networkmanager[teamd=]
+	modemmanager? (
+		>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+		>=dev-qt/qtxml-${QTMIN}:5
+		net-misc/mobile-broadband-provider-info
+	)
+	openconnect? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+		$(cmake_use_find_package modemmanager KF5ModemManagerQt)
+		$(cmake_use_find_package openconnect OpenConnect)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}

diff --git a/kde-plasma/plasma-pa/plasma-pa-5.18.5.ebuild b/kde-plasma/plasma-pa/plasma-pa-5.18.5.ebuild
new file mode 100644
index 0000000000..8ed54fe8fe
--- /dev/null
+++ b/kde-plasma/plasma-pa/plasma-pa-5.18.5.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Plasma applet for audio volume management using PulseAudio"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	dev-libs/glib:2
+	media-libs/libcanberra
+	media-sound/pulseaudio
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	media-libs/libcanberra
+	x11-themes/sound-theme-freedesktop
+"

diff --git a/kde-plasma/plasma-sdk/plasma-sdk-5.18.5.ebuild b/kde-plasma/plasma-sdk/plasma-sdk-5.18.5.ebuild
new file mode 100644
index 0000000000..b3d1a3b9ad
--- /dev/null
+++ b/kde-plasma/plasma-sdk/plasma-sdk-5.18.5.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="optional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Useful applications for Plasma development"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+"

diff --git a/kde-plasma/plasma-thunderbolt/plasma-thunderbolt-5.18.5.ebuild b/kde-plasma/plasma-thunderbolt/plasma-thunderbolt-5.18.5.ebuild
new file mode 100644
index 0000000000..03c59fa484
--- /dev/null
+++ b/kde-plasma/plasma-thunderbolt/plasma-thunderbolt-5.18.5.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Plasma integration for controlling Thunderbolt devices"
+HOMEPAGE="https://cgit.kde.org/plasma-thunderbolt.git"
+
+LICENSE="|| ( GPL-2 GPL-3+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	sys-apps/bolt
+"

diff --git a/kde-plasma/plasma-vault/plasma-vault-5.18.5.ebuild b/kde-plasma/plasma-vault/plasma-vault-5.18.5.ebuild
new file mode 100644
index 0000000000..ae5c9feab2
--- /dev/null
+++ b/kde-plasma/plasma-vault/plasma-vault-5.18.5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Plasma applet and services for creating encrypted vaults"
+HOMEPAGE+=" https://cukic.co/2017/02/03/vaults-encryption-in-plasma/"
+
+LICENSE="LGPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="networkmanager"
+
+DEPEND="
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	|| ( >=sys-fs/cryfs-0.9.9 >=sys-fs/encfs-1.9.2 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package networkmanager KF5NetworkManagerQt)
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.18.5.ebuild b/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.18.5.ebuild
new file mode 100644
index 0000000000..0fe9c7985b
--- /dev/null
+++ b/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.18.5.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-3)
+inherit cmake kde.org
+
+DESCRIPTION="Wallpapers for the Plasma workspace"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+BDEPEND="
+	dev-qt/qtcore:5
+	kde-frameworks/extra-cmake-modules:5
+"

diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.18.5.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.18.5.ebuild
new file mode 100644
index 0000000000..c71af205da
--- /dev/null
+++ b/kde-plasma/plasma-workspace/plasma-workspace-5.18.5.ebuild
@@ -0,0 +1,219 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma workspace"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="appstream +calendar geolocation gps qalculate qrcode +semantic-desktop systemd telemetry"
+
+REQUIRED_USE="gps? ( geolocation )"
+
+# drop qtgui subslot operator when QT_MINIMAL >= 5.14.0
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5=[jpeg]
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kpeople-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	media-libs/phonon[qt5(+)]
+	sys-libs/zlib
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libxcb
+	x11-libs/libXfixes
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	appstream? ( dev-libs/appstream[qt5] )
+	calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
+	geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+	gps? ( sci-geosciences/gpsd )
+	qalculate? ( sci-libs/libqalculate:= )
+	qrcode? ( >=kde-frameworks/prison-${KFMIN}:5 )
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	app-text/iso-codes
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpaths-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-apps/kio-extras-19.04.3:5
+	>=kde-frameworks/kquickcharts-${KFMIN}:5
+	>=kde-frameworks/kdesu-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/ksysguard-${PVCUT}:5
+	>=kde-plasma/milou-${PVCUT}:5
+	>=kde-plasma/plasma-integration-${PVCUT}:5
+	x11-apps/xmessage
+	x11-apps/xprop
+	x11-apps/xrdb
+	x11-apps/xsetroot
+	systemd? ( sys-apps/dbus[user-session] )
+	!systemd? ( sys-apps/dbus )
+	!<kde-plasma/plasma-desktop-5.16.80:5
+"
+PDEPEND="
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.14.2-split-libkworkspace.patch" )
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	ecm_pkg_setup
+
+	local md5
+	local srcfile=/etc/plasma/XX/10-agent-XX.sh
+	local newdir="${EPREFIX}"/etc/xdg/plasma-workspace
+
+	if [[ -f "${EROOT}"${srcfile//XX/startup} ]]; then
+		md5=$(md5sum "${EROOT}"${srcfile//XX/startup})
+		if [[ ${md5%% *} != 90caaabb40b56bfbe65388841a6dd6ca ]]; then
+			elog "Existing modified ${EPREFIX}${srcfile//XX/startup} detected."
+			elog "Copying to ${newdir}/env/10-agent-startup.sh..."
+			cp -v "${EROOT}"${srcfile//XX/startup} "${T}"/ || die
+		fi
+	fi
+
+	if [[ -f "${EROOT}"${srcfile//XX/shutdown} ]]; then
+		md5=$(md5sum "${EROOT}"${srcfile//XX/shutdown})
+		if [[ ${md5%% *} != d7bffa0273f92abd999c7c3c43dbc23d ]]; then
+			elog "Existing modified ${EPREFIX}${srcfile//XX/shutdown} detected."
+			elog "Copying to ${newdir}/shutdown/10-agent-shutdown.sh..."
+			cp -v "${EROOT}"${srcfile//XX/shutdown} "${T}"/ || die
+		fi
+	fi
+}
+
+src_prepare() {
+	ecm_src_prepare
+
+	if [[ ! -f "${T}"/10-agent-startup.sh ]]; then
+		cp "${FILESDIR}"/10-agent-startup.sh "${T}"/ || die
+	fi
+	if [[ ! -f "${T}"/10-agent-shutdown.sh ]]; then
+		cp "${FILESDIR}"/10-agent-shutdown.sh "${T}"/ || die
+	fi
+
+	cmake_comment_add_subdirectory libkworkspace
+	# delete colliding libkworkspace translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_xembed-sni-proxy=OFF
+		$(cmake_use_find_package appstream AppStreamQt)
+		$(cmake_use_find_package calendar KF5Holidays)
+		$(cmake_use_find_package geolocation KF5NetworkManagerQt)
+		$(cmake_use_find_package qalculate Qalculate)
+		$(cmake_use_find_package qrcode KF5Prison)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	use geolocation && mycmakeargs+=( $(cmake_use_find_package gps libgps) )
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# default startup and shutdown scripts
+	insinto /etc/xdg/plasma-workspace/env
+	doins "${T}"/10-agent-startup.sh
+
+	insinto /etc/xdg/plasma-workspace/shutdown
+	doins "${T}"/10-agent-shutdown.sh
+	fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	# Clean up pre-5.17.4 scripts
+	if [[ -e "${EROOT}"/etc/plasma/startup/10-agent-startup.sh ]]; then
+		rm "${EROOT}"/etc/plasma/startup/10-agent-startup.sh || die
+		elog "Removed obsolete ${EPREFIX}/etc/plasma/startup/10-agent-startup.sh"
+	fi
+	if [[ -e "${EROOT}"/etc/plasma/shutdown/10-agent-shutdown.sh ]]; then
+		rm "${EROOT}"/etc/plasma/shutdown/10-agent-shutdown.sh || die
+		elog "Removed obsolete ${EPREFIX}/etc/plasma/shutdown/10-agent-shutdown.sh"
+	fi
+
+	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
+	elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
+	elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
+}

diff --git a/kde-plasma/plymouth-kcm/plymouth-kcm-5.18.5.ebuild b/kde-plasma/plymouth-kcm/plymouth-kcm-5.18.5.ebuild
new file mode 100644
index 0000000000..f7cc90b1d8
--- /dev/null
+++ b/kde-plasma/plymouth-kcm/plymouth-kcm-5.18.5.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+BOGUS=1
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma control module for Plymouth"
+HOMEPAGE="https://cgit.kde.org/plymouth-kcm.git"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	sys-boot/plymouth
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+DOCS=( CONTRIBUTORS )

diff --git a/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.18.5.ebuild b/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.18.5.ebuild
new file mode 100644
index 0000000000..a2677ec86c
--- /dev/null
+++ b/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.18.5.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_ORG_NAME="${PN}-1"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="PolKit agent module for KDE Plasma"
+HOMEPAGE="https://kde.org/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=sys-auth/polkit-qt-0.112.0[qt5(+)]
+"
+RDEPEND="${DEPEND}"

diff --git a/kde-plasma/powerdevil/powerdevil-5.18.5.ebuild b/kde-plasma/powerdevil/powerdevil-5.18.5.ebuild
new file mode 100644
index 0000000000..3f5d960a10
--- /dev/null
+++ b/kde-plasma/powerdevil/powerdevil-5.18.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Power management for KDE Plasma Shell"
+HOMEPAGE="https://cgit.kde.org/powerdevil.git"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="brightness-control +wireless"
+
+DEPEND="
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5[policykit]
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	virtual/libudev:=
+	x11-libs/libxcb
+	brightness-control? ( app-misc/ddcutil )
+	wireless? (
+		>=kde-frameworks/bluez-qt-${KFMIN}:5
+		>=kde-frameworks/networkmanager-qt-${KFMIN}:5
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=sys-power/upower-0.9.23
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_DDCUTIL=$(usex brightness-control)
+		$(cmake_use_find_package wireless KF5BluezQt)
+		$(cmake_use_find_package wireless KF5NetworkManagerQt)
+	)
+
+	ecm_src_configure
+}

diff --git a/kde-plasma/sddm-kcm/sddm-kcm-5.18.5.ebuild b/kde-plasma/sddm-kcm/sddm-kcm-5.18.5.ebuild
new file mode 100644
index 0000000000..7db29087a9
--- /dev/null
+++ b/kde-plasma/sddm-kcm/sddm-kcm-5.18.5.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma control module for SDDM"
+HOMEPAGE="https://cgit.kde.org/sddm-kcm.git"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	x11-misc/sddm
+"
+
+DOCS=( CONTRIBUTORS )

diff --git a/kde-plasma/systemsettings/systemsettings-5.18.5.ebuild b/kde-plasma/systemsettings/systemsettings-5.18.5.ebuild
new file mode 100644
index 0000000000..4743a96659
--- /dev/null
+++ b/kde-plasma/systemsettings/systemsettings-5.18.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Control Center to configure KDE Plasma desktop"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kactivities-stats-${KFMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-misc/systemd-kcm
+	>=kde-frameworks/kirigami-${KFMIN}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# FIXME: hangs in chroot; similar to bug #640432
+	sed -e "s/^ecm_find_qmlmodule.*org\.kde\.kcm/#&/" \
+		-i CMakeLists.txt || die
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		has_version kde-plasma/kde-gtk-config || \
+			elog "Install kde-plasma/kde-gtk-config to configure looks for GTK+."
+	fi
+}

diff --git a/kde-plasma/user-manager/user-manager-5.18.5.ebuild b/kde-plasma/user-manager/user-manager-5.18.5.ebuild
new file mode 100644
index 0000000000..aae7f47b29
--- /dev/null
+++ b/kde-plasma/user-manager/user-manager-5.18.5.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Simple system settings module to manage the users of your system"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-libs/libpwquality-1.3.0
+"
+RDEPEND="${DEPEND}
+	sys-apps/accountsservice
+"

diff --git a/kde-plasma/xdg-desktop-portal-kde/xdg-desktop-portal-kde-5.18.5.ebuild b/kde-plasma/xdg-desktop-portal-kde/xdg-desktop-portal-kde-5.18.5.ebuild
new file mode 100644
index 0000000000..9f1a0bbc21
--- /dev/null
+++ b/kde-plasma/xdg-desktop-portal-kde/xdg-desktop-portal-kde-5.18.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Backend implementation for xdg-desktop-portal that is using Qt/KDE Frameworks"
+
+LICENSE="LGPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="screencast"
+
+COMMON_DEPEND="
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5[cups]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	screencast? (
+		media-libs/libepoxy
+		media-libs/mesa[gbm]
+		media-video/pipewire:=
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	sys-apps/xdg-desktop-portal[screencast?]
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package screencast PipeWire)
+		$(cmake_use_find_package screencast GBM)
+		$(cmake_use_find_package screencast Epoxy)
+	)
+	ecm_src_configure
+}

diff --git a/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.18.5.ebuild b/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.18.5.ebuild
new file mode 100644
index 0000000000..7ef93d8e5a
--- /dev/null
+++ b/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.18.5.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_ORG_NAME="plasma-workspace"
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit cmake kde.org
+
+DESCRIPTION="Legacy xembed tray icons support for SNI-only system trays"
+HOMEPAGE="https://cgit.kde.org/plasma-workspace.git/tree/xembed-sni-proxy/Readme.md"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+DEPEND="
+	>=dev-qt/qtcore-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/extra-cmake-modules-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	x11-libs/libxcb
+	x11-libs/libXtst
+	x11-libs/xcb-util-image
+"
+RDEPEND="${DEPEND}
+	!<kde-plasma/plasma-workspace-5.14.2:5
+	!kde-plasma/xembed-sni-proxy:0
+"
+
+S="${S}/${PN}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.14.90-standalone.patch" )
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" \
+		-i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
+}