[gentoo-commits] repo/gentoo:master commit in: media-libs/quesoglc/

[Ionen Wolkens]

commit:     b2c27008cb83263ee4c622ac90d67e01da1fd311
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Sat Jul 24 19:02:45 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Wed Jul 28 21:22:23 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b2c27008

media-libs/quesoglc: EAPI8 bump, minor improvements

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/21771
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-libs/quesoglc/quesoglc-0.7.2-r1.ebuild | 54 ++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/media-libs/quesoglc/quesoglc-0.7.2-r1.ebuild b/media-libs/quesoglc/quesoglc-0.7.2-r1.ebuild
new file mode 100644
index 00000000000..6f4fe15c6eb
--- /dev/null
+++ b/media-libs/quesoglc/quesoglc-0.7.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Free implementation of the OpenGL Character Renderer (GLC)"
+HOMEPAGE="http://quesoglc.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-free.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="doc"
+
+RDEPEND="
+	dev-libs/fribidi
+	media-libs/fontconfig
+	media-libs/freetype:2
+	virtual/glu
+	virtual/opengl"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)"
+
+src_prepare() {
+	default
+	rm -r src/fribidi || die
+}
+
+src_configure() {
+	# Uses its own copy of media-libs/glew with GLEW_MX
+	local myeconfargs=(
+		--disable-executables
+		--with-fribidi
+		--without-glew
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake all $(usev doc)
+}
+
+src_install() {
+	default
+
+	use doc && dodoc -r docs/html
+	find "${ED}" -name '*.la' -delete || die
+}