[gentoo-commits] gentoo-x86 commit in app-editors/nano: nano-2.3.1-r2.ebuild metadata.xml ChangeLog

[Mike Frysinger (vapier)]

vapier      12/08/26 03:24:37

  Modified:             metadata.xml ChangeLog
  Added:                nano-2.3.1-r2.ebuild
  Log:
  Update nanorc files #397413 by Davide Pesavento.  Split USE=nls dependency #398975 by Maxim Kammerer.
  
  (Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  app-editors/nano/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	23 Sep 2011 21:36:18 -0000	1.5
+++ metadata.xml	26 Aug 2012 03:24:37 -0000	1.6
@@ -27,6 +27,9 @@
   Enable debug messages and assert warnings.  Note that these will all be sent
   straight to stderr rather than some logging facility.
  </flag>
+ <flag name='magic'>
+  Add magic file support (sys-apps/file) to automatically detect appropriate syntax highlighting
+ </flag>
  <flag name='minimal'>
   Disable all fancy features, including ones that otherwise have a dedicated
   USE flag (such as spelling).



1.277                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?rev=1.277&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?rev=1.277&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?r1=1.276&r2=1.277

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.276
retrieving revision 1.277
diff -u -r1.276 -r1.277
--- ChangeLog	29 Jul 2012 16:52:55 -0000	1.276
+++ ChangeLog	26 Aug 2012 03:24:37 -0000	1.277
@@ -1,6 +1,15 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.276 2012/07/29 16:52:55 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.277 2012/08/26 03:24:37 vapier Exp $
+
+*nano-2.3.1-r2 (26 Aug 2012)
+
+  26 Aug 2012; Mike Frysinger <vapier@g.o>
+  +files/nano-2.3.1-bind-unbind-docs.patch, +files/nano-2.3.1-drop-target.patch,
+  +files/nano-2.3.1-gentoo-nanorc.patch, +files/nano-2.3.1-shell-nanorc.patch,
+  +nano-2.3.1-r2.ebuild, metadata.xml:
+  Update nanorc files #397413 by Davide Pesavento.  Split USE=nls dependency
+  #398975 by Maxim Kammerer.
 
   29 Jul 2012; Raúl Porcel <armin76@g.o> nano-2.3.1-r1.ebuild:
   alpha/sparc stable wrt #413897



1.1                  app-editors/nano/nano-2.3.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/nano-2.3.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/nano-2.3.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.3.1-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.3.1-r2.ebuild,v 1.1 2012/08/26 03:24:37 vapier Exp $

EAPI="3"

inherit eutils autotools
if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
	inherit subversion autotools
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="debug justify +magic minimal ncurses nls slang spell unicode"

RDEPEND=">=sys-libs/ncurses-5.9-r1[unicode?]
	magic? ( sys-apps/file )
	nls? ( virtual/libintl )
	!ncurses? ( slang? ( sys-libs/slang ) )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	virtual/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.3.1-drop-target.patch
	epatch "${FILESDIR}"/${PN}-2.3.1-ncurses-pkg-config.patch
	epatch "${FILESDIR}"/${PN}-2.3.1-bind-unbind-docs.patch
	epatch "${FILESDIR}"/${PN}-2.3.1-{shell,gentoo}-nanorc.patch
	eautoreconf
}

src_configure() {
	eval export ac_cv_{header_magic_h,lib_magic_magic_open}=$(usex magic)
	econf \
		--bindir="${EPREFIX}"/bin \
		$(use_enable !minimal color) \
		$(use_enable !minimal multibuffer) \
		$(use_enable !minimal nanorc) \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		$(usex ncurses --without-slang $(use_with slang))
}

src_install() {
	emake DESTDIR="${D}" install || die
	rm -r "${ED}"/usr/share/nano/man-html || die

	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
	dohtml doc/faq.html
	insinto /etc
	newins doc/nanorc.sample nanorc

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano
}

pkg_postinst() {
	einfo "More helpful info about nano, visit the GDP page:"
	einfo "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
}