[gentoo-commits] repo/gentoo:master commit in: dev-perl/Crypt-SSLeay/

[Kent Fredric]

commit:     311e81f1a1938a08afc041609aea19d404e91acf
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  2 13:22:59 2020 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Thu Jul  2 13:23:52 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=311e81f1

dev-perl/Crypt-SSLeay: -r bump for EAPI7 + CFLAGS love

- EAPI7
- Ensure CFLAGS passed to make/compiler

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>

 .../Crypt-SSLeay/Crypt-SSLeay-0.720.0-r3.ebuild    | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-perl/Crypt-SSLeay/Crypt-SSLeay-0.720.0-r3.ebuild b/dev-perl/Crypt-SSLeay/Crypt-SSLeay-0.720.0-r3.ebuild
new file mode 100644
index 00000000000..eac3765540b
--- /dev/null
+++ b/dev-perl/Crypt-SSLeay/Crypt-SSLeay-0.720.0-r3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=NANIS
+DIST_VERSION=0.72
+inherit perl-module
+
+DESCRIPTION="OpenSSL support for LWP"
+
+LICENSE="Artistic-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="libressl test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!libressl? ( >=dev-libs/openssl-0.9.7c:0= )
+	libressl? ( dev-libs/libressl:0= )
+	virtual/perl-MIME-Base64
+"
+DEPEND="
+	!libressl? ( >=dev-libs/openssl-0.9.7c:0= )
+	libressl? ( dev-libs/libressl:0= )
+"
+BDEPEND="${RDEPEND}
+	virtual/perl-ExtUtils-MakeMaker
+	>=virtual/perl-ExtUtils-CBuilder-0.280.205
+	virtual/perl-Getopt-Long
+	>=dev-perl/Path-Class-0.260.0
+	>=dev-perl/Try-Tiny-0.190.0
+	test? (
+		>=virtual/perl-Test-Simple-0.190.0
+	)
+"
+# PDEPEND: circular dependencies bug #144761
+PDEPEND="
+	dev-perl/libwww-perl
+	>=dev-perl/LWP-Protocol-https-6.20.0
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.720.0-no-ssl3.patch"
+	"${FILESDIR}/${P}-no-dot-inc.patch"
+)
+src_compile() {
+	mymake=(
+		"OPTIMIZE=${CFLAGS}"
+	)
+	perl-module_src_compile
+}