[gentoo-commits] repo/gentoo:master commit in: dev-util/diffuse/

[Andrey Grozin]

commit:     3cf318dae8ac11f37d8a2c3ba56ec447856e0ad0
Author:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 21 17:08:25 2021 +0000
Commit:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
CommitDate: Sun Nov 21 17:08:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3cf318da

dev-util/diffuse: bump to 0.7.2

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Andrey Grozin <grozin <AT> gentoo.org>

 dev-util/diffuse/Manifest             |  1 +
 dev-util/diffuse/diffuse-0.7.2.ebuild | 52 +++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/dev-util/diffuse/Manifest b/dev-util/diffuse/Manifest
index 7388c55e4caa..9ac73c226f8f 100644
--- a/dev-util/diffuse/Manifest
+++ b/dev-util/diffuse/Manifest
@@ -1 +1,2 @@
 DIST diffuse-0.6.0.tar.gz 621120 BLAKE2B c39cbe55edb6e1734d4db1343a0b0029ab146fe92ef4edc58cd6ea82bc6780e3f789d6765d2bddecd941fa458781c59ddde71a010f1b90d4ca238e6d6b233dc2 SHA512 fe9842738560dbefe9c546c8bba3f9f1cefcf4c327ad644430c512ec6bb1b4877986ca2b816af75226975eefa9b0f70120a4ed574e2ed90058b0a92380e8995a
+DIST diffuse-0.7.2.tar.gz 512468 BLAKE2B 82d9e13399fe775ae7d901198fca4bcc596914cbc5b2b52497a68292d78298346f51caa2031704858cfc770c7cbd6cb6ce1648fc2df7a674db71041c6abbf1ee SHA512 86488cf5a22b791c036de7299c0cd95e63de0bb26d89080c785972341144e72b006910860652190ff250fa5ecad6c7fac64aa3fe90035eda42b923650e292b76

diff --git a/dev-util/diffuse/diffuse-0.7.2.ebuild b/dev-util/diffuse/diffuse-0.7.2.ebuild
new file mode 100644
index 000000000000..7e314bbfba40
--- /dev/null
+++ b/dev-util/diffuse/diffuse-0.7.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+PLOCALES="cs de es it ja ko pl pt pt_BR ru sv th zh_CN zh_TW"
+inherit meson plocale python-r1 xdg
+
+DESCRIPTION="A graphical tool to compare and merge text files"
+HOMEPAGE="http://diffuse.sourceforge.net/ https://github.com/MightyCreak/diffuse/"
+SRC_URI="https://github.com/MightyCreak/diffuse/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP},cairo]
+	')
+	x11-libs/gtk+:3[introspection]"
+# file collision, bug #279018
+DEPEND="${DEPEND}
+	!sci-chemistry/tinker"
+
+src_prepare() {
+	default
+	plocale_find_changes po '' '.po'
+
+	rm_locale() {
+		rm -f po/${1}.po
+		rm -rf data/usr/share/man/${1}
+		rm -rf data/usr/share/gnome/help/${PN}/$1
+		rm -f data/usr/share/omf/${PN}/${PN}-$1.omf
+		sed -e "/^${1}/d" -i po/LINGUAS
+	}
+
+	plocale_for_each_disabled_locale rm_locale
+}
+
+src_install() {
+	meson_src_install
+	rm "${D}"/usr/bin/${PN} || die "rm ${PN} failed"
+	python_foreach_impl python_doscript ../${P}-build/src/${PN}
+	mkdir "${D}"/usr/share/metainfo || die "mkdir metainfo failed"
+	mv "${D}"/usr/share/appdata/* "${D}"/usr/share/metainfo/ \
+		|| die "mv appdata -> metainfo failed"
+	dodoc AUTHORS CHANGELOG.md README.md
+}