[gentoo-commits] repo/gentoo:master commit in: dev-ruby/redcloth/

[Hans de Graaff]

commit:     24abd24cd2e0414aac8a040af45a4132ab7cc0ec
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 22 07:37:54 2021 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Mon Nov 22 08:01:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=24abd24c

dev-ruby/redcloth: use correct version number

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/redcloth/redcloth-4.3.2-r4.ebuild | 55 ++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/dev-ruby/redcloth/redcloth-4.3.2-r4.ebuild b/dev-ruby/redcloth/redcloth-4.3.2-r4.ebuild
new file mode 100644
index 000000000000..13b216f45d45
--- /dev/null
+++ b/dev-ruby/redcloth/redcloth-4.3.2-r4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_NAME="RedCloth"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="README.rdoc CHANGELOG"
+
+RUBY_FAKEGEM_REQUIRE_PATHS="lib/case_sensitive_require"
+
+RUBY_FAKEGEM_GEMSPEC=redcloth.gemspec
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/redcloth_scan/extconf.rb)
+
+inherit ruby-fakegem
+
+DESCRIPTION="A module for using Textile in Ruby"
+HOMEPAGE="http://redcloth.org/"
+
+GITHUB_USER=jgarber
+SRC_URI="https://github.com/${GITHUB_USER}/redcloth/archive/v${PV}.tar.gz -> ${RUBY_FAKEGEM_NAME}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+DEPEND+=" =dev-util/ragel-6*"
+
+PATCHES=( "${FILESDIR}/${P}-load-documents.patch" )
+
+ruby_add_bdepend "
+	>=dev-ruby/rake-0.8.7
+	>=dev-ruby/rake-compiler-0.7.1
+	test? ( >=dev-ruby/diff-lcs-1.1.2 )"
+
+all_ruby_prepare() {
+	sed -i -e '/[Bb]undler/d' Rakefile ${PN}.gemspec || die
+	rm -f tasks/{release,rspec,rvm}.rake || die
+
+	# Fix version
+	sed -i -e '/TINY/ s/1/2/' lib/redcloth/version.rb || die
+}
+
+each_ruby_prepare() {
+	${RUBY} -S rake ext/redcloth_scan/extconf.rb || die
+}