[gentoo-commits] gentoo-x86 commit in games-fps/alienarena: ChangeLog alienarena-20091227.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    09/12/29 05:09:13

  Modified:             ChangeLog
  Added:                alienarena-20091227.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.17                 games-fps/alienarena/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	3 Nov 2009 23:28:31 -0000	1.16
+++ ChangeLog	29 Dec 2009 05:09:13 -0000	1.17
@@ -1,6 +1,12 @@
 # ChangeLog for games-fps/alienarena
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.16 2009/11/03 23:28:31 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.17 2009/12/29 05:09:13 mr_bones_ Exp $
+
+*alienarena-20091227 (29 Dec 2009)
+
+  29 Dec 2009; Michael Sterrett <mr_bones_@g.o>
+  +alienarena-20091227.ebuild:
+  version bump
 
 *alienarena-20091016 (03 Nov 2009)
 



1.1                  games-fps/alienarena/alienarena-20091227.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/alienarena-20091227.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/alienarena-20091227.ebuild?rev=1.1&content-type=text/plain

Index: alienarena-20091227.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/alienarena-20091227.ebuild,v 1.1 2009/12/29 05:09:13 mr_bones_ Exp $

EAPI=2
inherit eutils games

MY_PN=alienarena7_33
DESCRIPTION="Fast-paced multiplayer deathmatch game"
HOMEPAGE="http://red.planetarena.org/"
SRC_URI="http://icculus.org/alienarena/Files/${MY_PN}-linux${PV}.zip"

LICENSE="GPL-2 free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated opengl"

UIRDEPEND="media-libs/jpeg
	media-libs/openal
	media-libs/libvorbis
	virtual/glu
	virtual/opengl
	x11-libs/libXxf86dga
	x11-libs/libXxf86vm"
RDEPEND="opengl? ( ${UIRDEPEND} )
	!opengl? ( !dedicated? ( ${UIRDEPEND} ) )
	net-misc/curl"
UIDEPEND="x11-proto/xf86dgaproto
	x11-proto/xf86vidmodeproto"
DEPEND="${RDEPEND}
	opengl? ( ${UIDEPEND} )
	!opengl? ( !dedicated? ( ${UIDEPEND} ) )
	dev-util/pkgconfig
	app-arch/unzip"

S=${WORKDIR}/${MY_PN}/source

src_prepare() {
	rm -f ../*/*.so
	sed -i \
		-e 's:\($(SHLIBLDFLAGS)\):$(LDFLAGS) \1:' \
		Makefile \
		|| die "sed failed"
}

src_compile() {
	emake \
		ARCH="unknown" \
		OSTYPE="linux" \
		OPTIMIZED_CFLAGS=no \
		WITH_DATADIR=yes \
		WITH_LIBDIR=yes \
		DATADIR="${GAMES_DATADIR}"/${PN} \
		LIBDIR="$(games_get_libdir)"/${PN} \
		$(use opengl && ! use dedicated && echo BUILD=CLIENT) \
		$(! use opengl && use dedicated && echo BUILD=DEDICATED) \
		$(use opengl && use dedicated && echo BUILD=ALL) \
		$(use opengl || use dedicated || echo BUILD=CLIENT) \
		|| die "emake failed"
}

src_install() {
	cd release
	exeinto "$(games_get_libdir)"/${PN}
	doexe game.so || die "doexe failed"
	dosym . "$(games_get_libdir)"/${PN}/arena
	dosym . "$(games_get_libdir)"/${PN}/data1

	if use opengl || ! use dedicated ; then
		newgamesbin crx ${PN} || die "newgamesbin crx failed"
		make_desktop_entry ${PN} "Alien Arena"
	fi

	if use dedicated ; then
		newgamesbin crded ${PN}-ded || die "newgamesbin crded failed"
	fi

	cd "${WORKDIR}"/${MY_PN}
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r arena botinfo data1 || die "doins failed"
	newicon aa.png ${PN}.png || die "newicon failed"
	dodoc docs/README.txt

	prepgamesdirs
}