[gentoo-commits] repo/gentoo:master commit in: app-crypt/qca/

[Andreas Sturmlechner]

commit:     f5060516b2c6fc1b9d6527079654c25dffd5d28d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 10 13:48:57 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Jun 10 15:32:14 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5060516

app-crypt/qca: 2.3.3 version bump

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-crypt/qca/Manifest         |  1 +
 app-crypt/qca/qca-2.3.3.ebuild | 82 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
index 880177b2651..d4d9f7558a0 100644
--- a/app-crypt/qca/Manifest
+++ b/app-crypt/qca/Manifest
@@ -1 +1,2 @@
 DIST qca-2.3.2.tar.xz 735500 BLAKE2B 559b27c48c756f2b4f4f206d2157c90ae4856610f1539b4162a2bffe7fffe19b5c768d3d3f9d0486d2098fb403eb64372515815f49fd428d22dfc0405d99e435 SHA512 da6415a097c99b878f45730c1dd1e0bfc7f96858ad7018918ac7c2ae2eca830cb73e131173b1018ee4caa6c3a504b80c8ad28f8f9448c2fd1593161c2ac8aad4
+DIST qca-2.3.3.tar.xz 736456 BLAKE2B f0812fd33bd19293c8034e48bcf214d2d70dc1397860779c2c145fe841365384a8eb6bad9859520d32104010acb0cefb97e3a974b9852a37ca8039d52d9dbd03 SHA512 9a262350502daa1dd10802a7a24f0e4712d87d4ddcf752452a51caa8694a30835672f54f8e600aa8dc4afdac9ef073641deed52a24423e304d18ad2b83deeca6

diff --git a/app-crypt/qca/qca-2.3.3.ebuild b/app-crypt/qca/qca-2.3.3.ebuild
new file mode 100644
index 00000000000..5f2030b035f
--- /dev/null
+++ b/app-crypt/qca/qca-2.3.3.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde.org cmake qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="https://userbase.kde.org/QCA"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+IUSE="botan debug doc examples gcrypt gpg logger nss pkcs11 sasl softstore +ssl test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	botan? ( dev-libs/botan:= )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	pkcs11? (
+		>=dev-libs/openssl-1.1
+		dev-libs/pkcs11-helper
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? ( >=dev-libs/openssl-1.1:0= )
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-qt/qtnetwork:5
+		dev-qt/qttest:5
+	)
+"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+PATCHES=( "${FILESDIR}/${PN}-disable-pgp-test.patch" )
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(qt5_get_mkspecsdir)/features"
+		-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(qt5_get_plugindir)"
+		$(qca_plugin_use botan)
+		$(qca_plugin_use gcrypt)
+		$(qca_plugin_use gpg gnupg)
+		$(qca_plugin_use logger)
+		$(qca_plugin_use nss)
+		$(qca_plugin_use pkcs11)
+		$(qca_plugin_use sasl cyrus-sasl)
+		$(qca_plugin_use softstore)
+		$(qca_plugin_use ssl ossl)
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null || die
+		doxygen Doxyfile || die
+		dodoc -r apidocs/html
+		popd >/dev/null || die
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}