[gentoo-commits] gentoo-x86 commit in net-libs/xrootd: xrootd-4.0.0.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    14/06/19 18:13:17

  Modified:             ChangeLog
  Added:                xrootd-4.0.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.19                 net-libs/xrootd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/xrootd/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	11 Mar 2014 03:14:28 -0000	1.18
+++ ChangeLog	19 Jun 2014 18:13:17 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/xrootd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/xrootd/ChangeLog,v 1.18 2014/03/11 03:14:28 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/xrootd/ChangeLog,v 1.19 2014/06/19 18:13:17 bicatali Exp $
+
+*xrootd-4.0.0 (19 Jun 2014)
+
+  19 Jun 2014; Sébastien Fabbro <bicatali@g.o> +xrootd-4.0.0.ebuild:
+  Version bump
 
   11 Mar 2014; Patrick Lauer <patrick@g.o> xrootd-3.3.6.ebuild:
   Whitespace



1.1                  net-libs/xrootd/xrootd-4.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/xrootd-4.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/xrootd/xrootd-4.0.0.ebuild?rev=1.1&content-type=text/plain

Index: xrootd-4.0.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/xrootd/xrootd-4.0.0.ebuild,v 1.1 2014/06/19 18:13:17 bicatali Exp $

EAPI=5

inherit cmake-utils eutils user multilib

DURI="http://xrootd.slac.stanford.edu/doc/prod"

DESCRIPTION="Extended ROOT remote file server"
HOMEPAGE="http://xrootd.org/"
SRC_URI="${HOMEPAGE}/download/v${PV}/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc fuse kerberos perl readline ssl test"

RDEPEND="
	!<sci-physics/root-5.32[xrootd]
	sys-libs/zlib:0=
	fuse? ( sys-fs/fuse:0= )
	kerberos? ( virtual/krb5 )
	perl? (
		dev-lang/perl
		readline? ( dev-perl/Term-ReadLine-Perl )
	)
	readline? ( sys-libs/readline:0= )
	ssl? ( dev-libs/openssl:0= )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen[dot] )
	perl? ( dev-lang/swig )
	test? ( dev-util/cppunit )"

pkg_setup() {
	enewgroup xrootd
	enewuser xrootd -1 -1 "${EPREFIX}"/var/spool/xrootd xrootd
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable fuse)
		$(cmake-utils_use_enable kerberos KRB5)
		$(cmake-utils_use_enable perl)
		$(cmake-utils_use_enable readline)
		$(cmake-utils_use_enable ssl CRYPTO)
		$(cmake-utils_use_enable test TESTS)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	use doc && doxygen Doxyfile
}

src_install() {
	cmake-utils_src_install

	# base configs
	insinto /etc/xrootd
	doins packaging/common/*.cfg

	fowners root:xrootd /etc/xrootd
	keepdir /var/log/xrootd
	fowners xrootd:xrootd /var/log/xrootd

	local i
	for i in cmsd frm_purged frm_xfrd xrootd; do
		newinitd "${FILESDIR}"/${i}.initd ${i}
	done
	# all daemons MUST use single master config file
	newconfd "${FILESDIR}"/xrootd.confd xrootd

	dodoc docs/ReleaseNotes.txt
	use doc && dohtml -r doxydoc/html/*
}