[gentoo-commits] repo/gentoo:master commit in: dev-python/python-keystoneclient/

[Matt Thode]

commit:     23ef560502d2b5c0f20cc216a62f6a16febff1fb
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Thu Mar  3 15:16:23 2016 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Thu Mar  3 15:27:18 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23ef5605

dev-python/python-keystoneclient: bup

Package-Manager: portage-2.2.26

 dev-python/python-keystoneclient/Manifest          |  1 +
 .../python-keystoneclient-1.7.4.ebuild             | 99 ++++++++++++++++++++++
 2 files changed, 100 insertions(+)

diff --git a/dev-python/python-keystoneclient/Manifest b/dev-python/python-keystoneclient/Manifest
index 811902e..fce3403 100644
--- a/dev-python/python-keystoneclient/Manifest
+++ b/dev-python/python-keystoneclient/Manifest
@@ -1,3 +1,4 @@
 DIST python-keystoneclient-1.3.1.tar.gz 338187 SHA256 8a421dbdf01251119164bf6baa0ef78b261e5dd4d3508748e47b77d7652e7e92 SHA512 d11825b717d0aeec67d4dfb0382173ee834fe3dea2097b8ff9505b86bb08a5579d6fe87509d65022d4436a3a1b4d20f2a877ece3160b53979999495b77df0f08 WHIRLPOOL 9aa0af722f56eb4d98d7efb8a35b1db95207970fba0b32496a9ae4593a16471f976efe1e9bb3690106ec0f5a76b5a744e9177cc7c03d9ffe9ed54111e3bb138c
 DIST python-keystoneclient-1.3.2.tar.gz 342434 SHA256 1b2fd5ceeefd8d75ee749acd2c3dd8805c833c89828075b814392069cd5ae1eb SHA512 4cd986c42256fbc366b81c07ab637fe81358dde530a8e9a5b3f59f4deef5d56fb1799fc82d35a3f04d3e3b810c94bfc21235e93a77c925d235322aeaa20e420c WHIRLPOOL 65b776c928126f92108c1585658a10b89e6563ff8e71f8f249fdb86e11b29811de12b17ddddb39845d66ff9533ae44d93148bd811d1e31577092c3b598348c03
 DIST python-keystoneclient-1.7.3.tar.gz 355578 SHA256 805a317c92cd8700a4733ee80f383b2187de75aeb8e9895015799628df97c68f SHA512 36682247de6c6afee2e0cdf35115b4e6adc4bafef05311337e3299f97a8608a967ca537e8aeaea2e030344a7a8a103c627ff7d118c96c75ac1d169e1bc53d1af WHIRLPOOL 91f6744ea96f8343f1e6665e6db4159fa7d48e9cbc891a8c14aa5bd2165437f9d242f3ee9c960502fda0e26ab1669abec4b32f12be1c79626fe67f6bf25c2137
+DIST python-keystoneclient-1.7.4.tar.gz 356596 SHA256 0bcf562831c4552851f1fa5562f068efd339186a746baae1786498917dc78803 SHA512 c5190e874804baa41f7a4f816eaf974dea943dfbf008a0c66893113168747ffd3910a87dc63edce7f6d4b52ceb5f6f255383a2d88d79a50f4d75d337b3421b46 WHIRLPOOL 172193536486edac34c709355e09e0a1eba9e794f483134c4fa1c33d965f26c573012bc60006dbe707f4267b4f807fade509d67ab56cde3d0285e0cf5a9e0831

diff --git a/dev-python/python-keystoneclient/python-keystoneclient-1.7.4.ebuild b/dev-python/python-keystoneclient/python-keystoneclient-1.7.4.ebuild
new file mode 100644
index 0000000..10b2648
--- /dev/null
+++ b/dev-python/python-keystoneclient/python-keystoneclient-1.7.4.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Client Library for OpenStack Identity"
+HOMEPAGE="http://www.openstack.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+# Note: blacklist version not in portage:
+#doc? ( !~dev-python/sphinx-1.3_preb1[${PYTHON_USEDEP}] )
+
+CDEPEND="
+	>=dev-python/pbr-1.6[${PYTHON_USEDEP}]"
+TCDEPEND="
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-mock-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/tempest-lib-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/testresources-0.2.4[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.2.3[${PYTHON_USEDEP}]
+	>=dev-python/bandit-0.13.2[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		${TCDEPEND}
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		>=dev-python/keyring-2.1[${PYTHON_USEDEP}]
+		!~dev-python/keyring-3.3[${PYTHON_USEDEP}]
+		>=dev-python/oauthlib-0.6[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		${TCDEPEND}
+		>=dev-python/fixtures-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.12[${PYTHON_USEDEP}]
+	!~dev-python/netaddr-0.7.16[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-utils-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7[${PYTHON_USEDEP}]
+	<dev-python/prettytable-0.8[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.2[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.8.0[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.5.0[${PYTHON_USEDEP}]
+"
+PATCHES=(
+)
+
+python_prepare_all() {
+	use doc && esetup.py build_sphinx
+	sed -i '/^argparse/d' requirements.txt || die
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPYTHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}