[gentoo-commits] gentoo-x86 commit in media-plugins/kipi-plugins: kipi-plugins-1.7.0.ebuild ChangeLog kipi-plugins-1.5.0.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    10/12/29 18:18:12

  Modified:             ChangeLog
  Added:                kipi-plugins-1.7.0.ebuild
  Removed:              kipi-plugins-1.5.0.ebuild
  Log:
  Version bump; remove old
  
  (Portage version: 2.1.9.26/cvs/Linux i686)

Revision  Changes    Path
1.82                 media-plugins/kipi-plugins/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/kipi-plugins/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/kipi-plugins/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/kipi-plugins/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/kipi-plugins/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	25 Nov 2010 21:08:54 -0000	1.81
+++ ChangeLog	29 Dec 2010 18:18:11 -0000	1.82
@@ -1,6 +1,13 @@
 # ChangeLog for media-plugins/kipi-plugins
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/kipi-plugins/ChangeLog,v 1.81 2010/11/25 21:08:54 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/kipi-plugins/ChangeLog,v 1.82 2010/12/29 18:18:11 dilfridge Exp $
+
+*kipi-plugins-1.7.0 (29 Dec 2010)
+
+  29 Dec 2010; Andreas K. Huettel <dilfridge@g.o>
+  -kipi-plugins-1.5.0.ebuild, +kipi-plugins-1.7.0.ebuild,
+  +files/kipi-plugins-1.7.0-expoblending.patch:
+  Version bump; remove old
 
 *kipi-plugins-1.6.0 (25 Nov 2010)
 



1.1                  media-plugins/kipi-plugins/kipi-plugins-1.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/kipi-plugins/kipi-plugins-1.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/kipi-plugins/kipi-plugins-1.7.0.ebuild?rev=1.1&content-type=text/plain

Index: kipi-plugins-1.7.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/kipi-plugins/kipi-plugins-1.7.0.ebuild,v 1.1 2010/12/29 18:18:11 dilfridge Exp $

EAPI="2"

OPENGL_REQUIRED="optional"
KDE_LINGUAS="ar ast be ca ca@valencia cs da de el en_GB eo es et eu fi fr ga gl hi hne hr is it ja km
lt lv mai ms nb nds nl nn pa pl pt pt_BR ro ru se sv tr uk zh_CN zh_TW"
KMNAME="extragear/graphics"
KDE_MINIMAL="4.5"
inherit flag-o-matic kde4-base

DESCRIPTION="Plugins for the KDE Image Plugin Interface"
HOMEPAGE="http://www.kipi-plugins.org"
[[ ${PV} != *9999* ]] && SRC_URI="mirror://sourceforge/kipi/${P}.tar.bz2
	handbook? ( mirror://gentoo/${PN}-doc-1.5.0.tar.bz2 )"

LICENSE="GPL-2
	handbook? ( FDL-1.2 )"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="cdr calendar crypt debug expoblending handbook +imagemagick ipod mjpeg redeyes scanner"

DEPEND="
	>=dev-libs/expat-2.0.1
	>=dev-libs/libxml2-2.7
	>=dev-libs/libxslt-1.1
	dev-libs/qjson
	$(add_kdebase_dep libkdcraw)
	$(add_kdebase_dep libkexiv2)
	$(add_kdebase_dep libkipi)
	virtual/jpeg
	media-libs/libpng
	media-libs/tiff
	calendar?	( $(add_kdebase_dep kdepimlibs) )
	crypt?		( app-crypt/qca:2 )
	ipod?		(
			  media-libs/libgpod
			  x11-libs/gtk+:2
			)
	redeyes?	( media-libs/opencv )
	scanner? 	(
			  $(add_kdebase_dep libksane)
			  media-gfx/sane-backends
			)
"
RDEPEND="${DEPEND}
	cdr? 		( app-cdr/k3b )
	expoblending? 	( media-gfx/hugin )
	imagemagick? 	( media-gfx/imagemagick )
	mjpeg? 		( media-video/mjpegtools )
"

PATCHES=( "${FILESDIR}/${PN}-1.7.0-expoblending.patch" )

src_prepare() {
	if use handbook; then
		mv "${WORKDIR}/${PN}"-1.5.0/* "${S}/" || die
		echo "add_subdirectory( doc )" >> CMakeLists.txt
	else
		mkdir doc || die
		echo >> doc/CMakeLists.txt || die
	fi

	kde4-base_src_prepare
}

src_configure() {
	# Remove flags -floop-block -floop-interchange
	# -floop-strip-mine due to bug #305443.
	filter-flags -floop-block
	filter-flags -floop-interchange
	filter-flags -floop-strip-mine

	mycmakeargs+=(
		$(cmake-utils_use_with ipod GLIB2)
		$(cmake-utils_use_with ipod GObject)
		$(cmake-utils_use_with ipod Gdk)
		$(cmake-utils_use_with ipod Gpod)
		$(cmake-utils_use_with calendar KdepimLibs)
		$(cmake-utils_use_with redeyes OpenCV)
		$(cmake-utils_use_with opengl OpenGL)
		$(cmake-utils_use_with crypt QCA2)
		$(cmake-utils_use_with scanner Sane)
		$(cmake-utils_use_enable expoblending)
	)

	kde4-base_src_configure
}

src_install() {
	kde4-base_src_install

	if use handbook; then
		dodoc readme-handbook.txt || die
	fi
}