[gentoo-commits] gentoo-x86 commit in app-misc/vifm: ChangeLog vifm-0.7.7.ebuild

[JosA MarAa Alonso (nimiux)]

nimiux      14/07/08 15:43:58

  Modified:             ChangeLog
  Added:                vifm-0.7.7.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key D628E536)

Revision  Changes    Path
1.34                 app-misc/vifm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/vifm/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/vifm/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/vifm/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/vifm/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	15 May 2014 12:01:07 -0000	1.33
+++ ChangeLog	8 Jul 2014 15:43:58 -0000	1.34
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/vifm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/vifm/ChangeLog,v 1.33 2014/05/15 12:01:07 nimiux Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/vifm/ChangeLog,v 1.34 2014/07/08 15:43:58 nimiux Exp $
+
+*vifm-0.7.7 (08 Jul 2014)
+
+  08 Jul 2014; Chema Alonso <nimiux@g.o> +vifm-0.7.7.ebuild:
+  Version bump
 
   15 May 2014; Chema Alonso <nimiux@g.o> metadata.xml:
   Take maintainership of package



1.1                  app-misc/vifm/vifm-0.7.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/vifm/vifm-0.7.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/vifm/vifm-0.7.7.ebuild?rev=1.1&content-type=text/plain

Index: vifm-0.7.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/vifm/vifm-0.7.7.ebuild,v 1.1 2014/07/08 15:43:58 nimiux Exp $

EAPI=5
inherit base vim-doc

DESCRIPTION="Console file manager with vi(m)-like keybindings"
HOMEPAGE="http://vifm.sourceforge.net/"
SRC_URI="mirror://sourceforge/vifm/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~s390 ~x86"
IUSE="X developer +extended-keys gtk +magic vim vim-syntax"

DEPEND="
	>=sys-libs/ncurses-5.7-r7
	magic? ( sys-apps/file )
	gtk? ( x11-libs/gtk+:2 )
	X? ( x11-libs/libX11 )
"
RDEPEND="
	${DEPEND}
	vim? ( || ( app-editors/vim app-editors/gvim ) )
	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
"

DOCS=( AUTHORS TODO README )

src_configure() {
	econf \
		$(use_enable developer) \
		$(use_enable extended-keys) \
		$(use_with magic libmagic) \
		$(use_with gtk) \
		$(use_with X X11)
}

src_install() {
	base_src_install

	if use vim; then
		local t
		for t in doc plugin; do
			insinto /usr/share/vim/vimfiles/"${t}"
			doins "${S}"/data/vim/"${t}"/"${PN}".*
		done
	fi

	if use vim-syntax; then
		local t
		for t in ftdetect ftplugin syntax; do
			insinto /usr/share/vim/vimfiles/"${t}"
			doins "${S}"/data/vim/"${t}"/"${PN}".vim
		done
	fi
}

src_test() {
	emake check
}

pkg_postinst() {
	if use vim; then
		update_vim_helptags

		if [[ -n ${REPLACING_VERSIONS} ]]; then
			elog
			elog "You don't need to copy or link any files for"
			elog "  the vim plugin and documentation to work anymore."
			elog "If you copied any vifm files to ~/.vim/ manually"
			elog "  in earlier vifm versions, please delete them."
		fi
		elog
		elog "To use vim in vifm to view the documentation"
		elog "  edit ~/.vifm/vifmrc and set vimhelp instead of novimhelp"
		elog
	fi
}

pkg_postrm() {
	use vim && update_vim_helptags
}