[gentoo-commits] gentoo-x86 commit in x11-terms/rxvt-unicode: rxvt-unicode-9.17.ebuild metadata.xml ChangeLog rxvt-unicode-9.15.ebuild rxvt-unicode-9.15-r1.ebuild

[Jeroen Roovers (jer)]

jer         13/03/03 15:56:56

  Modified:             metadata.xml ChangeLog
  Added:                rxvt-unicode-9.17.ebuild
  Removed:              rxvt-unicode-9.15.ebuild
                        rxvt-unicode-9.15-r1.ebuild
  Log:
  Version bump (bug #460080).
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.30                 x11-terms/rxvt-unicode/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/metadata.xml?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/metadata.xml?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/metadata.xml?r1=1.29&r2=1.30

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/metadata.xml,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- metadata.xml	7 Jan 2013 20:31:17 -0000	1.29
+++ metadata.xml	3 Mar 2013 15:56:56 -0000	1.30
@@ -11,8 +11,6 @@
 </maintainer>
 <use>
 <flag name='256-color'>Enable 256 color support</flag>
-<flag name='afterimage'>Enable transparency support using
-<pkg>media-libs/libafterimage</pkg> (deprecated in 9.15, removed in 9.16)</flag>
 <flag name='alt-font-width'>Calculate the font width using a different method</flag>
 <flag name='blink'>Enable blinking text</flag>
 <flag name='buffer-on-clear'>Store visible output to history buffer when clearing the screen with ctrl-l.



1.236                x11-terms/rxvt-unicode/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog?rev=1.236&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog?rev=1.236&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog?r1=1.235&r2=1.236

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog,v
retrieving revision 1.235
retrieving revision 1.236
diff -u -r1.235 -r1.236
--- ChangeLog	27 Feb 2013 07:51:05 -0000	1.235
+++ ChangeLog	3 Mar 2013 15:56:56 -0000	1.236
@@ -1,6 +1,12 @@
 # ChangeLog for x11-terms/rxvt-unicode
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog,v 1.235 2013/02/27 07:51:05 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/ChangeLog,v 1.236 2013/03/03 15:56:56 jer Exp $
+
+*rxvt-unicode-9.17 (03 Mar 2013)
+
+  03 Mar 2013; Jeroen Roovers <jer@g.o> -rxvt-unicode-9.15.ebuild,
+  -rxvt-unicode-9.15-r1.ebuild, +rxvt-unicode-9.17.ebuild, metadata.xml:
+  Version bump (bug #460080).
 
   27 Feb 2013; Mike Frysinger <vapier@g.o> rxvt-unicode-9.16.ebuild:
   Add arm lovin.



1.1                  x11-terms/rxvt-unicode/rxvt-unicode-9.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/rxvt-unicode-9.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/rxvt-unicode/rxvt-unicode-9.17.ebuild?rev=1.1&content-type=text/plain

Index: rxvt-unicode-9.17.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt-unicode/rxvt-unicode-9.17.ebuild,v 1.1 2013/03/03 15:56:56 jer Exp $

EAPI=4
inherit autotools eutils

DESCRIPTION="rxvt clone with xft and unicode support"
HOMEPAGE="http://software.schmorp.de/pkg/rxvt-unicode.html"
SRC_URI="http://dist.schmorp.de/rxvt-unicode/Attic/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
IUSE="
	256-color alt-font-width blink buffer-on-clear +focused-urgency
	fading-colors +font-styles iso14755 +mousewheel +perl pixbuf secondary-wheel
	startup-notification xft unicode3 +vanilla wcwidth
"

RDEPEND="
	>=sys-libs/ncurses-5.7-r6
	kernel_Darwin? ( dev-perl/Mac-Pasteboard )
	media-libs/fontconfig
	perl? ( dev-lang/perl )
	pixbuf? ( x11-libs/gdk-pixbuf x11-libs/gtk+:2 )
	startup-notification? ( x11-libs/startup-notification )
	x11-libs/libX11
	x11-libs/libXrender
	xft? ( x11-libs/libXft )
"
DEPEND="
	${RDEPEND}
	virtual/pkgconfig
	x11-proto/xproto
"

RESTRICT="test"
REQUIRED_USE="vanilla? ( !alt-font-width !buffer-on-clear focused-urgency !secondary-wheel !wcwidth )"

src_prepare() {
	# fix for prefix not installing properly
	epatch \
		"${FILESDIR}"/${PN}-9.06-case-insensitive-fs.patch \
		"${FILESDIR}"/${PN}-9.15-xsubpp.patch

	if ! use vanilla; then
		ewarn "You are going to include unsupported third-party bug fixes/features."
		ewarn "If you want even more control over patches, then set USE=vanilla"
		ewarn "and store your patch set in /etc/portage/patches/${CATEGORY}/${PF}/"

		use wcwidth && epatch doc/wcwidth.patch

		# bug #240165
		use focused-urgency || epatch "${FILESDIR}"/${PN}-9.06-no-urgency-if-focused.diff

		# bug #263638
		epatch "${FILESDIR}"/${PN}-9.06-popups-hangs.patch

		# bug #237271
		epatch "${FILESDIR}"/${PN}-9.05_no-MOTIF-WM-INFO.patch

		# support for wheel scrolling on secondary screens
		use secondary-wheel && epatch "${FILESDIR}"/${PN}-9.14-secondary-wheel.patch

		# ctrl-l buffer fix
		use buffer-on-clear && epatch "${FILESDIR}"/${PN}-9.14-clear.patch

		use alt-font-width && epatch "${FILESDIR}"/${PN}-9.06-font-width.patch
	else
		epatch_user
	fi

	# kill the rxvt-unicode terminfo file - #192083
	sed -i -e "/rxvt-unicode.terminfo/d" doc/Makefile.in || die "sed failed"

	eautoreconf
}

src_configure() {
	local myconf=''

	use iso14755 || myconf='--disable-iso14755'

	econf --enable-everything \
		$(use_enable 256-color) \
		$(use_enable blink text-blink) \
		$(use_enable fading-colors fading) \
		$(use_enable font-styles) \
		$(use_enable mousewheel) \
		$(use_enable perl) \
		$(use_enable pixbuf) \
		$(use_enable startup-notification) \
		$(use_enable xft) \
		$(use_enable unicode3) \
		${myconf}
}

src_compile() {
	emake || die "emake failed"

	sed -i \
		-e 's/RXVT_BASENAME = "rxvt"/RXVT_BASENAME = "urxvt"/' \
		"${S}"/doc/rxvt-tabbed || die "tabs sed failed"
}

src_install() {
	default

	dodoc \
		README.FAQ Changes doc/README* doc/changes.txt doc/etc/* doc/rxvt-tabbed

	make_desktop_entry urxvt rxvt-unicode utilities-terminal \
		"System;TerminalEmulator"
}

pkg_postinst() {
	if use buffer-on-clear; then
		ewarn "You have enabled the buffer-on-clear USE flag."
		ewarn "Please note that, although this works well for most prompts,"
		ewarn "there have been cases with fancy prompts, like bug #397829,"
		ewarn "where it caused issues. Proceed with caution."
		ewarn "  (keep this terminal open until you make sure it works)"
	fi
	if use secondary-wheel; then
		elog "You have enabled the secondary-wheel USE flag."
		elog "This allows you to scroll in secondary screens"
		elog "(like mutt's message list/view) using the mouse wheel."
		elog
		elog "To actually enable the feature you have to add"
		elog "  URxvt*secondaryWheel: true"
		elog "in your ~/.Xdefaults file"
	fi
}