[gentoo-commits] gentoo-x86 commit in app-editors/neovim: neovim-0.0.0_pre20150627.ebuild ChangeLog

[Ben de Groot (yngwin)]

yngwin      15/06/27 03:54:39

  Modified:             ChangeLog
  Added:                neovim-0.0.0_pre20150627.ebuild
  Log:
  new development snapshot
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x4FDF9CFD2FAC514E!)

Revision  Changes    Path
1.5                  app-editors/neovim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/neovim/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/neovim/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/neovim/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/neovim/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	5 Jun 2015 12:13:25 -0000	1.4
+++ ChangeLog	27 Jun 2015 03:54:39 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/neovim
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/neovim/ChangeLog,v 1.4 2015/06/05 12:13:25 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/neovim/ChangeLog,v 1.5 2015/06/27 03:54:39 yngwin Exp $
+
+*neovim-0.0.0_pre20150627 (27 Jun 2015)
+
+  27 Jun 2015; Ben de Groot <yngwin@g.o>
+  +neovim-0.0.0_pre20150627.ebuild:
+  new development snapshot
 
   05 Jun 2015; Justin Lecher <jlec@g.o> metadata.xml:
   Add github to remote-id in metadata.xml



1.1                  app-editors/neovim/neovim-0.0.0_pre20150627.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/neovim/neovim-0.0.0_pre20150627.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/neovim/neovim-0.0.0_pre20150627.ebuild?rev=1.1&content-type=text/plain

Index: neovim-0.0.0_pre20150627.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/neovim/neovim-0.0.0_pre20150627.ebuild,v 1.1 2015/06/27 03:54:39 yngwin Exp $

EAPI=5
inherit cmake-utils flag-o-matic

DESCRIPTION="Vim's rebirth for the 21st century"
HOMEPAGE="https://github.com/neovim/neovim"
if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="git://github.com/neovim/neovim.git"
else
	SRC_URI="http://dev.gentoo.org/~yngwin/distfiles/${P}.tar.xz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="Apache-2.0 vim"
SLOT="0"
IUSE="perl python"

CDEPEND="dev-lang/luajit:2
	>=dev-libs/libtermkey-0.17
	dev-libs/libvterm-neovim
	>=dev-libs/unibilium-1.1.1
	>=dev-libs/libuv-1.2.0
	>=dev-libs/msgpack-0.6.0_pre20150220
	dev-lua/lpeg
	dev-lua/messagepack"
DEPEND="${CDEPEND}
	virtual/libiconv
	virtual/libintl"
RDEPEND="${CDEPEND}
	perl? ( dev-lang/perl )
	python? ( dev-python/neovim-python-client )"

src_prepare() {
	# use our system vim dir
	sed -e '/^# define SYS_VIMRC_FILE/s|$VIM|'"${EPREFIX}"'/etc/vim|' \
		-i src/nvim/os_unix_defs.h || die
	cmake-utils_src_prepare
}

src_configure() {
	export USE_BUNDLED_DEPS=OFF
	append-cflags "-Wno-error"
	append-cppflags "-DNDEBUG -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=1"
	local mycmakeargs=(
		-DCMAKE_BUILD_TYPE=Release
		-DLIBUNIBILIUM_USE_STATIC=OFF
		-DLIBTERMKEY_USE_STATIC=OFF
		-DLIBVTERM_USE_STATIC=OFF
		)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	# install a default configuration file
	insinto /etc/vim
	doins "${FILESDIR}"/nvimrc
}