[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-epgsearch: ChangeLog vdr-epgsearch-0.9.25_beta11.ebuild

[Matthias Schwarzott (zzam)]

zzam        09/03/21 16:02:06

  Modified:             ChangeLog
  Added:                vdr-epgsearch-0.9.25_beta11.ebuild
  Log:
  Version bumped.
  (Portage version: 2.1.6.9/cvs/Linux i686)

Revision  Changes    Path
1.40                 media-plugins/vdr-epgsearch/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	8 Nov 2008 16:53:07 -0000	1.39
+++ ChangeLog	21 Mar 2009 16:02:06 -0000	1.40
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/vdr-epgsearch
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog,v 1.39 2008/11/08 16:53:07 zzam Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog,v 1.40 2009/03/21 16:02:06 zzam Exp $
+
+*vdr-epgsearch-0.9.25_beta11 (21 Mar 2009)
+
+  21 Mar 2009; Matthias Schwarzott <zzam@g.o>
+  +vdr-epgsearch-0.9.25_beta11.ebuild:
+  Version bumped.
 
   08 Nov 2008; Matthias Schwarzott <zzam@g.o>
   vdr-epgsearch-0.9.24-r2.ebuild:



1.1                  media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta11.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta11.ebuild?rev=1.1&content-type=text/plain

Index: vdr-epgsearch-0.9.25_beta11.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta11.ebuild,v 1.1 2009/03/21 16:02:06 zzam Exp $

inherit vdr-plugin

DESCRIPTION="Video Disk Recorder epgsearch plugin"
HOMEPAGE="http://winni.vdr-developer.org/epgsearch"

case ${P#*_} in
	rc*|beta*)
		MY_P="${P/_/.}"
		SRC_URI="http://winni.vdr-developer.org/epgsearch/downloads/beta/${MY_P}.tgz"
		S="${WORKDIR}/${MY_P#vdr-}"
		;;
	*)
		SRC_URI="http://winni.vdr-developer.org/epgsearch/downloads/${P}.tgz"
		;;
esac

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pcre"

DEPEND=">=media-video/vdr-1.3.45
	pcre? ( dev-libs/libpcre )"
RDEPEND="${DEPEND}"

src_unpack() {
	vdr-plugin_src_unpack

	cd "${S}"
	fix_vdr_libsi_include conflictcheck.c

	use pcre && sed -i Makefile -e 's/^#HAVE_PCREPOSIX/HAVE_PCREPOSIX/'

	# install conf-file disabled
	sed -e '/^Menu/s:^:#:' -i conf/epgsearchmenu.conf
}

src_install() {
	vdr-plugin_src_install
	cd "${S}"
	diropts "-m755 -o vdr -g vdr"
	keepdir /etc/vdr/plugins/epgsearch
	insinto /etc/vdr/plugins/epgsearch

	doins conf/epgsearchmenu.conf
	doins conf/epgsearchconflmail.templ conf/epgsearchupdmail.templ

	dodoc conf/*.templ

	emake install-doc MANDIR="${D}/usr/share/man"
	dodoc MANUAL
}

pkg_preinst() {
	has_version "<${CATEGORY}/${PN}-0.9.18"
	previous_less_than_0_9_18=$?
}

pkg_postinst() {
	vdr-plugin_pkg_postinst
	if [[ $previous_less_than_0_9_18 = 0 ]] ; then
		elog "Moving config-files to new location /etc/vdr/plugins/epgsearch"
		cd "${ROOT}"/etc/vdr/plugins
		local f
		local moved=""
		for f in epgsearch*.* .epgsearch*; do
			[[ -e ${f} ]] || continue
			mv "${f}" "${ROOT}/etc/vdr/plugins/epgsearch"
			moved="${moved} ${f}"
		done
		elog "These files were moved:${moved}"
	fi
}