[gentoo-commits] repo/gentoo:master commit in: net-misc/dibbler/

[Bernard Cafarelli]

commit:     fb5b26d018a97862abb5d839627d773797bc0458
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 29 21:42:44 2020 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Wed Jan 29 21:43:02 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb5b26d0

net-misc/dibbler: ebuild enhancements, add resolvconf support

EAPI bump, use new eclass for README, use keepdir for /var/lib/dibbler

Closes: https://bugs.gentoo.org/670516
Closes: https://bugs.gentoo.org/693874
Closes: https://bugs.gentoo.org/706808
Package-Manager: Portage-2.3.86, Repoman-2.3.20
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 net-misc/dibbler/dibbler-1.0.1-r1.ebuild | 61 ++++++++++++++++++++++++++++++++
 net-misc/dibbler/metadata.xml            |  3 ++
 2 files changed, 64 insertions(+)

diff --git a/net-misc/dibbler/dibbler-1.0.1-r1.ebuild b/net-misc/dibbler/dibbler-1.0.1-r1.ebuild
new file mode 100644
index 00000000000..bf028c2ee5e
--- /dev/null
+++ b/net-misc/dibbler/dibbler-1.0.1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit readme.gentoo-r1 systemd
+
+DESCRIPTION="Portable DHCPv6 implementation (server, client and relay)"
+HOMEPAGE="http://klub.com.pl/dhcpv6/"
+SRC_URI="http://klub.com.pl/dhcpv6/dibbler/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~mips ~x86"
+IUSE="doc resolvconf"
+
+RDEPEND="virtual/resolvconf"
+DEPEND="${RDEPEND}
+	doc? (
+		|| (
+			dev-texlive/texlive-latexextra
+			dev-tex/floatflt
+		)
+	)"
+
+PATCHES=( "${FILESDIR}"/${P}-fno-common.patch )
+
+DOC_CONTENTS="Make sure that you modify client.conf, server.conf and/or relay.conf
+to suit your needs. They are stored in /etc/dibbler"
+
+src_configure() {
+	econf $(use_enable resolvconf)
+}
+
+src_compile() {
+	default
+	# devel documentation is broken and users should consult the online version
+	# http://klub.com.pl/dhcpv6/doxygen/
+	use doc && emake -C doc/ user
+}
+
+src_install() {
+	default
+	readme.gentoo_create_doc
+
+	dosbin dibbler-{client,relay,server}
+	doman doc/man/*.8
+
+	insinto /etc/dibbler
+	doins doc/examples/*.conf
+	keepdir /var/lib/dibbler
+
+	dodoc AUTHORS CHANGELOG RELNOTES TODO
+	use doc && dodoc doc/dibbler-user.pdf
+
+	doinitd "${FILESDIR}"/dibbler-{client,relay,server}
+	systemd_dounit "${FILESDIR}"/dibbler-client.service
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}

diff --git a/net-misc/dibbler/metadata.xml b/net-misc/dibbler/metadata.xml
index 7d273a80ff6..d88cf30d7ac 100644
--- a/net-misc/dibbler/metadata.xml
+++ b/net-misc/dibbler/metadata.xml
@@ -5,4 +5,7 @@
 		<email>voyageur@g.o</email>
 		<name>Bernard Cafarelli</name>
 	</maintainer>
+	<use>
+		<flag name="resolvconf">Use resolvconf to handle /etc/resolv.conf updates</flag>
+	</use>
 </pkgmetadata>