[gentoo-commits] repo/gentoo:master commit in: x11-plugins/asmem/, x11-plugins/asmem/files/

[Michael Orlitzky]

commit:     01fa5298a358a092d7f328b454af09dc6ed020c3
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 28 16:32:07 2016 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Sun Aug 28 16:36:46 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=01fa5298

x11-plugins/asmem: new EAPI=6 revision that respects LDFLAGS.

This new revision is based on the ebuild supplied by Michael
Mair-Keimberger in bug 334771. I turned his sed command into a patch,
and further updated the ebuild to EAPI=6.

Gentoo-Bug: 334771

Package-Manager: portage-2.2.28

 x11-plugins/asmem/asmem-1.12-r1.ebuild        | 41 +++++++++++++++++++++++++++
 x11-plugins/asmem/files/respect-ldflags.patch | 27 ++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/x11-plugins/asmem/asmem-1.12-r1.ebuild b/x11-plugins/asmem/asmem-1.12-r1.ebuild
new file mode 100644
index 00000000..dfe5d5c
--- /dev/null
+++ b/x11-plugins/asmem/asmem-1.12-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Monitor the utilization level of memory, cache and swap space"
+HOMEPAGE="http://www.tigr.net/"
+SRC_URI="${HOMEPAGE}afterstep/download/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="jpeg"
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libXpm
+	x11-libs/libXext
+	jpeg? ( virtual/jpeg:0 )"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+PATCHES=( "${FILESDIR}/respect-ldflags.patch" )
+
+src_configure() {
+	econf $(use_enable jpeg)
+}
+
+src_compile() {
+	emake CC=$(tc-getCC) LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin "${PN}"
+	newman "${PN}.man" "${PN}.1"
+	einstalldocs
+}

diff --git a/x11-plugins/asmem/files/respect-ldflags.patch b/x11-plugins/asmem/files/respect-ldflags.patch
new file mode 100644
index 00000000..75deb42
--- /dev/null
+++ b/x11-plugins/asmem/files/respect-ldflags.patch
@@ -0,0 +1,27 @@
+From 1f02c866884bd08dda27aada5ebaa92e560144d4 Mon Sep 17 00:00:00 2001
+From: Michael Orlitzky <michael@××××××××.com>
+Date: Sun, 28 Aug 2016 12:15:34 -0400
+Subject: [PATCH 1/1] autoconf/Makefile.common.in: add $LDFLAGS to the linker
+ command.
+
+Gentoo-Bug: 334771
+---
+ autoconf/Makefile.common.in | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/autoconf/Makefile.common.in b/autoconf/Makefile.common.in
+index 2409579..08e01a9 100644
+--- a/autoconf/Makefile.common.in
++++ b/autoconf/Makefile.common.in
+@@ -34,7 +34,7 @@ indent:
+ 		done
+ 
+ $(PROG):        $(OBJS)
+-		$(CC) $(OBJS) $(LIBRARIES) $(EXTRA_LIBRARIES) -o $(@)
++		$(CC) $(OBJS) $(LIBRARIES) $(EXTRA_LIBRARIES) -o $(@) $(LDFLAGS)
+ 
+ .c.o:
+ 		$(CC) $(CCFLAGS) $(EXTRA_DEFINES) $(INCLUDES) $(EXTRA_INCLUDES) -c $*.c
+-- 
+2.7.3
+