[gentoo-commits] repo/gentoo:master commit in: profiles/, dev-libs/gobject-introspection/

[Mart Raudsepp]

commit:     9209b919ea34f5432fe99fec73bc768806f19831
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 18 15:59:23 2021 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Sep 18 16:05:22 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9209b919

dev-libs/gobject-introspection: bump to 1.70.0

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-libs/gobject-introspection/Manifest            |  1 +
 .../gobject-introspection-1.70.0.ebuild            | 77 ++++++++++++++++++++++
 profiles/package.mask                              |  1 +
 3 files changed, 79 insertions(+)

diff --git a/dev-libs/gobject-introspection/Manifest b/dev-libs/gobject-introspection/Manifest
index bdfba874bc5..876524d19fb 100644
--- a/dev-libs/gobject-introspection/Manifest
+++ b/dev-libs/gobject-introspection/Manifest
@@ -1 +1,2 @@
 DIST gobject-introspection-1.68.0.tar.xz 1019732 BLAKE2B 2f99cc9cec5ea05f1a5fa4473d1ad424cc1f6b097075f798e89cf740519db180417a3f0de37afc8a0cf0771436a9d9f7d6193b69289dfb47ec077d33a7d27c91 SHA512 d2e64c119aa500b624a57baa2cebe9126ab100003d98b771f4fb51cf92748635de352997f702f40656f7c665f3dfedfbfa19912cc7a2d039d254555243bbc381
+DIST gobject-introspection-1.70.0.tar.xz 1029372 BLAKE2B a649ea77b2b7ca392202e21a7f4814aafe57afea7fedb39e78f1df1cd97d0437207c3807a51ece6c9e9bce51fdf961ee7438ccd4efd84b45dbdb57ae19a39272 SHA512 216b376ed423f607e36c723dd6b67975dbfb63c253f2d8bd0b3661e3d69f8c8059cf221db8c5260b0262fad1b7d738f3b2e5fbd51fdbc31e40ccb115c209baf0

diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.70.0.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.70.0.ebuild
new file mode 100644
index 00000000000..7c203556a91
--- /dev/null
+++ b/dev-libs/gobject-introspection/gobject-introspection-1.70.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml"
+inherit gnome.org meson python-single-r1 xdg
+
+DESCRIPTION="Introspection system for GObject-based libraries"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="doctool gtk-doc test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.58.0:2
+	dev-libs/libffi:=
+	doctool? (
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+# Wants real bison, not virtual/yacc
+DEPEND="${RDEPEND}
+	gtk-doc? ( >=dev-util/gtk-doc-1.19
+		app-text/docbook-xml-dtd:4.3
+		app-text/docbook-xml-dtd:4.5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	test? (
+		x11-libs/cairo[glib]
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature test cairo)
+		$(meson_feature doctool)
+		#-Dglib_src_dir
+		$(meson_use gtk-doc gtk_doc)
+		#-Dcairo_libname
+		-Dpython="${EPYTHON}"
+		#-Dgir_dir_prefix
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/
+	python_optimize "${ED}"/usr/$(get_libdir)/gobject-introspection/giscanner
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"/usr/share/aclocal/introspection.m4 \
+		"${ED}"/usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"/usr/share/aclocal || die
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index 0e791603226..746364dc0d6 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -82,6 +82,7 @@ net-libs/libsoup:3.0
 >=dev-libs/glib-2.69
 >=net-libs/glib-networking-2.69
 >=dev-libs/gobject-introspection-common-1.69
+>=dev-libs/gobject-introspection-1.69
 
 # Ionen Wolkens <ionen@g.o> (2021-09-12)
 # No reverse dependencies, stuck on EAPI-5.