[gentoo-commits] repo/gentoo:master commit in: dev-libs/capstone/

[Sergei Trofimovich]

commit:     efa42a94e69af8e64611dd012457691e8b420adf
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Wed May 20 17:53:27 2020 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Wed May 20 17:53:40 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=efa42a94

dev-libs/capstone: switch to cmake, add USE=static-libs, bug #724302

Make-based build system can't handle shared-only cstoll linkage.
Let's switch over to cmake and see how it goes.

Reported-by: Agostino Sarubbo
Closes: https://bugs.gentoo.org/724302
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>

 dev-libs/capstone/capstone-4.0.2-r1.ebuild | 70 ++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

diff --git a/dev-libs/capstone/capstone-4.0.2-r1.ebuild b/dev-libs/capstone/capstone-4.0.2-r1.ebuild
new file mode 100644
index 00000000000..6de5971d2cd
--- /dev/null
+++ b/dev-libs/capstone/capstone-4.0.2-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{3_6,3_7} )
+
+inherit cmake-utils distutils-r1 toolchain-funcs
+
+DESCRIPTION="disassembly/disassembler framework + bindings"
+HOMEPAGE="http://www.capstone-engine.org/"
+SRC_URI="https://github.com/aquynh/${PN}/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/4" # libcapstone.so.4
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RESTRICT="!test? ( test )"
+
+IUSE="python static-libs test"
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+S=${WORKDIR}/${P/_rc/-rc}
+
+wrap_python() {
+	if use python; then
+		pushd bindings/python >/dev/null || die
+		distutils-r1_${1} "$@"
+		popd >/dev/null
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	wrap_python ${FUNCNAME}
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCAPSTONE_BUILD_TESTS="$(usex test)"
+		-DCAPSTONE_BUILD_STATIC="$(usex static-libs)"
+	)
+	cmake-utils_src_configure
+
+	wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	wrap_python ${FUNCNAME}
+}
+
+src_test() {
+	cmake-utils_src_test
+
+	wrap_python ${FUNCNAME}
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	wrap_python ${FUNCNAME}
+}