[gentoo-commits] gentoo-x86 commit in net-misc/curl: ChangeLog curl-7.21.0.ebuild curl-7.20.0.ebuild curl-7.20.0-r1.ebuild curl-7.19.7.ebuild

[Dror Levin (spatz)]

spatz       10/07/01 20:14:55

  Modified:             ChangeLog
  Added:                curl-7.21.0.ebuild
  Removed:              curl-7.20.0.ebuild curl-7.20.0-r1.ebuild
                        curl-7.19.7.ebuild
  Log:
  Version bump, bug 324295.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.161                net-misc/curl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?rev=1.161&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?rev=1.161&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?r1=1.160&r2=1.161

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v
retrieving revision 1.160
retrieving revision 1.161
diff -u -r1.160 -r1.161
--- ChangeLog	22 May 2010 20:59:55 -0000	1.160
+++ ChangeLog	1 Jul 2010 20:14:54 -0000	1.161
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/curl
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.160 2010/05/22 20:59:55 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.161 2010/07/01 20:14:54 spatz Exp $
+
+*curl-7.21.0 (01 Jul 2010)
+
+  01 Jul 2010; Dror Levin <spatz@g.o> -curl-7.19.7.ebuild,
+  -curl-7.20.0.ebuild, -curl-7.20.0-r1.ebuild, +curl-7.21.0.ebuild:
+  Version bump, bug 324295.
 
   22 May 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
   curl-7.20.0-r2.ebuild:



1.1                  net-misc/curl/curl-7.21.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/curl-7.21.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/curl-7.21.0.ebuild?rev=1.1&content-type=text/plain

Index: curl-7.21.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/curl-7.21.0.ebuild,v 1.1 2010/07/01 20:14:54 spatz Exp $

# NOTE: If you bump this ebuild, make sure you bump dev-python/pycurl!

EAPI=2

inherit multilib eutils

#MY_P=${P/_pre/-}
DESCRIPTION="A Client that groks URLs"
HOMEPAGE="http://curl.haxx.se/ http://curl.planetmirror.com"
#SRC_URI="http://cool.haxx.se/curl-daily/${MY_P}.tar.bz2"
#SRC_URI="http://curl.planetmirror.com/download/${P}.tar.bz2"
SRC_URI="http://curl.haxx.se/download/${P}.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="ares gnutls idn ipv6 kerberos ldap libssh2 nss ssl test threads"

RDEPEND="ldap? ( net-nds/openldap )
	ssl? (
		gnutls? ( net-libs/gnutls app-misc/ca-certificates )
		nss? ( !gnutls? ( dev-libs/nss app-misc/ca-certificates ) )
		!gnutls? ( !nss? ( dev-libs/openssl ) )
	)
	idn? ( net-dns/libidn )
	ares? ( >=net-dns/c-ares-1.4.0 )
	kerberos? ( virtual/krb5 )
	libssh2? ( >=net-libs/libssh2-0.16 )"

# fbopenssl (not in gentoo) --with-spnego
# krb4 http://web.mit.edu/kerberos/www/krb4-end-of-life.html

DEPEND="${RDEPEND}
	test? (
		sys-apps/diffutils
		dev-lang/perl
	)"
# used - but can do without in self test: net-misc/stunnel

pkg_setup() {
	if ! use ssl && ( use gnutls || use nss ) ; then
		ewarn "USE='gnutls nss' are ignored without USE='ssl'."
		ewarn "Please review the local USE flags for this package."
	fi
	if use ares && use threads; then
		eerror "USE flags 'ares' and 'threads' are mutually exclusive,"
		eerror "please disable one of them."
		eerror
		die "USE flags 'ares' and 'threads' both enabled"
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-7.20.0-strip-ldflags.patch \
		"${FILESDIR}"/${PN}-7.19.7-test241.patch
}

src_configure() {
	myconf="$(use_enable ldap)
		$(use_enable ldap ldaps)
		$(use_with idn libidn)
		$(use_with kerberos gssapi /usr)
		$(use_with libssh2)
		$(use_enable ipv6)
		$(use_enable ares)
		$(use_enable threads threaded-resolver)
		--enable-http
		--enable-ftp
		--enable-gopher
		--enable-file
		--enable-dict
		--enable-manual
		--enable-telnet
		--enable-smtp
		--enable-pop3
		--enable-imap
		--enable-rtsp
		--enable-nonblocking
		--enable-largefile
		--enable-maintainer-mode
		--disable-sspi
		--without-krb4
		--without-spnego"

	if use ssl ; then
		if use gnutls; then
			myconf="${myconf} --without-ssl --with-gnutls --without-nss"
			myconf="${myconf} --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt"
		elif use nss; then
			myconf="${myconf} --without-ssl --without-gnutls --with-nss"
			myconf="${myconf} --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt"
		else
			myconf="${myconf} --without-gnutls --without-nss --with-ssl"
			myconf="${myconf} --without-ca-bundle --with-ca-path=/etc/ssl/certs"
		fi
	else
		myconf="${myconf} --without-gnutls --without-nss --without-ssl"
	fi

	econf ${myconf} || die 'configure failed'
}

src_install() {
	emake DESTDIR="${D}" install || die "installed failed for current version"
	rm -rf "${D}"/etc/

	# https://sourceforge.net/tracker/index.php?func=detail&aid=1705197&group_id=976&atid=350976
	insinto /usr/share/aclocal
	doins docs/libcurl/libcurl.m4 || die

	dodoc CHANGES README || die
	dodoc docs/FEATURES docs/INTERNALS || die
	dodoc docs/MANUAL docs/FAQ docs/BUGS docs/CONTRIBUTE || die
}