[gentoo-commits] gentoo-x86 commit in dev-python/oosuite: metadata.xml oosuite-0.43.ebuild ChangeLog oosuite-0.38.ebuild oosuite-0.39.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    13/02/27 21:57:45

  Modified:             metadata.xml ChangeLog
  Added:                oosuite-0.43.ebuild
  Removed:              oosuite-0.38.ebuild oosuite-0.39.ebuild
  Log:
  Version bump. Switch to python-r1 framework. Re-organize SpaceFuncs to make it work
  
  (Portage version: 2.2.01.21688-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.2                  dev-python/oosuite/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/oosuite/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	7 Jan 2012 20:39:27 -0000	1.1
+++ metadata.xml	27 Feb 2013 21:57:45 -0000	1.2
@@ -4,7 +4,7 @@
 <herd>sci-mathematics</herd>
 <longdescription lang='en'>
   The OpenOpt suite of Python packages contains the following modules:
-  * OpenOpt: universal numerical optimization package with
+  * openopt: universal numerical optimization package with
     several solvers (e.g. ralg) and connections to tens of other,
     graphical output of convergence. 
   * FuncDesigner: tool to rapidly build functions over



1.7                  dev-python/oosuite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/oosuite/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	1 Nov 2012 19:30:56 -0000	1.6
+++ ChangeLog	27 Feb 2013 21:57:45 -0000	1.7
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/oosuite
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/oosuite/ChangeLog,v 1.6 2012/11/01 19:30:56 bicatali Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/oosuite/ChangeLog,v 1.7 2013/02/27 21:57:45 bicatali Exp $
+
+*oosuite-0.43 (27 Feb 2013)
+
+  27 Feb 2013; Sébastien Fabbro <bicatali@g.o> +oosuite-0.43.ebuild,
+  -oosuite-0.38.ebuild, -oosuite-0.39.ebuild, metadata.xml:
+  Version bump. Switch to python-r1 framework. Re-organize SpaceFuncs to make it
+  work
 
 *oosuite-0.42 (01 Nov 2012)
 



1.1                  dev-python/oosuite/oosuite-0.43.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/oosuite-0.43.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/oosuite/oosuite-0.43.ebuild?rev=1.1&content-type=text/plain

Index: oosuite-0.43.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/oosuite/oosuite-0.43.ebuild,v 1.1 2013/02/27 21:57:45 bicatali Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE='tk?'

inherit distutils-r1 eutils

MYPN="OOSuite"
MYPID="f/f3"

DESCRIPTION="OpenOpt suite of Python modules for numerical optimization"
HOMEPAGE="http://openopt.org/"
SRC_URI="http://openopt.org/images/${MYPID}/${MYPN}.zip -> ${MYPN}-${PV}.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="examples minimal tk"

RDEPEND="
	dev-python/numpy[${PYTHON_USEDEP}]
	!minimal? (
		dev-python/cvxopt[glpk,${PYTHON_USEDEP}]
		dev-python/lp_solve[${PYTHON_USEDEP}]
		dev-python/matplotlib[${PYTHON_USEDEP}]
		dev-python/setproctitle[${PYTHON_USEDEP}]
		sci-libs/nlopt[python]
		sci-libs/scipy[${PYTHON_USEDEP}] )"
DEPEND="
	app-arch/unzip
	dev-python/numpy[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]"

S="${WORKDIR}/PythonPackages"

OO_DIRS="DerApproximator FuncDesigner OpenOpt SpaceFuncs"

python_prepare() {
	# reorganize SpaceFuncs
	pushd SpaceFuncs > /dev/null
	mkdir SpaceFuncs
	cp __version__.py SpaceFuncs || die
	mv SpaceFuncs.py __init__.py kernel SpaceFuncs || die
	popd > /dev/null
	local d
	for d in ${OO_DIRS}; do
		pushd ${d} > /dev/null
		find . -name "*COPYING*" -delete
		find . -type d -name examples -or -name tests -or -name doc \
			-exec rm -r '{}' +
		distutils-r1_python_prepare
		popd > /dev/null
	done
}

src_prepare() {
	distutils-r1_src_prepare
	# move all examples and tests to ease installation in proper directory
	mkdir "${WORKDIR}/examples"
	local d e
	for d in ${OO_DIRS}; do
		mkdir "${WORKDIR}/examples/${d}" || die
		for e in $(find ${d} -type d -name examples -or -name tests -or -name doc); do
			mv ${e} "${WORKDIR}/examples/${d}/" || die
		done
	done
}

python_compile() {
	local d
	for d in ${OO_DIRS}; do
		pushd ${d} > /dev/null
		distutils-r1_python_compile
		popd > /dev/null
	done
}

python_test() {
	local d t oldpath=${PYTHONPATH}
	for d in ${OO_DIRS}; do
		PYTHONPATH="${BUILD_DIR}/${d}/build/lib:${PYTHONPATH}"
	done
	export PYTHONPATH
	cd "${WORKDIR}"/examples
	# limit the tests, other need more dependencies
	for t in \
		DerApproximator/tests/t_check.py \
		FuncDesigner/examples/sle1.py \
		OpenOpt/examples/nlp_1.py \
		SpaceFuncs/examples/triangle.py
	do
		"${PYTHON}" ${t} || die "test ${t} failed"
	done
	export PYTHONPATH=${oldpath}
}

python_install() {
	local d
	for d in ${OO_DIRS}; do
		pushd ${d} > /dev/null
		distutils-r1_python_install
		popd > /dev/null
	done
	use examples && EXAMPLES="${WORKDIR}"/examples
}