[gentoo-commits] repo/gentoo:master commit in: dev-libs/ocl-icd/

[James Le Cuirot]

commit:     108710c9a2875c0b31f78b917eaa40fbd136bd59
Author:     Peter Levine <plevine457 <AT> gmail <DOT> com>
AuthorDate: Sat Mar 27 08:16:37 2021 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Sat May 29 14:43:18 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=108710c9

dev-libs/ocl-icd: Remove ruby24 from USE_RUBY

dev-lang/ruby:2.4 is no longer in the gentoo tree.

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Peter Levine <plevine457 <AT> gmail.com>
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 dev-libs/ocl-icd/ocl-icd-2.2.14-r1.ebuild | 44 +++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/dev-libs/ocl-icd/ocl-icd-2.2.14-r1.ebuild b/dev-libs/ocl-icd/ocl-icd-2.2.14-r1.ebuild
new file mode 100644
index 00000000000..94aa219cb56
--- /dev/null
+++ b/dev-libs/ocl-icd/ocl-icd-2.2.14-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby25 ruby26 ruby27"
+inherit autotools flag-o-matic multilib-minimal ruby-single
+
+DESCRIPTION="Alternative to vendor specific OpenCL ICD loaders"
+HOMEPAGE="https://github.com/OCL-dev/ocl-icd"
+SRC_URI="https://github.com/OCL-dev/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Does nothing now but by keeping it here we avoid having to have virtual/opencl
+# handle ebuilds both with and without this flag.
+IUSE="+khronos-headers"
+
+BDEPEND="${RUBY_DEPS}"
+DEPEND=">=dev-util/opencl-headers-2020.12.18"
+RDEPEND="${DEPEND}
+	!app-eselect/eselect-opencl
+	!dev-libs/opencl-icd-loader"
+
+src_prepare() {
+	replace-flags -Os -O2 # bug 646122
+
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# dev-util/opencl-headers ARE official Khronos Group headers, what this option
+	# does is disable the use of the bundled ones
+	ECONF_SOURCE="${S}" econf --enable-pthread-once --disable-official-khronos-headers
+}
+
+multilib_src_install() {
+	default
+
+	# Drop .la files
+	find "${ED}" -name '*.la' -delete || die
+}