[gentoo-commits] repo/gentoo:master commit in: dev-python/zope-testing/

[Michał Górny]

commit:     edc8e716cb50cb3f0f026925677571811211afd0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  9 20:20:03 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr  9 20:23:22 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=edc8e716

dev-python/zope-testing: Remove namespace pkg dep

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../zope-testing/zope-testing-4.10-r1.ebuild       | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-python/zope-testing/zope-testing-4.10-r1.ebuild b/dev-python/zope-testing/zope-testing-4.10-r1.ebuild
new file mode 100644
index 000000000000..0ad39021764d
--- /dev/null
+++ b/dev-python/zope-testing/zope-testing-4.10-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Zope testing helpers"
+HOMEPAGE="
+	https://pypi.org/project/zope.testing/
+	https://github.com/zopefoundation/zope.testing/
+"
+SRC_URI="mirror://pypi/${P::1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	# this is needed to keep the tests working while
+	# dev-python/namespace-zope is still installed
+	cat > zope/__init__.py <<-EOF || die
+		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
+	EOF
+	eunittest
+	rm zope/__init__.py || die
+}