[gentoo-commits] gentoo-x86 commit in net-im/skype: ChangeLog skype-4.2.0.11-r1.ebuild

[Arun Raghavan (ford_prefect)]

ford_prefect    13/08/02 15:57:52

  Modified:             ChangeLog
  Added:                skype-4.2.0.11-r1.ebuild
  Log:
  Fix up the .desktop file to work around a Skype bug with PulseAudio 4.0. Dropped our desktop file generation and just fixed up the one that Skype ships. Also fixed a grammatical error in the ebuild description.
  
  (Portage version: 2.2.0_alpha187/cvs/Linux x86_64, signed Manifest commit with key 29C3E2EC)

Revision  Changes    Path
1.150                net-im/skype/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/skype/ChangeLog?rev=1.150&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/skype/ChangeLog?rev=1.150&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/skype/ChangeLog?r1=1.149&r2=1.150

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/skype/ChangeLog,v
retrieving revision 1.149
retrieving revision 1.150
diff -u -r1.149 -r1.150
--- ChangeLog	20 Jul 2013 00:45:20 -0000	1.149
+++ ChangeLog	2 Aug 2013 15:57:52 -0000	1.150
@@ -1,6 +1,14 @@
 # ChangeLog for net-im/skype
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/skype/ChangeLog,v 1.149 2013/07/20 00:45:20 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/skype/ChangeLog,v 1.150 2013/08/02 15:57:52 ford_prefect Exp $
+
+*skype-4.2.0.11-r1 (02 Aug 2013)
+
+  02 Aug 2013; Arun Raghavan <ford_prefect@g.o>
+  +skype-4.2.0.11-r1.ebuild, +files/skype-4.2.0.11-desktop.patch:
+  Fix up the .desktop file to work around a Skype bug with PulseAudio 4.0.
+  Dropped our desktop file generation and just fixed up the one that Skype
+  ships. Also fixed a grammatical error in the ebuild description.
 
   20 Jul 2013; Jonathan Callen <abcd@g.o> skype-2.2.0.35-r99.ebuild,
   skype-4.0.0.8-r1.ebuild, skype-4.1.0.20.ebuild, skype-4.2.0.11.ebuild:



1.1                  net-im/skype/skype-4.2.0.11-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/skype/skype-4.2.0.11-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/skype/skype-4.2.0.11-r1.ebuild?rev=1.1&content-type=text/plain

Index: skype-4.2.0.11-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/skype/skype-4.2.0.11-r1.ebuild,v 1.1 2013/08/02 15:57:52 ford_prefect Exp $

EAPI=5
inherit eutils gnome2-utils pax-utils

DESCRIPTION="A P2P Internet Telephony (VoiceIP) client"
HOMEPAGE="http://www.skype.com/"
SRC_URI="http://download.${PN}.com/linux/${P}.tar.bz2"

LICENSE="${PN}-4.0.0.7-copyright ${PN}-4.0.0.7-third-party_attributions.txt"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pax_kernel selinux"

QA_PREBUILT=opt/bin/${PN}
RESTRICT="mirror strip" #299368

EMUL_X86_VER=20120520

RDEPEND="virtual/ttf-fonts
	amd64? (
		>=app-emulation/emul-linux-x86-baselibs-${EMUL_X86_VER}
		>=app-emulation/emul-linux-x86-qtlibs-${EMUL_X86_VER}
		>=app-emulation/emul-linux-x86-soundlibs-${EMUL_X86_VER}
		|| (
			(
				x11-libs/libX11[abi_x86_32]
				x11-libs/libXext[abi_x86_32]
				x11-libs/libXScrnSaver[abi_x86_32]
				x11-libs/libXv[abi_x86_32]
			)
			>=app-emulation/emul-linux-x86-xlibs-${EMUL_X86_VER}
		)
	)
	!amd64? (
		media-libs/alsa-lib
		x11-libs/libX11
		x11-libs/libXext
		x11-libs/libXScrnSaver
		x11-libs/libXv
		dev-qt/qtcore:4
		dev-qt/qtdbus:4
		dev-qt/qtgui:4[accessibility,dbus(+)]
		dev-qt/qtwebkit:4
	)
	selinux? ( sec-policy/selinux-skype )"

src_prepare() {
	epatch "${FILESDIR}/${P}-desktop.patch"
}

src_compile() {
	type -P lrelease >/dev/null && lrelease lang/*.ts
	rm -f lang/*.ts
}

src_install() {
	into /opt
	dobin ${PN}
	fowners root:audio /opt/bin/${PN}

	insinto /etc/dbus-1/system.d
	doins ${PN}.conf

	insinto /usr/share/skype
	doins -r avatars lang sounds

	dodoc README

	local res
	for res in 16 32 48 64 96 128 256; do
		newicon -s ${res} icons/SkypeBlue_${res}x${res}.png ${PN}.png
	done

	domenu skype.desktop

	if use pax_kernel; then
		pax-mark Cm "${ED}"/opt/bin/${PN} || die
		eqawarn "You have set USE=pax_kernel meaning that you intend to run"
		eqawarn "${PN} under a PaX enabled kernel.  To do so, we must modify"
		eqawarn "the ${PN} binary itself and this *may* lead to breakage!  If"
		eqawarn "you suspect that ${PN} is being broken by this modification,"
		eqawarn "please open a bug."
	fi

	echo PRELINK_PATH_MASK=/opt/bin/${PN} > ${T}/99${PN}
	doenvd "${T}"/99${PN} #430142
}

pkg_preinst() {
	gnome2_icon_savelist

	rm -rf "${EROOT}"/usr/share/${PN} #421165
}

pkg_postinst() {
	gnome2_icon_cache_update

	# http://bugs.gentoo.org/360815
	elog "For webcam support, see \"LD_PRELOAD\" section of \"README.lib\" document provided by"
	elog "media-libs/libv4l package and \"README\" document of this package."
	if use amd64; then
		elog "You can install app-emulation/emul-linux-x86-medialibs package for the 32bit"
		elog "libraries from the media-libs/libv4l package."
	fi
}

pkg_postrm() {
	gnome2_icon_cache_update
}