[gentoo-commits] gentoo-x86 commit in dev-util/buildbot: ChangeLog buildbot-0.8.0_p1.ebuild

[Dirkjan Ochtman (djc)]

djc         10/10/05 19:28:10

  Modified:             ChangeLog
  Added:                buildbot-0.8.0_p1.ebuild
  Log:
  Version bump 0.8.0p1 for bug 339863.
  
  (Portage version: 2.1.9.13/cvs/Linux x86_64)

Revision  Changes    Path
1.68                 dev-util/buildbot/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	10 Sep 2010 14:06:05 -0000	1.67
+++ ChangeLog	5 Oct 2010 19:28:10 -0000	1.68
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/buildbot
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.67 2010/09/10 14:06:05 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.68 2010/10/05 19:28:10 djc Exp $
+
+*buildbot-0.8.0_p1 (05 Oct 2010)
+
+  05 Oct 2010; Dirkjan Ochtman <djc@g.o> +buildbot-0.8.0_p1.ebuild:
+  Version bump 0.8.0p1 for bug 339863.
 
   10 Sep 2010; Tobias Klausmann <klausman@g.o> buildbot-0.8.0.ebuild:
   Stable on alpha, bug #325899



1.1                  dev-util/buildbot/buildbot-0.8.0_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/buildbot-0.8.0_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/buildbot-0.8.0_p1.ebuild?rev=1.1&content-type=text/plain

Index: buildbot-0.8.0_p1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/buildbot-0.8.0_p1.ebuild,v 1.1 2010/10/05 19:28:10 djc Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"
DISTUTILS_SRC_TEST="trial"
DISTUTILS_DISABLE_TEST_DEPENDENCY="1"

inherit distutils eutils

MY_PV="${PV/_p/p}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="A Python system to automate the compile/test cycle to validate code changes"
HOMEPAGE="http://buildbot.net/ http://pypi.python.org/pypi/buildbot"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc irc mail manhole test"

# sqlite3 module of Python 2.5 is not supported.
RDEPEND="dev-python/jinja
	|| ( dev-python/pysqlite:2 >=dev-lang/python-2.6[sqlite] )
	>=dev-python/twisted-2.0.1
	dev-python/twisted-web
	dev-python/twisted-mail
	irc? ( dev-python/twisted-words )
	mail? ( dev-python/twisted-mail )
	manhole? ( dev-python/twisted-conch )"
DEPEND="${DEPEND}
	doc? ( dev-python/epydoc )
	test? ( dev-python/twisted-mail
			dev-python/twisted-web
			dev-python/twisted-words )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	enewuser buildbot
	python_pkg_setup
}

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		PYTHONPATH="." "$(PYTHON -f)" docs/epyrun -o docs/reference || die "Generation of documentation failed"
	fi
}

src_install() {
	distutils_src_install
	#doinfo docs/buildbot.info # not in 0.8.0p1
	dohtml -r docs/images

	insinto /usr/share/doc/${PF}
	doins -r contrib
	doins -r docs/examples

	if use doc; then
		doins -r docs/reference || die "doins failed"
	fi

	newconfd "${FILESDIR}/buildslave.confd" buildslave || die "newconfd failed"
	newinitd "${FILESDIR}/buildbot.initd-r1" buildslave || die "newinitd failed"
	newconfd "${FILESDIR}/buildmaster.confd" buildmaster || die "newconfd failed"
	newinitd "${FILESDIR}/buildbot.initd-r1" buildmaster || die "newinitd failed"

	# Make it print the right names when you start/stop the script.
	sed -e "s/@buildbot@/buildslave/" -i "${ED}etc/init.d/buildslave" || die "sed buildslave failed"
	sed -e "s/@buildbot@/buildmaster/" -i "${ED}etc/init.d/buildmaster" || die "sed buildmaster failed"
}

pkg_postinst() {
	distutils_pkg_postinst

	elog 'The "buildbot" user and the "buildmaster" and "buildslave" init'
	elog "scripts were added to support starting buildbot through gentoo's"
	elog "init system.  To use this set up your build master or build slave"
	elog "following the buildbot documentation, make sure the resulting"
	elog 'directories are owned by the "buildbot" user and point'
	elog "${ROOT}etc/conf.d/buildmaster or ${ROOT}etc/conf.d/buildslave"
	elog "at the right location.  The scripts can run as a different user"
	elog "if desired.  If you need to run more than one master or slave"
	elog "just copy the scripts."
	elog ""
	elog "Upstream recommends the following when upgrading:"
	elog "Each time you install a new version of Buildbot, you should run the new"
	elog "'buildbot upgrade-master' command on each of your pre-existing buildmasters."
	elog "This will add files and fix (or at least detect) incompatibilities between"
	elog "your old config and the new code."
}