[gentoo-commits] repo/gentoo:master commit in: x11-libs/libva-compat/

[Jason A. Donenfeld]

commit:     cc60cfdd419b765696ec50b523bddb71d975e652
Author:     Jason A. Donenfeld <zx2c4 <AT> gentoo <DOT> org>
AuthorDate: Mon Nov  8 23:30:30 2021 +0000
Commit:     Jason A. Donenfeld <zx2c4 <AT> gentoo <DOT> org>
CommitDate: Mon Nov  8 23:37:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc60cfdd

x11-libs/libva-compat: use optfeatures instead of VIDEO_CARDS

VIDEO_CARDS is ill suited for this because the situation with Intel GPUs
is complicated.

Discussed-with: Matt Turner <mattst88 <AT> gentoo.org>
Discussed-with: Sam James <sam <AT> gentoo.org>
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Jason A. Donenfeld <zx2c4 <AT> gentoo.org>

 x11-libs/libva-compat/libva-compat-1.8.3-r2.ebuild | 67 ++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/x11-libs/libva-compat/libva-compat-1.8.3-r2.ebuild b/x11-libs/libva-compat/libva-compat-1.8.3-r2.ebuild
new file mode 100644
index 00000000000..af57dbec426
--- /dev/null
+++ b/x11-libs/libva-compat/libva-compat-1.8.3-r2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal optfeature
+
+MY_PN="${PN%-compat}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+SRC_URI="https://github.com/01org/libva/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="1"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+drm egl opengl wayland X"
+
+RDEPEND=">=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+	)
+	egl? ( >=media-libs/mesa-9.1.6[egl(+),${MULTILIB_USEDEP}] )
+	opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
+	!x11-libs/libva:0/0"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="|| ( drm wayland X )
+		opengl? ( X )"
+
+S="${WORKDIR}/${MY_P}"
+DOCS=( NEWS )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		$(use_enable opengl glx)
+		$(use_enable X x11)
+		$(use_enable wayland)
+		$(use_enable egl)
+		$(use_enable drm)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	emake -C va DESTDIR="${D}" install-libLTLIBRARIES
+	rm -vf "${ED}"/usr/$(get_libdir)/*.{la,so} || die
+}
+
+pkg_postinst() {
+	optfeature_header
+	optfeature "NVIDIA GPU support" x11-libs/libva-vdpau-driver
+	optfeature "Older Intel GPU support" x11-libs/libva-intel-driver
+	optfeature "Newer Intel GPU support" x11-libs/libva-intel-media-driver
+}