[gentoo-commits] repo/gentoo:master commit in: dev-ada/gnat_util/

[Alfredo Tupone]

commit:     407579c32281e3edfe0bd1ca7aa243a26999f5e1
Author:     Tupone Alfredo <tupone <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  5 17:10:31 2019 +0000
Commit:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Wed Jun  5 17:10:31 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=407579c3

dev-ada/gnat_util: fix dependencies

Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>
Package-Manager: Portage-2.3.66, Repoman-2.3.11

 dev-ada/gnat_util/gnat_util-2017-r1.ebuild | 60 ++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/dev-ada/gnat_util/gnat_util-2017-r1.ebuild b/dev-ada/gnat_util/gnat_util-2017-r1.ebuild
new file mode 100644
index 00000000000..0d7f07e12a8
--- /dev/null
+++ b/dev-ada/gnat_util/gnat_util-2017-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs multiprocessing
+
+MYP=${PN}-gpl-${PV}
+
+DESCRIPTION="Provides access to GNAT compiler internals for AdaCore utilities"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="http://mirrors.cdn.adacore.com/art/591c45e2c7a447af2deed037
+	-> ${MYP}-src.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnat_2016 +gnat_2017 +shared static-libs static-pic"
+
+RDEPEND="gnat_2016? ( dev-lang/gnat-gpl:4.9.4 )
+	gnat_2017? ( dev-lang/gnat-gpl:6.3.0 )"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[gnat_2016(-)?,gnat_2017(-)?]"
+REQUIRED_USE="^^ ( gnat_2016 gnat_2017 )"
+
+S="${WORKDIR}"/${MYP}-src
+
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+src_compile() {
+	if use gnat_2016; then
+		GCC_PV=4.9.4
+	else
+		GCC_PV=6.3.0
+	fi
+	GNATMAKE=${CHOST}-gnatmake-${GCC_PV}
+	emake GNATMAKE="${GNATMAKE} ${ADAFLAGS}" \
+		BUILDER="gprbuild -j$(makeopts_jobs)" generate_sources
+	if use static-libs; then
+		emake BUILDER="gprbuild -v -j$(makeopts_jobs)" build-static
+	fi
+	for kind in shared static-pic; do
+		if use ${kind}; then
+			emake BUILDER="gprbuild -v -j$(makeopts_jobs)" \
+				build-${kind}
+		fi
+	done
+}
+
+src_install() {
+	if use static-libs; then
+		emake prefix="${D}"/usr install-static
+	fi
+	for kind in shared static-pic; do
+		if use ${kind}; then
+			emake prefix="${D}"/usr install-${kind}
+		fi
+	done
+	einstalldocs
+}