[gentoo-commits] gentoo-x86 commit in sys-libs/cracklib: ChangeLog cracklib-2.8.18-r1.ebuild

[Mike Frysinger (vapier)]

vapier      11/11/20 06:45:26

  Modified:             ChangeLog
  Added:                cracklib-2.8.18-r1.ebuild
  Log:
  Add USE=static-libs support #378291 by Agostino Sarubbo.
  
  (Portage version: 2.2.0_alpha75/cvs/Linux x86_64)

Revision  Changes    Path
1.158                sys-libs/cracklib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/ChangeLog?rev=1.158&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/ChangeLog?rev=1.158&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/ChangeLog?r1=1.157&r2=1.158

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/cracklib/ChangeLog,v
retrieving revision 1.157
retrieving revision 1.158
diff -u -r1.157 -r1.158
--- ChangeLog	29 Sep 2010 22:35:57 -0000	1.157
+++ ChangeLog	20 Nov 2011 06:45:25 -0000	1.158
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/cracklib
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/cracklib/ChangeLog,v 1.157 2010/09/29 22:35:57 vapier Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/cracklib/ChangeLog,v 1.158 2011/11/20 06:45:25 vapier Exp $
+
+*cracklib-2.8.18-r1 (20 Nov 2011)
+
+  20 Nov 2011; Mike Frysinger <vapier@g.o> +cracklib-2.8.18-r1.ebuild:
+  Add USE=static-libs support #378291 by Agostino Sarubbo.
 
 *cracklib-2.8.18 (29 Sep 2010)
 



1.1                  sys-libs/cracklib/cracklib-2.8.18-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/cracklib-2.8.18-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/cracklib-2.8.18-r1.ebuild?rev=1.1&content-type=text/plain

Index: cracklib-2.8.18-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/cracklib/cracklib-2.8.18-r1.ebuild,v 1.1 2011/11/20 06:45:26 vapier Exp $

EAPI="3"
PYTHON_DEPEND="python? 2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit eutils distutils libtool toolchain-funcs

MY_P=${P/_}
DESCRIPTION="Password Checking Library"
HOMEPAGE="http://sourceforge.net/projects/cracklib"
SRC_URI="mirror://sourceforge/cracklib/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls python static-libs"

RDEPEND="sys-libs/zlib"
DEPEND="${RDEPEND}
	python? ( dev-python/setuptools )"

S=${WORKDIR}/${MY_P}

PYTHON_MODNAME="cracklib.py"
do_python() {
	pushd python > /dev/null || die
	distutils_src_${EBUILD_PHASE}
	popd > /dev/null
}

pkg_setup() {
	# workaround #195017
	if has unmerge-orphans ${FEATURES} && has_version "<${CATEGORY}/${PN}-2.8.10" ; then
		eerror "Upgrade path is broken with FEATURES=unmerge-orphans"
		eerror "Please run: FEATURES=-unmerge-orphans emerge cracklib"
		die "Please run: FEATURES=-unmerge-orphans emerge cracklib"
	fi

	use python && python_pkg_setup
}

src_prepare() {
	elibtoolize #269003
	use python && do_python
}

src_configure() {
	econf \
		--with-default-dict='$(libdir)/cracklib_dict' \
		--without-python \
		$(use_enable nls) \
		$(use_enable static-libs static)
}

src_compile() {
	default
	use python && do_python
}

src_install() {
	emake DESTDIR="${D}" install || die
	use static-libs || rm -f "${ED}"/usr/lib*/libcrack.la
	rm -r "${ED}"/usr/share/cracklib

	use python && do_python

	# move shared libs to /
	gen_usr_ldscript -a crack

	insinto /usr/share/dict
	doins dicts/cracklib-small || die

	dodoc AUTHORS ChangeLog NEWS README*
}

pkg_postinst() {
	if [[ ${ROOT} == "/" ]] ; then
		ebegin "Regenerating cracklib dictionary"
		create-cracklib-dict /usr/share/dict/* > /dev/null
		eend $?
	fi

	use python && distutils_pkg_postinst
}

pkg_postrm() {
	use python && distutils_pkg_postrm
}