[gentoo-commits] gentoo-x86 commit in x11-misc/dclock: dclock-2.2.2_p4-r1.ebuild ChangeLog dclock-2.1.2_p8.ebuild

[Jeroen Roovers (jer)]

jer         14/07/02 00:46:40

  Modified:             ChangeLog
  Added:                dclock-2.2.2_p4-r1.ebuild
  Removed:              dclock-2.1.2_p8.ebuild
  Log:
  Hack USE=xft onto imake build (bug #514110).
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.20                 x11-misc/dclock/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dclock/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dclock/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dclock/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/dclock/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	22 May 2012 20:59:25 -0000	1.19
+++ ChangeLog	2 Jul 2014 00:46:39 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/dclock
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/dclock/ChangeLog,v 1.19 2012/05/22 20:59:25 ranger Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/dclock/ChangeLog,v 1.20 2014/07/02 00:46:39 jer Exp $
+
+*dclock-2.2.2_p4-r1 (02 Jul 2014)
+
+  02 Jul 2014; Jeroen Roovers <jer@g.o> -dclock-2.1.2_p8.ebuild,
+  +dclock-2.2.2_p4-r1.ebuild:
+  Hack USE=xft onto imake build (bug #514110).
 
   22 May 2012; Brent Baude <ranger@g.o> dclock-2.2.2_p4.ebuild:
   Marking dclock-2.2.2_p4 ppc for bug 416087



1.1                  x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild?rev=1.1&content-type=text/plain

Index: dclock-2.2.2_p4-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild,v 1.1 2014/07/02 00:46:39 jer Exp $

EAPI=4
inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="Digital clock for the X window system."
HOMEPAGE="http://packages.qa.debian.org/d/dclock.html"
SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p*/}.orig.tar.gz
		mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p/-}.debian.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="xft"

RDEPEND="
	xft? (
		media-libs/freetype
		x11-libs/libXft
	)
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXt
"
DEPEND="
	${RDEPEND}
	app-text/rman
	x11-misc/imake
	xft? ( virtual/pkgconfig )
"

S=${WORKDIR}/${P/_p*/}

src_prepare() {
	EPATCH_FORCE=yes EPATCH_SUFFIX=diff epatch "${WORKDIR}"/debian/patches
	epatch "${FILESDIR}"/${P}-include.patch
}

src_configure() {
	if use xft; then
		append-cppflags \
			-DXFT_SUPPORT \
			$( $(tc-getPKG_CONFIG) --cflags freetype2)
	else
		append-cppflags -UXFT_SUPPORT
		sed -i -e '/EXTRA_LIBRARIES/s|^|#|g' Imakefile || die
	fi

	xmkmf || die
}

src_compile() {
	emake \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		EXTRA_LDOPTIONS="${LDFLAGS}"
}

src_install() {
	emake DESTDIR="${D}" install{,.man}

	insinto /usr/share/sounds
	doins sounds/*

	insinto /usr/share/X11/app-defaults
	newins Dclock.ad DClock

	dodoc README TODO
}