[gentoo-commits] gentoo-x86 commit in sys-cluster/heartbeat: ChangeLog heartbeat-3.0.5-r1.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    12/10/29 16:44:23

  Modified:             ChangeLog
  Added:                heartbeat-3.0.5-r1.ebuild
  Log:
  Fix heartbeat init script fix #438672
  
  (Portage version: 2.1.11.30/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

Revision  Changes    Path
1.104                sys-cluster/heartbeat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/heartbeat/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/heartbeat/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/heartbeat/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/heartbeat/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	4 May 2012 07:20:30 -0000	1.103
+++ ChangeLog	29 Oct 2012 16:44:23 -0000	1.104
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/heartbeat
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/heartbeat/ChangeLog,v 1.103 2012/05/04 07:20:30 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/heartbeat/ChangeLog,v 1.104 2012/10/29 16:44:23 ultrabug Exp $
+
+*heartbeat-3.0.5-r1 (29 Oct 2012)
+
+  29 Oct 2012; Ultrabug <ultrabug@g.o> +heartbeat-3.0.5-r1.ebuild,
+  files/heartbeat-init:
+  Fix init script vital directory creation wrt #438672 thx to Petric Frank.
 
   04 May 2012; Jeff Horelick <jdhore@g.o> heartbeat-3.0.5.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig



1.1                  sys-cluster/heartbeat/heartbeat-3.0.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/heartbeat/heartbeat-3.0.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/heartbeat/heartbeat-3.0.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: heartbeat-3.0.5-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/heartbeat/heartbeat-3.0.5-r1.ebuild,v 1.1 2012/10/29 16:44:23 ultrabug Exp $

EAPI="2"

PYTHON_DEPEND="2"
inherit python autotools multilib eutils base

DESCRIPTION="Heartbeat high availability cluster manager"
HOMEPAGE="http://www.linux-ha.org/wiki/Heartbeat"
SRC_URI="http://hg.linux-ha.org/${PN}-STABLE_3_0/archive/STABLE-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
IUSE="doc snmp static-libs"

RDEPEND="sys-cluster/cluster-glue
	dev-libs/glib:2
	virtual/ssh
	net-libs/gnutls
	snmp? ( net-analyzer/net-snmp )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	dev-lang/swig
	doc? ( dev-libs/libxslt app-text/docbook-xsl-stylesheets )"

PDEPEND="sys-cluster/resource-agents"

S=${WORKDIR}/Heartbeat-3-0-STABLE-${PV}

PATCHES=(
	"${FILESDIR}/3.0.4-fix_configure.patch"
	"${FILESDIR}/3.0.4-docs.patch"
	"${FILESDIR}/3.0.4-python_tests.patch"
)

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup

	ewarn "If you're upgrading from heartbeat-2.x please follow:"
	ewarn "http://www.gentoo.org/proj/en/cluster/ha-cluster/heartbeat-upgrade.xml"
}

src_prepare() {
	base_src_prepare
	eautoreconf

	cp "${FILESDIR}"/heartbeat-init "${T}" || die
	sed -i \
		-e "/ResourceManager/ s/lib/share/" \
		-e "s:lib:$(get_libdir):g" \
		"${T}"/heartbeat-init || die
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		--disable-fatal-warnings \
		$(use_enable static-libs static) \
		$(use_enable doc) \
		--disable-tipc \
		--enable-dopd \
		--libdir=/usr/$(get_libdir) \
		--localstatedir=/var \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable snmp)
}

src_install() {
	base_src_install

	newinitd "${T}/heartbeat-init" heartbeat || die

	# fix collisions
	rm -rf "${D}"/usr/include/heartbeat/{compress,ha_msg}.h

	use static-libs || find "${D}"/usr/$(get_libdir) -name "*.la" -delete

	if use doc ; then
		dodoc README doc/*.txt doc/AUTHORS  || die
	fi
}